Raspberry Pi Pico をUSBシリアル変換器として使用したい

Question

前提

AVRマイコン(ブート書き込み済み/生)へ書き込む為、Raspberry Pi PicoをUSBシリアル変換器として利用できないかと考えています。

実現したいこと

TXD RXD (DTR or RST) 1組の出力をするため、Arduinoのリセットのタイミング、Raspberry Pi Pico の内蔵usbコンバータからの直接出力が可能かを知りたい

試したこと

2,6組の2ピン出力のものがありましたが、直接引き出せるかは分かりませんでした

Comments

[dameo]

pico2台で繫いで片割れをデバッグできるみたいなので、可能だと思いますよ。ただし実際に使ったことはありません。

[thkana]

> 内蔵usbコンバータからの直接出力
なんて難しいこと考えなくても、単純にUSB(CDCプロトコル)から受けたデータを適切なボーレートでUARTにリレーしてやればよいだけに思えますが。あとはDTRを見てリセット制御と。(5V系だとレベル変換も要るか)
https://github.com/adafruit/Adafruit_TinyUSB_Arduino 覗いてみると、Adafruit_USBD_CDC.hに
uint32_t baud(void);
とか
int dtr(void);
なんていうメンバ関数も見えます。
これからおでかけなので私はすぐにはいじれませんが。

Answer 1

多分これでできたりしそうな。5V/3.3V変換とか発振器の用意が面倒なので試してませんが。
ボードライブラリ: Raspberry Pi Pico
リポジトリ https://github.com/earlephilhower/arduino-pico/releases/download/global/package_rp2040_index.json から取得する物で、mbed版ではないので注意
[ツール]-[USB Stack]-> Adafruit Tiny USB に設定
ライブラリ: Adafruit TinyUSB Arduino

#include <Adafruit_TinyUSB.h>

#define LED LED_BUILTIN
const int RESET=9;
uint32_t t0;
int lastDTR;
int lastbaud;
void setup() {
    pinMode(LED, OUTPUT); //デバッグ用
    pinMode(RESET, OUTPUT); //ターゲットリセット用
    digitalWrite(RESET,HIGH);
    Serial.begin(115200);

    while(!Serial); //USBシリアルが接続されるまで待つ
    int baud=Serial.baud(); //接続されたボーレートを取得する
    lastDTR=0;
    lastbaud=baud;
    Serial1.begin(baud);
}

void loop() {
    if(Serial.available()){
        Serial1.write(Serial.read());
    }
    if(Serial1.available()){
        Serial.write(Serial1.read());
    }
    int currentDTR=Serial.dtr();
    if(lastDTR==0 && currentDTR!=0){
        t0=millis();
    }
    lastDTR=currentDTR;
    int rst=HIGH;
    if(millis()-t0<100){
        rst=LOW;
    }
    digitalWrite(RESET,rst);
    digitalWrite(LED,!rst);
    if(Serial.baud()!=lastbaud){
        Serial1.end();
        lastbaud=Serial.baud();
        Serial1.begin(lastbaud);
    }
}

USB側をCDC(つまり仮想シリアル)で接続すると、そのボーレートを検出してUART(Serial1)を設定し、USB-UART間のデータを中継します。ボーレートの変更を検出したときは再設定します。
また、DTRを検出し、DTRがアクティブになった時にPIO(とりあえずなんとなく9pin)を100msLにすることでターゲットにリセットをかけます。

Comments

[thkana]

あ、Arduinoタグを見てArduino IDEでやっちゃったけど、circuit Pythonじゃなきゃヤダ、とかあったりするのでしょうか? タグは情報を絞り込むためにあるので、関係のないタグは付けるのは誰かの迷惑になる可能性があります。できるだけ絞り込んでタグ付けして欲しいなぁ、と思います。

[eipi-1-0]

丁寧なご回答ありがとうございます。
ソースや説明が分かりやすく、DTRについても触れて下さり、良かったです。
特に言語は問いませんし、指針さえ分かれば良いかな、と思っていたので本当にありがたい限りです。

[eipi-1-0]

タグ付けについては、広く取り過ぎでしたね。以後、注意していきます。
申し訳ありませんでした。

Answer 2

ラズパイPicoのことはよく知りませんが、

1. CPUのメーカ、あるいはラズパイ公式から、仮想USBシリアルのサンプルコードを探してそれをもとに実装する
2. どこかで仮想シリアルを使用したソースコードが公開されているなら、それをもとに改造する
3. CPUのデータシートから、内蔵USBの操作法がわかりますんで、そこから仮想シリアルポートのコードを書いていく

というやり口になろうかと思います（下に行くほど難易度が上がる）
まずはCPUメーカの公開サンプルコードを探してみることでしょうか

＃STM32なんかだと、それ用の開発環境から自動生成でUSBユニットのコードを吐いてくれたりしますが

Comments

[eipi-1-0]

遅くなって申し訳ありません。
他の方が具体的に指針を示して下さったので、そちらをベストアンサーとさせて頂きます。
CPUを無効化してUSBコンバータを利用できればと考えていましたが、仮想シリアルを利用すると良いのですね。
1は見つかりませんでしたが、2, 3を検討しようと思います。
ありがとうございました。