ポリゴンの表面と裏面に別テクスチャを貼る機能を追加したい

解決したいこと

下記のシェーダにポリゴンの表面と裏面に別テクスチャを貼る機能を追加したいのですが、可能でしょうか。
https://teratail.com/questions/127166
お手数をおかけしますが、ご教授頂けると幸いです。

Shader "Unlit/CastShadowTest1"
{
	Properties
	{
		_Color ("Main Color", Color) = (1, 1, 1, 1)
		_MainTex ("Base (RGB)", 2D) = "white" { }
		_ShadowIntensity ("Shadow Intensity", Range(0.0, 1.0)) = 0.5 // 大きくするほど影が暗くなる
		// _Cutoff ("Alpha cutoff", Range(0, 1)) = 0.5 // 半透明物体の場合、アルファカットオフを可変にはせずに...
		[Toggle(UNITY_UI_ALPHACLIP)] _UseUIAlphaClip ("Use Alpha Clip", Float) = 0 // カットオフをトグルで切り替え、オンならば固定値0.001でカットオフするケースが多いようです
	}
	CGINCLUDE
    // 影係数の取得および緩和に使う
    // 1 - (1 - 影係数) * _ShadowIntensity を最終的な影係数とすることで、影が暗くなりすぎるのを防ぐ
	#define FADED_SHADOW_ATTENUATION(i) (1.0 - (1.0 - UNITY_SHADOW_ATTENUATION(i, i.worldPos)) * _ShadowIntensity)
	ENDCG
	SubShader
	{
		// Queueが「AlphaTest」になっていましたが、おそらく妥当な方法だと思います
		// 本来は「AlphaTest」はアルファを基に完全透明・完全不透明を切り替えるタイプの不透明オブジェクトに
		// 用いるもので、半透明オブジェクトは「Transparent」を使うべきかと思いますが、そうしてしまうと
		// 影機能も使えなくなってしまうようです
		// 半透明オブジェクトを正しくアルファ合成するには他の不透明オブジェクトよりも後に描画させたいところですが
		// 「AlphaTest」なら一般的な不透明オブジェクトの「Geometry」よりは後になるそうなので、描画不具合も
		// 起こりにくいのではないでしょうか
		Tags { "Queue" = "AlphaTest" "RenderType" = "TransparentCutout" }
		// シャドウキャスティングパス
		// LightModeが「ShadowCaster」のパスがないと、影を落とす・受けるのいずれも行われなくなるようです
		// コード末尾にFallbackを記述しておくことで他のシェーダーに処理を代替させることもできますが、
		// 今回は半透明の特殊なケースですので、自前で用意することにしました
        // なお、旧バージョンでは「ShadowCollector」パスが影を受ける処理を担当していたそうですが
        // 現在は廃止されたようです
		Pass
		{
			Name "ShadowCaster"
			Tags { "LightMode" = "ShadowCaster" }
			ZWrite On ZTest LEqual
			CGPROGRAM
			#define UNITY_STANDARD_USE_DITHER_MASK
			#define UNITY_STANDARD_USE_SHADOW_UVS
			#pragma target 3.0
			#pragma vertex vert
			#pragma fragment frag
			#include "UnityStandardShadow.cginc"
			struct VertexOutput
			{
				V2F_SHADOW_CASTER_NOPOS
				float2 tex: TEXCOORD1;
			};
			void vert(VertexInput v, out VertexOutput o, out float4 opos: SV_POSITION)
			{
				TRANSFER_SHADOW_CASTER_NOPOS(o, opos)
				o.tex = v.uv0;
			}
			half4 frag(VertexOutput i, UNITY_VPOS_TYPE vpos: VPOS): SV_Target
			{
				// シャドウマップへの描画は原理的に完全透明か完全不透明でないとなりません
                // そこで、Unity組み込みのディザリング用テクスチャをアルファに基づいて参照することで
				// アルファが小さいほど高確率で透明、大きいほど不透明となるような動作をさせることができます
				// できあがるシャドウマップにはディザリングによるノイズが乗っていますが、ソフトシャドウモードなら
				// 後で近傍比率フィルタリングがかかるので、影に関してはさほど見た目は悪くないと思われます
                // 半透明部分のエッジにノイズが目立つかもしれませんが、これはポストエフェクトなどでごまかす...?
				half alpha = tex2D(_MainTex, i.tex.xy).a * _Color.a;
				alpha = tex3D(_DitherMaskLOD, float3(vpos.xy * 0.25, alpha * 0.9375)).a;
                // 場合によっては下記1行をコメントアウトして、Quad全面を完全描画させた方が良好な結果になるかと思います
				clip(alpha - 0.01); // ディザリングの結果アルファ0.01未満になればフラグメントを破棄
				SHADOW_CASTER_FRAGMENT(i)
			}
			
			ENDCG
		}
		// フォワードレンダリングベースパス
		Pass
		{
			Name "ForwardBase"
			Tags { "LightMode" = "ForwardBase" }
			Blend SrcAlpha OneMinusSrcAlpha // 一般的なアルファ合成方式を使用
			ZWrite On ZTest LEqual
			CGPROGRAM
			
			#pragma vertex vert
			#pragma fragment frag
			#pragma fragmentoption ARB_fog_exp2
			#pragma fragmentoption ARB_precision_hint_fastest
			#pragma multi_compile_fwdbase
			#pragma multi_compile _ UNITY_UI_ALPHACLIP // アルファクリップがオン・オフの場合でマルチコンパイル
			#include "UnityCG.cginc"
			#include "AutoLight.cginc"
			sampler2D _MainTex;
			fixed4 _Color;
			float _ShadowIntensity;
			struct v2f
			{
				float4 pos: SV_POSITION; // UNITY_TRANSFER_SHADOW内ではクリッピング座標の名前が「pos」であることが前提になっているため、そのようにする(ご質問者さんのコードでは、すでにそうなっていました)
				float2 uv: TEXCOORD0;
				UNITY_SHADOW_COORDS(1) // TEXCOORD1を影情報伝達に使用する
				float3 worldPos: TEXCOORD2; // TEXCOORD2をワールド座標伝達に使用する
			};
			v2f vert(appdata_full v) // 頂点入力データの形式として、appdata_tanに代わってappdata_fullを使う
			{
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				o.uv = v.texcoord.xy;
				UNITY_TRANSFER_SHADOW(o, v.texcoord1); // texcoord1にライトマップ用UVが格納されているので、それを使って影情報の計算を行う
				o.worldPos = mul(unity_ObjectToWorld, v.vertex); // worldPosに頂点のワールド座標をセットする
				return o;
			}
			fixed4 frag(v2f i): SV_Target
			{
				fixed4 color = tex2D(_MainTex, i.uv) * _Color;
				#ifdef UNITY_UI_ALPHACLIP
					clip(color.a - 0.001); // アルファ0.001未満は完全透明と見なし、フラグメントを破棄してレンダリングしない
				#endif
				color.rgb *= FADED_SHADOW_ATTENUATION(i); // 影係数はアルファには作用させない
				return color;
			}
			ENDCG
			
		}
		
		// フォワードレンダリング加算パス
		Pass
		{
			Name "ForwardAdd"
			Tags { "LightMode" = "ForwardAdd" }
			Blend DstColor Zero // 普通は加算パスでは照明効果をどんどん加算していくかと思いますが、今回は影をどんどん乗算していくことにしました
			ZWrite Off
			CGPROGRAM
			
			#pragma vertex vert
			#pragma fragment frag
			#pragma fragmentoption ARB_fog_exp2
			#pragma fragmentoption ARB_precision_hint_fastest
			#pragma multi_compile_fwdadd_fullshadows
			#pragma multi_compile _ UNITY_UI_ALPHACLIP
			#include "UnityCG.cginc"
			#include "AutoLight.cginc"
			sampler2D _MainTex;
			fixed4 _Color;
			float _ShadowIntensity;
            // v2f、vertはベースパスと同じ(CGINCLUDEやcgincを使って共通コードをまとめることも可能かと思います)
			struct v2f
			{
				float4 pos: SV_POSITION;
				float2 uv: TEXCOORD0;
				UNITY_SHADOW_COORDS(1)
				float3 worldPos: TEXCOORD2;
			};
			v2f vert(appdata_full v)
			{
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				o.uv = v.texcoord.xy;
				UNITY_TRANSFER_SHADOW(o, v.texcoord1);
				o.worldPos = mul(unity_ObjectToWorld, v.vertex);
				return o;
			}
			fixed4 frag(v2f i): SV_Target
			{
				float alpha = tex2D(_MainTex, i.uv).a * _Color.a;
				#ifdef UNITY_UI_ALPHACLIP
					clip(alpha - 0.001); // アルファ0.001未満は完全透明と見なし、フラグメントを破棄してレンダリングしない
				#endif
				float attenuation = FADED_SHADOW_ATTENUATION(i);
				return fixed4(attenuation, attenuation, attenuation, 1.0);
			}
			ENDCG
			
		}
	}
}

進捗

こちらのコードを参照しているのですが、うまく表示されません。

Shader "Unlit/reversible"
{
    Properties
    {
        _MainTex ("Texture", 2D)    = "white" {}
        _MainTex2("Texture2", 2D) = "white"{}
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100
        Cull off

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma target 3.0

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
            };

            sampler2D _MainTex;
            sampler2D _MainTex2;
            float4 _MainTex_ST;
            
            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos( v.vertex );
                o.uv = v.uv;
                return o;
            }
            
            fixed4 frag (v2f i, fixed facing : VFACE) : SV_Target
            {                
                return (facing > 0 ) ? tex2D(_MainTex, i.uv) : tex2D(_MainTex2, i.uv);
            }
            ENDCG
        }
    }
}

回答1件

ベストアンサー

両者を合体させるとなりますと、下記のような形はいかがでしょうか。

ShaderLab
1Shader "Unlit/DoubleSided"
2{
3	Properties
4	{
5		_Color ("Front Color", Color) = (1, 1, 1, 1)
6		[NoScaleOffset] _MainTex ("Front Texture", 2D) = "white" { }
7		_BackColor ("Back Color", Color) = (1, 1, 1, 1)
8		[NoScaleOffset] _BackTex ("Back Texture", 2D) = "white" { }
9		_ShadowIntensity ("Shadow Intensity", Range(0.0, 1.0)) = 0.5
10		[Toggle(UNITY_UI_ALPHACLIP)] _UseUIAlphaClip ("Use Alpha Clip", Float) = 0
11		[Toggle(RECT_DEPTH)] _UseRectDepth ("Use Rectangular Depth", Float) = 0
12	}
13	
14	// v2f、vertなどの共通化できる部分をCGINCLUDE内にまとめました
15	CGINCLUDE
16	#include "UnityCG.cginc"
17	#include "AutoLight.cginc"
18	#define FADED_SHADOW_ATTENUATION(i) (1.0 - (1.0 - UNITY_SHADOW_ATTENUATION(i, i.worldPos)) * _ShadowIntensity)
19	float4 _BackColor;
20	sampler2D _BackTex;
21	struct v2f
22	{
23		float4 pos: SV_POSITION;
24		float2 uv: TEXCOORD0;
25		UNITY_SHADOW_COORDS(1)
26		float3 worldPos: TEXCOORD2;
27	};
28	v2f vert(appdata_full v)
29	{
30		v2f o;
31		o.pos = UnityObjectToClipPos(v.vertex);
32		o.uv = v.texcoord.xy;
33		UNITY_TRANSFER_SHADOW(o, v.texcoord1);
34		o.worldPos = mul(unity_ObjectToWorld, v.vertex);
35		return o;
36	}
37	ENDCG
38
39	SubShader
40	{
41		Tags { "Queue" = "AlphaTest" "RenderType" = "TransparentCutout" }
42
43		Pass
44		{
45			Name "ShadowCaster"
46			Tags { "LightMode" = "ShadowCaster" }
47			ZWrite On ZTest LEqual Cull Off // カリングをオフにして両面描画としました
48			CGPROGRAM
49			#define UNITY_STANDARD_USE_DITHER_MASK
50			#define UNITY_STANDARD_USE_SHADOW_UVS
51			#pragma target 3.0
52			#pragma vertex vertShadow
53			#pragma fragment fragShadow
54			#pragma multi_compile _ RECT_DEPTH
55			#include "UnityStandardShadow.cginc"
56			struct VertexOutput
57			{
58				V2F_SHADOW_CASTER_NOPOS
59				float2 tex: TEXCOORD1;
60			};
61			void vertShadow(VertexInput v, out VertexOutput o, out float4 opos: SV_POSITION)
62			{
63				TRANSFER_SHADOW_CASTER_NOPOS(o, opos)
64				o.tex = v.uv0;
65			}
66			half4 fragShadow(VertexOutput i, UNITY_VPOS_TYPE vpos: VPOS, float facing : VFACE): SV_Target
67			{
68				// 自身の落とす影を四角にするかどうかをトグルで切り替えるようにしました
69				#ifndef RECT_DEPTH
70					// facingに応じて前面・背面のアルファを切り替えるようにしました
71					half alpha = lerp(tex2D(_BackTex, i.tex).a * _BackColor.a, tex2D(_MainTex, i.tex).a * _Color.a, facing * 0.5 + 0.5);
72					alpha = tex3D(_DitherMaskLOD, float3(vpos.xy * 0.25, alpha * 0.9375)).a;
73					clip(alpha - 0.01);
74				#endif
75				SHADOW_CASTER_FRAGMENT(i)
76			}
77			ENDCG
78		}
79
80		Pass
81		{
82			Name "ForwardBase"
83			Tags { "LightMode" = "ForwardBase" }
84			Blend SrcAlpha OneMinusSrcAlpha
85			ZWrite On ZTest LEqual Cull Off // カリングをオフにして両面描画としました
86			CGPROGRAM
87			#pragma vertex vert
88			#pragma fragment frag
89			#pragma fragmentoption ARB_fog_exp2
90			#pragma fragmentoption ARB_precision_hint_fastest
91			#pragma multi_compile_fwdbase
92			#pragma multi_compile _ UNITY_UI_ALPHACLIP
93			sampler2D _MainTex;
94			fixed4 _Color;
95			float _ShadowIntensity;
96			fixed4 frag(v2f i, float facing : VFACE): SV_Target
97			{
98				// facingに応じて前面・背面の色を切り替えるようにしました
99				fixed4 color = lerp(tex2D(_BackTex, i.uv) * _BackColor, tex2D(_MainTex, i.uv) * _Color, facing * 0.5 + 0.5);
100				#ifdef UNITY_UI_ALPHACLIP
101					clip(color.a - 0.001);
102				#endif
103				color.rgb *= FADED_SHADOW_ATTENUATION(i);
104				return color;
105			}
106			ENDCG
107		}
108		
109		Pass
110		{
111			Name "ForwardAdd"
112			Tags { "LightMode" = "ForwardAdd" }
113			Blend DstColor Zero
114			ZWrite Off Cull Off // カリングをオフにして両面描画としました
115			CGPROGRAM
116			#pragma vertex vert
117			#pragma fragment frag
118			#pragma fragmentoption ARB_fog_exp2
119			#pragma fragmentoption ARB_precision_hint_fastest
120			#pragma multi_compile_fwdadd_fullshadows
121			#pragma multi_compile _ UNITY_UI_ALPHACLIP
122			#include "UnityCG.cginc"
123			#include "AutoLight.cginc"
124			sampler2D _MainTex;
125			fixed4 _Color;
126			float _ShadowIntensity;
127			fixed4 frag(v2f i, float facing : VFACE): SV_Target
128			{
129				// facingに応じて前面・背面のアルファを切り替えるようにしました
130				float alpha = lerp(tex2D(_BackTex, i.uv).a * _BackColor.a, tex2D(_MainTex, i.uv).a * _Color.a, facing * 0.5 + 0.5);
131				#ifdef UNITY_UI_ALPHACLIP
132					clip(alpha - 0.001);
133				#endif
134				float attenuation = lerp(1.0, FADED_SHADOW_ATTENUATION(i), alpha);
135				return fixed4(attenuation, attenuation, attenuation, 1.0);
136			}
137			ENDCG
138		}
139	}
140}

表面

裏面

Use Rectangular Depth オン

Use Rectangular Depth オフ

デプスをディザリングすると半透明部分にノイズが乗ってしまったり、逆にデプスを四角形のままにすると透明部分にも影が乗っているかのように見えてしまったり（あの影は実際には地面側のマテリアルが描画しているものです）...といった欠点は相変わらずですが、ひとまずCastShadowTest1と同等の描画結果、かつ表裏別々のテクスチャにはなるかと思います。

投稿2022/03/23 22:07

編集2022/03/24 00:25