javaで当たり判定のついたシューティングゲームを作りたい。

Question

Processingを使用してシューティングゲームを制作しています。
当たり判定を実装したいのですが、うまくいきません。
自機から放った弾（SHOT）が、敵（ENEMY）の当たり判定範囲内に入った時に、弾と敵が描画されなくなるようにしたいです。

【試したこと】
boolean でhitflagを立てて、衝突範囲内に入った時にtrueを返すようなプログラムを作っていますが、うまくいきません。
加えて、敵や弾の速度が不安定になってしまっています。

ENEMY enemy[];
HIKOU hikou;
HAIKEI haikei[];
ArrayList<SHOT> shotList = new ArrayList<SHOT>();
PImage png; int N = 100; int n = 5;
float ey, ex; float sx, sy;
boolean hitflag;

void setup() {
  size(300, 600);
  frameRate(30);
  rectMode(CENTER);
  noCursor();
  png = loadImage("hikou.png");
  png = loadImage("enemy.png");
  hikou = new HIKOU();
  haikei = new HAIKEI[N];
  for (int i = 0; i < N; i++) {
    haikei[i] = new HAIKEI();
  }
  enemy = new ENEMY[n];
  if(!hitflag){　　//ここにhitflagを立てて、falseの時だけ描画しようとしています。
  for (int i = 0; i < n; i++) {
    enemy[i] = new ENEMY();
  }
  }
}

void draw() {
  background(0);
  for (int i = 0; i < N; i++) {
    haikei[i].draw();
  }
  if(!hitflag){  //ここもfalseの時だけ描画しようとしています。
  for (int i = 0; i < n; i++) {
    enemy[i].draw();
  }
  }
  for (int i=shotList.size ()-1; i>=0; i--) {
    SHOT t = shotList.get(i);
    if (t.isAlive()) {
      t.move();
      t.display();
    } else {
      shotList.remove(i);
    }
  }
  hikou.move(mouseX, mouseY);
  hikou.display();
  PImage hikoupng = loadImage("hikou.png");
  image(hikoupng, mouseX - 15, mouseY - 32);
}

void mousePressed() {
  shotList.add(new SHOT(hikou.x, hikou.y));
}

class HIKOU {　　//自機
  float x, y;
  float size;
  
  HIKOU() {
    size = 10;
  }
  
  void move(float _x, float _y) {
    x = _x;
    y = _y;
  }
  void display() {
  }
}

public class SHOT {　　//弾
  float size;
  float speed;
  
  SHOT(float _x, float _y) {
    sx = _x;
    sy = _y;
    size = 6;
    speed = 15;
  }
  
  void move() {
    sy -= speed;
  }
  
  void display() {
    stroke(0);
    fill(255, 0, 0);
    rect(sx, sy, size, size);
  }
  
  boolean isAlive() {
    if (sx+size/2<0 || width<sx-size/2 || sy+size/2<0 || height<sy-size/2) {
      return false;
    }
    return true;
  }
  
}

class HAIKEI {　　//背景
  float y;
  float x;
  float vy = 10;
  float len;
  
  HAIKEI() {
    init();
    y = random(-height, height);
  }
  void init() {
    y = random(-2*height, -1);
    x = random(0, width);
    vy = random(10, 18);
    len = random(15, 25);
  }
  
  void draw() {
    stroke(200);//color
    line(x, y, x, y+len);
    update();
  }
  
  void update() {
    y += vy;
    if (height < y+len) {
      init();
    }
}
}

public class ENEMY {　　//敵
  float vy = 5;
  float len;
  
  ENEMY() {
    init();
    ey = random(-2 * height, -height);
  }
  void init() {
    ey = random(-20);
    ex = random(20, width - 20);
    len = random(20, 35);
  }
  void draw() {
    PImage enemypng = loadImage("enemy.png");
    image(enemypng, ex, ey);
    update();
  }
  
  void update() {
    ey += vy;
    
    if (height + 40 < ey + len) {
      init();
    }
}

public boolean hitflag;{　　//ここがhitflagです。
  if(ex + 20 > sx && ex - 20 > sx && ey + 20 > sy && ey > sy + 20){
  hitflag = true;
  } else {
  hitflag = false;
  }
}
}

修正点が多く、拙い内容で申し訳ないのですが、ご教授いただければ幸いです。

Comments

[jimbe]

> 衝突範囲内に入った時にtrueを返すようなプログラム
というのはコードの最後にある hitflag でしょうか。
これはメソッドなのでしょうか、それともフィールド(プロパティ)なのでしょうか。いつ if 文が実行されるのでしょう。

[stdio]

jimbeさんの指摘している通り、hitflag の存在があやふやです。使い方は普通の変数に見えますが、当たり判定だというなら各キャラクターがいている座標ぐらい取得できるようにしないと、判定が上手くいくわけありません。
かなり上から目線の文章になってしまいましたが、ゲームを作る前にもう少しJavaという言語を勉強した方がいいかも知れません。

Answer 1

Java - シューティングゲームで、当たり判定を実装したい｜teratail
から1週間だいぶ試行錯誤しておられるようですね。
しかし残念ながら方向が違うような気がします。

Processingは仕組み上クラス内からグローバル変数にアクセスし放題なのですが、そのせいでスパゲッティコードにもなりやすいです（ありがたい時もあるんですが^^;
例えばENEMYのx・yが外に出てしまって（ex・ey）、前回より退化してしまっています。

敵や弾の速度が不安定になってしまっています。

ちゃんとは追っていませんが、おそらくex・ey・sx・syのせいです。

boolean でhitflagを立てて、衝突範囲内に入った時にtrueを返すような

敵が複数いるのですから、フラグも複数あるべきでは？
ひとつでもできないことはないでしょうが、ややこしくなるしすでにクラスがあるんですからそっちに定義すればいいと思います。

個人的に気になった点を変更しました。

• 命名規則を標準的なものに
  Javaではクラス名は通常パスカルケース（例:PascalCase）です。
  大文字だけ（例:UPPER_SNAKE_CASE）は定数に使用します。
  （まあ「個人で作っているものは好きにつけりゃいいじゃん」と思っていますが、標準のもの（ArrayList等）と混じると読みにくいので^^;

• 同じような意味のmove・displayと、update・drawがあるのは気持ち悪いので統一
  ２つのプログラムを合体させた感じ？（いろいろ参考にされていると思いますが

• つどloadImageしてしまっているのは大変無駄
  せっかくクラスを作ったのだから、メンバ変数に入れときましょう。

• Nやnはわかりにくいので、lengthや拡張for文に置き換える
  特にグローバル変数は多いほど読みにくくなるので、使わずに済む場合は積極的に減らします。

Player player;
Enemy[] enemies = new Enemy[5];
Star[] stars = new Star[100];
ArrayList<Shot> shotList = new ArrayList<Shot>();


void setup() {
  size(300, 600);
  frameRate(30);
  rectMode(CENTER);
  imageMode(CENTER);
  noCursor();

  player = new Player(loadImage("hikou.png"));

  PImage png = loadImage("enemy.png");
  for (int i = 0; i < enemies.length; i++) {
    enemies[i] = new Enemy(png);
  }

  for (int i = 0; i < stars.length; i++) {
    stars[i] = new Star();
  }
}

void draw() {
  background(0);

  player.update();

  for (Star star : stars) {
    star.update();
    star.draw();
  }

  boolean gameOver = false;
  for (Enemy enemy : enemies) {
    enemy.update();

    // 弾に当たっているか確認のため全弾ループ
    for (int i = shotList.size () - 1; i >= 0; i--) { 
      Shot shot = shotList.get(i);
      if (enemy.isHit(shot.x, shot.y)) { // shotの座標と接触していれば...
        enemy.isDead = true; // フラグで管理するならこう
        //enemy.init(); // でも敵がいなくなってしまうので単に初期化でいい気が^^;
        shotList.remove(i);
        println("hit");
      }
    }

    // ついでに自機との接触も
    if (enemy.isHit(player.x, player.y)) { // playerの座標と接触していれば...
      gameOver = true;
    }

    enemy.draw();
  }

  for (int i = shotList.size () - 1; i >= 0; i--) {
    Shot shot = shotList.get(i);
    shot.update();
    if (shot.isAlive()) {
      shot.draw();
    } else {
      shotList.remove(i);
    }
  }

  player.draw();

  if (gameOver) {
    fill(255);
    textSize(40);
    textAlign(CENTER, CENTER);
    text("GAME OVER", width / 2, height / 2);
    noLoop();
  }
}

void mousePressed() {
  shotList.add(new Shot(player.x, player.y));
}


class Player {
  PImage image; 
  float x;
  float y;

  Player(PImage _image) {
    image = _image;
  }

  void update() {
    x = mouseX;
    y = mouseY;
  }

  void draw() {
    image(image, x, y);
  }
}

class Enemy {
  PImage image; 
  float x;
  float y;
  float vy = 5;
  float size = 40;
  boolean isDead; // フラグを作るならココ

  Enemy(PImage _image) {
    image = _image;
    init();
    y = random(-2 * height, -height);
  }

  void init() {
    isDead = false;
    y = random(-20);
    x = random(20, width - 20);
  }

  void draw() {
    if (isDead) return;

    image(image, x, y);
  }

  void update() {
    if (isDead) return;

    y += vy;
    if (height + size < y) {
      init();
    }
  }

  // Shot#isAliveと同じような感じで指定座標（_x・_y）との接触判定
  boolean isHit(float _x, float _y) { 
    if (isDead) return false;

    float r = size / 2;
    return x - r < _x && _x < x + r &&  y - r < _y && _y < y + r;
  }
}

class Star {
  float x;
  float y;
  float vy;
  float len;

  Star() {
    init();
    y = random(-height, height);
  }

  void init() {
    y = random(-2 * height, -1);
    x = random(0, width);
    vy = random(10, 18);
    len = random(15, 25);
  }

  void update() {
    y += vy;
    if (height < y + len) {
      init();
    }
  }

  void draw() {
    stroke(200);
    line(x, y, x, y + len);
  }
}

class Shot {
  float x;
  float y;
  float vy = -15;
  float size = 6;

  Shot(float _x, float _y) {
    x = _x;
    y = _y;
  }

  void update() {
    y += vy;
  }

  void draw() {
    stroke(0);
    fill(255, 0, 0);
    rect(x, y, size, size);
  }

  boolean isAlive() {
    float r = size / 2;
    return 0 <= x + r && x - r <= width && 0 <= y + r && y - r <= height;
  }
}

---

別にこれが正解というわけではありません。
10人いたら10通りのコードになるでしょうし、あまりいじらないようにしたので「ちょっとどうかな？」という部分もあります。

Comments

[wotuyu]

とても丁寧なご回答本当にありがとうございます。
理解が難しかった点などが、詳しい解説でとても分かりやすかったです。
フラグの立て方や、細かい点（意味が同じコードの統一等）までご指摘いただき、大変勉強になりました。
これを今後の学習に役立て、より一層プログラミングを頑張りたいと思います。
本当にありがとうございました。