m5stack に現在の時刻を取得して表示したい

Question

m5stackに時刻を切り出して表示させたいです．
しかし，時刻の切り出しがうまくいかず， hour や month が 0 として表示されてしまいます．
どのようにすれば時刻を切り出すことができますか？
よろしくお願いいたします．

ちなみに，時刻は今後手動で増やせるようにしたいため，変数に切り出したいです．

以下コード

#include <M5Stack.h>
#include <WiFi.h>
#include "time.h"

const char* ssid       = "hogehoge";
const char* password   = "fugafuga";

const char* ntpServer = "ntp.nict.jp";
const long  gmtOffset_sec = 3600 * 9;
const int   daylightOffset_sec = 0;

int month;
int day;
int hour;
int minute;

void printLocalTime()
{
  M5.Lcd.setTextSize(2);
  M5.Lcd.setCursor(40,100);
  
  M5.Lcd.printf("%02d-%02d %02d:%02d",month,day,hour,minute);
}

void setup()
{
  M5.begin();
  M5.Lcd.print("Connecting to YOUR_SSID ");
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
      delay(500);
      M5.Lcd.print(".");
  }
  M5.Lcd.println(" CONNECTED");
  
  configTime(gmtOffset_sec, daylightOffset_sec, ntpServer);

  struct tm timeinfo;
  month  = timeinfo.tm_mon;
  day    = timeinfo.tm_mday;
  hour   = timeinfo.tm_hour;
  minute = timeinfo.tm_min;

  printLocalTime();

  WiFi.disconnect(true);
  WiFi.mode(WIFI_OFF);
}

void loop()
{
  delay(1000);
  printLocalTime();
}

Comments

[thkana]

タグのC#は明らかに関係ないので外して下さい。IoTもこの質問の範囲としては関係ないと思いますけれど。

Answer 1

<time.h> の localtime と同様の関数 getLocalTime が <M5Stack.h> にあるようです。

  struct tm timeinfo;
  getLocalTime(&timeinfo);  // 現在時刻を timeinfo に取得
  month  = timeinfo.tm_mon + 1;  // +1 を忘れずに
  day    = timeinfo.tm_mday;
  hour   = timeinfo.tm_hour;
  minute = timeinfo.tm_min;

Comments

[退会済みユーザー]

ありがとうございます！できました！

Answer 2

時刻を読み取る処理がどこにも無いです…

  configTime(gmtOffset_sec, daylightOffset_sec, ntpServer);  // これから読み取る時刻の設定をしている
  struct tm timeinfo;  // 構造体の領域を確保している
  // <= ここに構造体へ時刻をロードする処理を記述する必要があるはず
  month  = timeinfo.tm_mon;  // 構造体から値を取り出す？
  day    = timeinfo.tm_mday;
  hour   = timeinfo.tm_hour;
  minute = timeinfo.tm_min;