Unityで投擲物等の着弾予測円を地形によって変化させたい

Question

前提・実現したいこと

unityで着弾予測円を地形に沿わせる形で変化させたいです


地面と建物と同時に円を表示させたいです

円の表示角度を変えることはできたのですが、地形に沿って画像を表示などで検索してみましたが回答を得られませんでした。
それからどういう単語で検索すればいいか検討がつかないです。

こういう機能でできる、こういう単語で検索すればいい等ありましたら教えていただきたいです。

補足情報（FW/ツールのバージョンなど）

Unity 2019.2.4fi

Answer 1

着弾点に球体オブジェクトを置き、「デプスフェイル法」の記事で紹介されているようなテクニックを使って、球が他のオブジェクトと交差している部分だけを塗るというのはどうでしょう。

一例として、球体に下記のマテリアルを使ったところ...

Shader "Unlit/ExplosionArea"
{
    Properties
    {
        _Color ("Color", Color) = (1.0, 0.0, 0.0, 0.5)
    }
    SubShader
    {
        Tags {"RenderType"="Opaque" "Queue"="Geometry+1"}

        CGINCLUDE
        half4 _Color;
        float4 vert(float4 vertex : POSITION) : SV_POSITION
        { 
            return UnityObjectToClipPos(vertex);
        }
        half4 frag() : SV_Target
        {
            return _Color;
        }
        ENDCG

        Pass
        {
            // 第1パスでは画面上に色は塗らず、ステンシルの構築だけを行う
            ColorMask 0
            ZWrite Off

            // 前面・背面両方について処理を行う
            Cull Off

            // すでに描画された不透明オブジェクト表面のうち、このオブジェクトに
            // 包まれている領域がステンシル値1になるようにする
            Stencil
            {
                ZFailFront DecrWrap
                ZFailBack IncrWrap
            }
        
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            ENDCG
        }
        Pass
        {
            Cull Front
            ZTest Always
            ZWrite Off
            Blend SrcAlpha OneMinusSrcAlpha

            // 第2パスで、ステンシル値が0でない領域にだけ色を塗る
            Stencil
            {
                Ref 0
                Comp NotEqual
            }
        
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            ENDCG
        }
    } 
}

下図のような見え方になりました。

Comments

[kkk]

ありがとうございます、無事解決しました。
シェーダー使うのが初めてなので理解があまりできてないですが・・・
頑張って勉強をして理解してみます。