Arduino IDE 割り込み で-1をかける方法以外があればご教授ください。

Question

前提・実現したいこと

皆様、アイデアをお願いいたします。

点滅など、delayが継続している途中で、割り込みができて、違う動作をさせたいと考えています。
試行錯誤して、スイッチが押される毎に、aに-1をかけて、+と-ごとに動作を変える方法を考えました。
以下は、1の時は消灯が長いLED９と、-1の時は点灯が長いLED9というif文のサンプルです。

しかし、この割り込みは、小学生と扱って行きたいのです。
実は、-1は中学生で習うので　-1を使わない方法を探しています。
もし、アイデア等があれば、皆様ご教授を頂ければと思います。
よろしくお願いいたします。

該当のソースコード

int a;
void setup() {
  pinMode(9, OUTPUT);
  attachInterrupt(0, blink, FALLING); //割り込み用 0=2番ピンでblink発動
  Serial.begin(9600); //変数の値を表示
  a=1;
}
void loop() {
  Serial.println(a);
if(a==-1){
  digitalWrite(9,HIGH);
  delay(800);
  digitalWrite(9,LOW);
  delay(100);
}
if(a==1){
  digitalWrite(9,HIGH);
  delay(100);
  digitalWrite(9,LOW);
  delay(800);
}
}
void blink() {　//押される度に -1をかけることで、aが1と-1になる
  a=a*(-1);
}

試したこと

2番ピンの割り込み用スイッチが押される毎に、aに-1がかけられ、1と-1の値ごとに、光り方が変わります。

補足情報（FW/ツールのバージョンなど）

ここにより詳細な情報を記載してください。

Answer 1

小学校3年生で剰余、つまり割り算のあまりを習うはずなので、%演算子を使うのもいいと思います。

• 小学校学習指導要領　174ページほか

たとえば、割り込みで呼ばれる側で

a = a + 1;
a = a % 2;

と記述すれば、aがとりうる値は0か1のいずれかです。

ちなみに、上の二行はもっともっと簡素に書けますが、小学生でも理解できるようにあえて冗長に書いています。

剰余を使った計算というのは意外に多いのですが、その便利さに気づかないまま「こんなん何に使うの」で終わっているのも事実だと思いますので、振り返りの良い機会になるのではないでしょうか。

• Qiita 余り(剰余)の性質をプログラムに活かす

Comments

[norisans]

TsukubaDepot様
0を代入すれば、
0+1→1
1%2→1

1を代入すれば
1+1→2
2%2→0

なんと！！！凄い。
紹介いただいた剰余のページも眼から鱗の事ばかり。。

これもいけそうですね！！ご教授ありがとうございます！

[TsukubaDepot]

方法はひとつではないので、生徒さんの理解度や興味に応じて使い分けるのがいいのではないでしょうか。

Answer 2

true とfalse、あるいは１と０ではどうでしょう

a= !a;

あるいは

if(a==0) a=1;else a=0;

Comments

[norisans]

早速のお返事ありがとうございます。レスポンスが早くて驚いております。。
boolean型というやつですね。。実は使ったことがなかったので・・・。これは小学生でも使えそうですね！！
ありがとうございます！

[y_waiwai]

真と偽、そこからブール代数へと話を広げていきましょう

[norisans]

プログラムに導入したら、すぐに動きました!!!
boolean a=true;
としておいて、
割り込み時に
a=!aですね。
そして、if文で、trueとfalseで分けるという事で・・・
なんて簡単なのでしょうか！！ありがとうございます。

Answer 3

とりあえずやりたいことは出来たようなので余計なことを言うと、
-1よりも心配しなきゃいけないことが一杯ある気がします。

aなんていう変数名じゃなくて意味のある名前を使うこととか、
2つしか状態がないのならif()～else～で処理すべきじゃないかとか
似た処理をふたつならべることの是非とか
チャタリングへの対応とか

a=a*(-1);なんてことさえしなければ、小学生だって単純な負の数ぐらい聞きかじっているでしょうし

(そもそも私だったら割り込み使わないなぁ)

---

コメント頂きました。

今回想定しているのが、

①delayを使ってLEDの点滅を制御。歩行者信号機で、青点灯→点滅→赤 のような感じです。
②スイッチが押されたら、①の青点灯のdelayを待たずに割り込んで、点滅→赤
のようなプログラムなのですが、割り込みを使わないでできる方法があれば、教えてくださいませ。

とのことですので、サンプルを書きました。青点灯10秒->青点滅5秒->赤点灯10秒を繰り返します。それぞれの途中でボタンSWを押す(ピン-GND間短絡)と、時間を待たずに次の状態に遷移します。割り込みは使っていません。

const int BUTTON = 10;//ピンアサインは私の環境に合わせています。適宜変更して下さい
const int GREEN = 2;
const int RED = 3;

const int DLY_UNIT = 10;//1ループの時間(ミリ秒)
const int PERIOD_GREEN = 10 * 1000 / DLY_UNIT;//緑点灯期間(DLY_UNIT単位)
const int PERIOD_BLINK = 5 * 1000 / DLY_UNIT;//緑点滅期間
const int PERIOD_RED = 10 * 1000 / DLY_UNIT;//赤点灯期間
const int BLINK_CYCLE = 0.5 * 1000 / DLY_UNIT;//緑点滅周期
int count = 0; //時間を計るための変数
const int CHATFILTER = 100 / DLY_UNIT; //チャタリング除去時間
bool buttonHistory[CHATFILTER];//チャタリング除去のための履歴

enum STATUS { //LED状態変数
  STAT_GREEN,
  STAT_BLINK,
  STAT_RED
} stat;

void setup() {
  for (int i = 0; i < CHATFILTER; i++) {
    buttonHistory[i] = true;
  }
  pinMode(GREEN, OUTPUT);
  pinMode(RED, OUTPUT);
  pinMode(BUTTON, INPUT_PULLUP);
  stat = STAT_GREEN;
  Serial.begin(115200);
}

bool checkButtonOn() {//ボタンが「押された」ことを検出する
  static bool prevButton = true;
  bool currentButton = true;
  bool isButtonStable = true;
  bool ret = false;
  currentButton = digitalRead(BUTTON);
  for (int i = 1; i < CHATFILTER; i++) {
    if (currentButton != buttonHistory[i - 1]) {
      isButtonStable = false;
    }
    buttonHistory[i] = buttonHistory[i - 1];
  }
  buttonHistory[0] = currentButton;
  if (isButtonStable) {
    ret = prevButton != currentButton && prevButton;
    prevButton = currentButton;
  }
  return ret;
}

void loop() {
  bool green = false;
  bool red = false;
  bool isButtonTurnedOn = checkButtonOn();
  Serial.println(isButtonTurnedOn);
  switch (stat) {//状態によって動作を振り分ける
    case STAT_GREEN:
      green = true;//緑の点灯処理
      if (count > PERIOD_GREEN || isButtonTurnedOn) {//次に遷移する条件
        count = 0;//時間クリア
        stat = STAT_BLINK;//次の状態へ
      }
      break;
    case STAT_BLINK:
      green = (count / BLINK_CYCLE) & 1;
      if (count > PERIOD_BLINK || isButtonTurnedOn) {
        count = 0;
        stat = STAT_RED;
      }
      break;
    case STAT_RED:
      red = true;
      if (count > PERIOD_RED || isButtonTurnedOn) {
        count = 0;
        stat = STAT_GREEN;
      }
      break;
    default:
      stat = STAT_GREEN;
  }
  digitalWrite(RED, red);
  digitalWrite(GREEN, green);
  delay(DLY_UNIT);
  count++;
}

この程度のプログラムの場合、割り込みを使う使わないは本質ではありません。なんなら、ボタンの検出部分を割り込みを使ったものに置き換えるのも大した手間ではないでしょう。
要は、長時間のdelay()がプログラムの動作を阻害するので、それを短時間のdelay()の繰り返しに置き換えてやる、ということです。あるいは、細切れのdelay()ではなくmillis()を使って時間を計ってもいいですけれど、とにかく長時間のdelay()を使わないことですね。

Comments

[norisans]

thkana様 ありがとうございます。
aでなくとも、もちろん良いと思っております。必要に応じて、変数名は使い分けられればよいかと考えています。
ご指摘の中で教えていただきたいのが、
if elseのみで、delayなどで動作をさせるプログラムでの割り込みは可能でしょうか？？

今回想定しているのが、
①delayを使ってLEDの点滅を制御。歩行者信号機で、青点灯→点滅→赤 のような感じです。
②スイッチが押されたら、①の青点灯のdelayを待たずに割り込んで、点滅→赤
のようなプログラムなのですが、割り込みを使わないでできる方法があれば、教えてくださいませ。

[thkana]

> aでなくとも、もちろん良い
aは良くない、というつもりだったのですが伝わりませんでしたか...「動けばいい」ではなく、ソースリストもドキュメントの一部という考えから、変数名は(関数名等、その他のシンボルも)「名が体を表す」ようにすべきです。

> ご指摘の中で教えていただきたいのが、
それ以外のこともちゃんと伝わっているのか不安ですが...

> if elseのみで、delayなどで動作をさせるプログラムでの割り込み
すみません、文章に書いてあることが読み取れません。
私が書いた回答でif()～else～云々と言っているのは、質問のプログラムが
if(条件A)
if(!条件A)
という構造になっていることへの指摘で、その部分にはdelayとか割り込みは関係しません。

if()～ else～とdelayと割り込みのどのような関わり方について知りたいのでしょうか。

> 今回想定しているのが
プログラムに関わるので、回答を編集して記載します。

[norisans]

thkana様
> aでなくとも、もちろん良い
aは良くない、というつもりだったのですが伝わりませんでしたか...「動けばいい」ではなく、ソースリストもドキュメントの一部という考えから、変数名は(関数名等、その他のシンボルも)「名が体を表す」ようにすべきです。
→なるほど。。「ドキュメントの一部」という意識はあまりなかったので、きちんと名前をつけるようにします。ご教授ありがとうございます。

ご提示いただいたプログラムについて
→delayではなく、countの積み重ねをする中で、ボタンが押されたどうかの判定を受け付けるという事ですね。

私自身もロボコンなどに出る時にcount等を使うのでdelayの使いにくさはご指摘いただき、さらに納得です。
様々ありがとうございました。