unity 雲の上のステージを作るアイデアをください。

Question

実現したいこと

写真のような雲の上のステージを雲の動きも付けて作りたいです。

試したこと

skyboxを回してみたが太陽も回ってしまいダメだった。skyboxを雲と空、二つ適応することはできなかった。

試そうとしてること

雲と空を分けてskyboxのような感じで表示したい。
###教えていただきたいこと
どうすれば、写真のようなステージを作れるか。
試そうとしていることはどうすればできるか。

初心者なので、どんな回答でもありがたいです。よろしくお願いします。

###途中経過
Bongoさんから教えていただいた方法で上空の雲を動かすことができました。ありがとうございます。
下の雲はパーティクルで作ってみようと思います。

Answer 1

私からも一案として、ご質問者さんの「空と雲の2つのスカイボックス」のアイディアを検討してみました。
以前見かけました他の方のご質問に「Unityのシェーダーで、透明部分が黒く表示されてしまう。」というものがあり、この時と同様に2つのカメラを用意してやって、それぞれが空背景・雲背景を担当するようにできるかもしれないと考えました。

まず、雲担当のスカイボックスは半透明に対応する必要があるでしょうが、デフォルトのスカイボックス用シェーダーはアルファを無視するようです。そこでビルトインシェーダーをコピーして一部改変したものを用意することにしました。
DefaultResourcesExtra/Skybox-Cubed.shaderをベースに、ファイル名をSkybox-Alpha.shaderとして下記部分を変更しました（コード中にコメントを入れた部分）。

// Unity built-in shader source. Copyright (c) 2016 Unity Technologies. MIT license (see license.txt)

// 区別がつくようにシェーダー名を変更
Shader "Skybox/Cubemap (Alpha)" {
Properties {
    // アルファも利用するようにしたのに合わせ、_Tintのデフォルトのアルファを1に変更
    _Tint ("Tint Color", Color) = (.5, .5, .5, 1)
    [Gamma] _Exposure ("Exposure", Range(0, 8)) = 1.0
    _Rotation ("Rotation", Range(0, 360)) = 0
    [NoScaleOffset] _Tex ("Cubemap   (HDR)", Cube) = "grey" {}
}

SubShader {
    Tags { "Queue"="Background" "RenderType"="Background" "PreviewType"="Skybox" }
    Cull Off ZWrite Off

    Pass {
        // Blend指定を追加
        Blend SrcAlpha OneMinusSrcAlpha

        CGPROGRAM
        #pragma vertex vert
        #pragma fragment frag
        #pragma target 2.0

        #include "UnityCG.cginc"

        samplerCUBE _Tex;
        half4 _Tex_HDR;
        half4 _Tint;
        half _Exposure;
        float _Rotation;

        float3 RotateAroundYInDegrees (float3 vertex, float degrees)
        {
            float alpha = degrees * UNITY_PI / 180.0;
            float sina, cosa;
            sincos(alpha, sina, cosa);
            float2x2 m = float2x2(cosa, -sina, sina, cosa);
            return float3(mul(m, vertex.xz), vertex.y).xzy;
        }

        struct appdata_t {
            float4 vertex : POSITION;
            UNITY_VERTEX_INPUT_INSTANCE_ID
        };

        struct v2f {
            float4 vertex : SV_POSITION;
            float3 texcoord : TEXCOORD0;
            UNITY_VERTEX_OUTPUT_STEREO
        };

        v2f vert (appdata_t v)
        {
            v2f o;
            UNITY_SETUP_INSTANCE_ID(v);
            UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(o);
            float3 rotated = RotateAroundYInDegrees(v.vertex, _Rotation);
            o.vertex = UnityObjectToClipPos(rotated);
            o.texcoord = v.vertex.xyz;
            return o;
        }

        half4 frag (v2f i) : SV_Target
        {
            half4 tex = texCUBE (_Tex, i.texcoord);
            half3 c = DecodeHDR (tex, _Tex_HDR);
            c = c * _Tint.rgb * unity_ColorSpaceDouble.rgb;
            c *= _Exposure;

            // 出力する色のアルファ成分を_Texと_Tintの積にする
            return half4(c, tex.a * _Tint.a);
        }
        ENDCG
    }
}


Fallback Off

}

メインカメラの子としてもう一つカメラを作り、子カメラはCulling MaskをNothing、Depthを-2とし、これにベースとなる背景を担当させることにしました。Audio Listenerも削除しています。

一方、メインカメラのCameraコンポーネント自体の設定は特にいじらず、Skyboxコンポーネントを追加して、これに上記の半透明キューブマップシェーダーを使ったマテリアルをセットしました。

この状態で前景側（背景なのに前景というのは変ですが、つまり雲側です）のマテリアルのRotationを操作して回してみると、下図のような描画結果になりました。前景だけが回っていることをアピールするため、テクスチャは派手なタイル模様にしています。

ですがこの方式だと雲は無限遠にあるようなものですので、立体感には乏しいかもしれません。ha_wnさんやnskydivingさんの案のように三次元の雲にすればリアリティがありそうですし、雲を突き抜けて飛ぶような表現も可能そうですね。

Comments

[ryo0o0o]

わざわざやり方まで示してくださりとても参考になりました。ありがとうございます。組み合わせてやってみようと思います。

Answer 2

標準機能であれば他の方の回答が良い方法だと思いますが、優れたアセットがある場合、それに頼るのも手です。

雲の場合、私はMassive Cloudsをお勧めしてます。有料アセットですが30ドルてすし、セールなら半額近くに下がることも。

Massive Clouds

レイマーチングによる高品質なボリュームシャドウが、古いものから最新のUniversal RPまでUnityのレンダリングシステムにきちんと対応してます。
お尋ねの動く雲は標準で備わってますし、雲のレイヤー積み重ねたり、擬似的な大気表現などにも使えます。また負荷と品質のバランスがとりやすく、モバイルでも十分動きます。

作者が日本人なので、日本語で質問投げられるのも気軽で良いです。

Comments

[ryo0o0o]

パーティクルでは限界があったので、massive clouds試してみます。ありがとうございます。

[neran]

旧来のレンダリングシステムからHDRPまで対応している素晴らしいアセットですが、それぞれ導入方法が違います。

旧来のレンダリングシステムならカメラコンポーネントやPPS、URPならRenderer Features、HDRPならCustom Passなどなど。日本語の丁寧なマニュアルがあります。

残念ながらサンプルシーンは旧来のレンダリングシステムでしかそのままでは完全に表示されないので、新規の3Dプロジェクトを作成して試した方が良いです。

Answer 3

あまり難しく考えず、Terrain やポリゴンモデルでは実現できないでしょうか。

Comments

[ryo0o0o]

回答ありがとうございます。試してみます。

Answer 4

1.パーティクルで雲を発生させて敷き詰める
2.ボリュームレンダリングを使って雲を作る

初心者であれば1が良いかと思います。

Comments

[ryo0o0o]

回答ありがとうございます。大変参考になりました。他の方のアイデアと組み合わせて、作ってみようと思います。