プログラムのエラー場所について

Question

今、VBAで任意の範囲にあるデータをコピーする関数を作っています。
以下がそのプログラムです。

Function コピー関数()
Dim input_rg As Range
Dim output_rg As Range
Set input_rg = Application.InputBox("コピーするセルを選択してください", Title:="入力フォーム", Type:=8)
Set output_rg = Application.InputBox("貼り付け先を選択してください", Title:="出力フォーム", Type:=8)

If input_rg = False Or output_rg = False Then
    End
End If

input_rg.Copy Destination:=output_rg


End Function

これを実行すると、「型が一致しません」というエラーを吐き出します。
場所は[Set input_rg = Application.InputBox("コピーするセルを選択してください", Title:="入力フォーム", Type:=8)]の場所です。

このエラーメッセージを受けて
以下の様にしました。

１．イミディエイトウィンドウでセルのアドレスと型を調べました。
?input_rg.address
$C$3:$F$3
?typename(input_rg)
Range
?typename(output_rg)
Range
?output_rg.address
$C$10:$F$10

２．型をrange型からVariant形に変更しましたが、同じエラーを吐き出します。

回答の程、宜しくお願いします。

回答を受けて
まず、回答ありがとうございます。コメント欄に書こうか迷ったのですが、長文になりそうなのでこちらに書かせていただきます。

回答をいただいて、改めて実行した所、エラーを吐き出すことなく実行できました。
ただ、applicationのinputboxのダイアログボックスでキャンセルを選択すると、再び[型が一致しません]というエラーを吐き出します。
調べたところ、inputboxのキャンセルの戻り値はFalseらしいです。
回答を頂いて恐縮ですが、この点を踏まえて、再度回答をしていただけると嬉しいです。

Comments

[imihito]

追記の部分はよくある話なので、検索すれば何かしら見つかったと思います。
最近のteratail内だと以下の質問とかですね。
inputboxメソッドでセルを指定させる際のキャンセル対策
https://teratail.com/questions/200242

[bonji]

回答ありがとうございます。
紹介してくださったリンクに自分が知りたい情報が全て載っていました。
今度からは、こちらで調べてから質問させていただきます。

[imihito]

解決したようで何よりです。
であれば、どなたかの回答をベストアンサーとして選んで、質問を「解決済み」にしてあげて下さい。

Answer 1

エラー箇所ですが、本当にそこですか。当方でテストしてみたところ、そこはエラーなく通過しました。

が、

If input_rg = False Or output_rg = False Then 'ここでエラー
    End
End If

でエラーになりました。

オブジェクトの有無は、Is Nothing で判定します。
下記に修正したらエラーなく実行できました。

    If input_rg Is Nothing Or output_rg Is Nothing Then
        Exit Function
    End If

キャンセルに対応するコード

Function コピー関数() As Boolean
    Dim input_rg As Range
    Dim output_rg As Range
    
    コピー関数 = False
    On Error Resume Next
    Set input_rg = Application.InputBox("コピーするセルを選択してください", _
                                        Title:="入力フォーム", Type:=8)
    If Err.Number <> 0 Then
        MsgBox "キャンセルされました。"
        Exit Function
    End If
    Set output_rg = Application.InputBox("貼り付け先を選択してください", _
                                         Title:="出力フォーム", Type:=8)
    If Err.Number <> 0 Then
        MsgBox "キャンセルされました。"
        Exit Function
    End If
    
    If input_rg Is Nothing Or output_rg Is Nothing Then
        Exit Function
    End If
    input_rg.Copy Destination:=output_rg
    If Err.Number = 0 Then
        コピー関数 = True
    End If
End Function

せっかく Function にしているので、コピーに成功したかどうかを返す仕様にしてみました。

おまけ

質問のコードではEndで関数を終了させようとしてますが、通常は、Exit Functionで関数から抜けるようにします。
ちがいは、End は実行中のマクロを完全に終了させますが、Exit Functionは関数から抜けた後、次のコードがあればそれは実行されます。違いを意識して使い分けるようにすべきでしょう。

参考コード

Sub hoge()
    Debug.Print "hoge"
    Exit Sub
End Sub

Sub fuga()
    Debug.Print "fuga"
    End
End Sub

Sub hogefuga()
    Call hoge
    Debug.Print "hageの次"

    Call fuga
    Debug.Print "fugaの次"
End Sub

イミディエイトウィンドウ

hoge
hageの次
fuga

Comments

[bonji]

回答ありがとうございます。
Endの使い分けの仕方は知りませんでした。有益な情報ありがとうございます。
End functionに修正します！

Answer 2

＜再回答＞
想定されるエラーでキャンセルを判定する方法を考えてみました。

Function コピー関数()
    Dim input_rg As Range, output_rg As Range
    
    On Error GoTo myErr
    Set input_rg = Application.InputBox("コピーするセルを選択してください", Title:="入力フォーム", Type:=8)
    Set output_rg = Application.InputBox("貼り付け先を選択してください", Title:="出力フォーム", Type:=8)
    On Error GoTo 0
    
    'hatena19さんの回答
    If input_rg Is Nothing Or output_rg Is Nothing Then
        Exit Function
    End If
    input_rg.Copy Destination:=output_rg
    
myErr:
    If Err.Number = 424 Then
        MsgBox "キャンセルされました。"
        Err.Clear
    Else
        Err.Raise Err.Number
    End If
End Function

＜以下回答は、キャンセルボタンでエラーとなり、解決できていませんでした。＞
Inputboxのキャンセルの戻り値はFalseなので、Range型ではエラーとなります。
好みでないかもしれませんが、Variant型とすればキャンセルを判定する方法があります。

Function コピー関数()
'キャンセル判定のためにVariant型とする
Dim input_vt As Variant, output_vt As Variant
Set input_vt = Application.InputBox("コピーするセルを選択してください", Title:="入力フォーム", Type:=8)
Set output_vt = Application.InputBox("貼り付け先を選択してください", Title:="出力フォーム", Type:=8)

'キャンセルの判定
If VarType(input_vt) = vbBoolean Or VarType(output_vt) = vbBoolean Then
    Exit Function
End If

'hatena19さんの回答
If input_vt Is Nothing Or output_vt Is Nothing Then
    Exit Function
End If

input_vt.Copy Destination:=output_vt

End Function

Comments

[hatena19]

キャンセルで False が返った場合、Set しているところでエラーになりませんか。

[TanakaHiroaki]

'hatena19さん、ご指摘ありがとうございます。
以下のエラーが出ました。
　実行時エラー '13':
　型が一致しません。

私なりに修正してみます。

[bonji]

回答ありがとうございます。