inputboxメソッドでセルを指定させる際のキャンセル対策

Question

InputBoxメソッドでセルを指定させる目的の、以下のコードについて質問です。

Public Sub test()
    Dim outputcell As Variant
    
    'セル取得
    outputcell = Application.InputBox("セルを選択してください", , , , , , , 8)
    If outputcell = False Then
        MsgBox False
        Exit sub
    End If

    outputcell.value = "セル取得成功"
    
End Sub

InputBoxメソッドの引数Typeに8を設定し、セル参照（Rangeオブジェクト）のみを入力可能にしています。
キャンセルを押されたときのことを考え、変数outputcellをVariant型にしました。

これを実行すると、セルを指定してもキャンセルを押してもoutputcellにfalseが入ってしまいます。

因みに、引数Typeに12（論理値またはセル参照）を設定すると、論理値しか指定できなくなってしまいました。

適切な値を得るには、どうしたらよいのでしょうか。

Answer 1

んと、、、

https://www.moug.net/tech/exvba/0150102.html
http://officetanaka.net/excel/vba/tips/tips37.htm

この辺を参考にすると、
セル範囲を変数に代入するときは、
Setステートメントを使用しなければなりません。
単に変数の型をVariant型にするだけでは、
「オブジェクト」を変数に代入できません。

つまり、Set outputcell = Application.InputBox("セルを選択してください", , , , , , , 8)
こうかかないといけません。
が、キャンセルを押すと、Falseという論理値が返ってくるので、
エラーになりますよね。
両方に対応するのは厄介ですね。

こういうときは、
On Errorステートメントを使い、エラーを回避します。

エラーを無視したときは、
変数の中身はNothingのままですので、
変数の中身がNothingかどうかで、キャンセルが押されたかの判定をします。

Option Explicit

Public Sub test()
    Dim outputcell As Range

    Application.DisplayAlerts = False   '空でOKしたときの的外れなメッセージの表示を抑制
    On Error Resume Next
    Set outputcell = Application.InputBox("セルを選択してください", , , , , , , 8).Cells
    On Error GoTo 0
    Application.DisplayAlerts = True
    
    If outputcell Is Nothing Then
        MsgBox "キャンセルしました。"
    Else
        outputcell.Select
        MsgBox outputcell.Address(False, False) & "　を選択しました。"
    End If
End Sub

Answer 2

VBAの「値型とオブジェクト型で代入の方法が異なる」という仕様の関係上、きれいに処理することは難しいです。

またVarType関数についても、仕様上今回の用途では使いにくいです。

---

対策案1 エラーで判定

キャンセルを考慮せず、セル(オブジェクト)が返されるという前提で処理を行い、
エラーが発生したらキャンセルされた、と判断する方法です。
恐らくこちらの方が一般的な方法だと思います。

On Error Resume Nextによって、代入時のエラーに対して処理を行っています。

'https://teratail.com/questions/200242
Public Sub teratailQ200242_OnError()
    Const XlInputBoxTypeRange = 8
    
    Dim outputcell As Excel.Range
    
    'セル取得
    On Error Resume Next
        Set outputcell = Application.InputBox("セルを選択してください", Type:=XlInputBoxTypeRange)
        'キャンセルされた場合はBooleanが返ってくるので
        'エラー番号91:オブジェクト変数または With ブロック変数が設定されていません。
        'のエラーが発生する
        If Err.Number <> 0 Then
            MsgBox False
            Exit Sub
        End If
    On Error GoTo 0
    
    outputcell.Value = "セル取得成功"
    
End Sub

---

対策案2 結果で判定

「値型とオブジェクト型で代入の方法が異なる」という仕様

に関しては、代入部分を別プロシージャに切り出し、参照渡しの引数を使うことでむりやり対処することができます(例:下記コードSetVar)。

結果を変数に入れてしまえば、後は普通に判定するだけ、となります。

この判定のときの注意として、
If inputBoxResult = False Thenとした場合、セルの値が0、空(Empty)、Falseの場合もNGになってしまいますし、エラー値や複数セル選択の場合はエラーで止まってしまいます。

If VarType(inputBoxResult) = vbBoolean Thenとした場合、VarType関数は既定のメンバーの値を見に行くため、セルにFalseが入っている場合もNGとなってしまいます。

そのため下記コードでは「Object型に適合するかどうか？」の判定関数であるIsObjectを使って判定しています(VBAのほとんどのオブジェクトはObject型に適合し、ExcelのRangeもそうであるため)。

'https://teratail.com/questions/200242
Public Sub teratailQ200242_NotOnError()
    Const XlInputBoxTypeRange = 8
    
    'セル or Flase 取得
    Dim inputBoxResult As Variant
    SetVar(inputBoxResult) = Application.InputBox("セルを選択してください", Type:=XlInputBoxTypeRange)
    
    If Not VBA.IsObject(inputBoxResult) Then
        MsgBox False
        Exit Sub
    End If
    
    Dim outputcell As Excel.Range
    Set outputcell = inputBoxResult
    
    outputcell.Value = "セル取得成功"
    
End Sub

'https://qiita.com/nukie_53/items/bde16afd9a6ca789949d#%E5%A4%89%E6%95%B0%E3%81%B8%E4%BB%A3%E5%85%A5
Public Property Let SetVar(outVariable As Variant, inExpression As Variant)
    If VBA.IsObject(inExpression) Then
        Set outVariable = inExpression
    ElseIf VBA.VarType(inExpression) = vbDataObject Then
        Set outVariable = inExpression
    Else
        Let outVariable = inExpression
    End If
End Property

Answer 3

セル取得以外の場合は TanakaHiroakiさんの回答でいいのですが、
セル取得(Type引数が8)の場合はそれではダメです。
エラー処理で判断します。

Public Sub test()
    On Error Resume Next
    Dim outputcell As Range
    'セル取得
    Set outputcell = Application.InputBox("セルを選択してください", Type:=8)
    If Err.Number <> 0 Then
        MsgBox "キャンセルされました。"
        Exit Sub
    End If
    On Error GoTo 0
    outputcell.Value = "セル取得成功"
End Sub

Answer 4

＜回答後追記＞
複数の方から、今回の質問、つまり、Application.InputBoxでセル取得(Type引数が8)の場合、キャンセルを判定するために、単にVBAのVarType関数を用いるだけでは不可能であるとのご指摘をいただきました。
下記回答を撤回します。

キャンセルについては、以下のように、VarTypeで判定する方法があります。

'    If outputcell = False Then
    If VarType(outputcell) = vbBoolean Then
        MsgBox False
        Exit Sub
    End If