VBA 文字化けの半角「?」を全角「？」で表示させたい(vbWide関数やreplace関数ではダメでした)

Question

VBAで文字化けする場合、半角「?」で表示されるのですが
全角「？」で表示できるようにする方法はありますか？

例えば↓のように、セル1,1に「你」という文字が入っている場合でDebug.prrintすると
イミディエイトウィンドウに半角「?」が表示されます。

Sub moji()
    Dim s As String
    s = Cells(1, 1).Value
    Debug.Print s
End Sub

これを半角「?」ではなく全角「？」で表示したくReplace関数を使ったり、

s = Replace(s, "?", "？")

半角「?」が含まれている場合、vbWide関数で文字列を全角にする
という処理を入れたのですが、イミディエイトウィンドウに表示されるのは
どちらも半角「?」のままでした。

Sub moji()
    Dim s As String    
    s = Cells(1, 1).Value    
    If s Like "*[?]*" Then
        MsgBox "文字化けしている"
        s = StrConv(s, vbWide)
    End If
    Debug.Print s
End Sub

半角「?」を全角「？」に変換する方法をご存じでしたら教えてください。

セル1,1が文字化けする文字ではなく
半角「?」そのもの文字が入っている場合では
vbWide関数やreplace関数で全角「？」に変換されました。

「你」等、VBAでは文字化けする文字が入っている場合でも
半角「?」ではない全角の文字に変換する方法を教えていただければ幸いです。

※半角「?」ではなく全角の任意の文字で表示したいので
全角「？」ではなく「もじばけ」「全角」などの文字でも構いません。

よろしくお願いします。

Answer 1

回答も含めていろいろ勘違いがあるようです。

まずはVBAでの文字列は、最近のバージョンではUnicodeです。
古いバージョンはShif_JISでしたが、たしかOffice2000ぐらいのときにUnicodeになりました。

ですので基本的には「你」のようなShif_JISにないUnicode文字でも文字化けすることなく扱えます。

ただし、最新バージョンでも VBE(Visual Basic Editor)はShif_JISのままですので、Shif_JISにないUnicode文字はVBE上で表示すると文字化けします。

ですので、Debug.Print でイミディエイトウィンドウへの出力では本当に文字化けしているかどうか確認できません。
エクセルのセルはUnicodeですので、セルに出力して確認するようにしましょう。

また、一部の関数でUnicode対応していないものがあります。質問のコードの StrConv もUnicode対応してないもののひとつです。

下記のコードを実行してみてください。

Sub mojiTest()
    Dim s As String
    s = Cells(1, 1).Value
    If s Like "*[?？]*" Then
        MsgBox "代入のみ: 文字化けしている"
    End If
    Cells(2, 1).Value = s
    
    s = StrConv(s, vbWide)
    If s Like "*[?？]*" Then
        MsgBox "StrConv: 文字化けしている"
    End If
    Debug.Print s
    Cells(3, 1).Value = s
End Sub

String型変数に代入しただけでは文字化けせずに、StrConv で文字化けしているのが確認できます。

StrConv以外の他の関数でも確認してみてください。例えば、Replace関数では文字化けしません。

下記も参考にしてください。

VBA - Excelのセル内フォルダパス取得時、パスに含まれている全角文字「〜」が半角文字「?」に変化してしまう｜teratail

VBA - VBAで®と™を一括置換したい｜teratail

VBA - VBAで機種依存文字を含んだ文字列をifの条件とする｜teratail

追記

質問のコードの間違いをコメントしておきます。

Sub moji()
    Dim s As String    
    s = Cells(1, 1).Value
    'この時点でsの中身は文字化けしていない。  
    If s Like "*[?]*" Then 'よってこれはFalseになり
        MsgBox "文字化けしている"
        s = StrConv(s, vbWide) 'は実行されない。 
    End If
    Debug.Print s 'イミディエイトウィンドウ出力時に文字化けする。
   '以下確認用
   Cells(1, 1).Value = s '文字化けしていない
End Sub

Comments

[退会済みユーザー]

回答ありがとうございました。

Answer 2

文字化けする文字を■に変換した文字列を返却します。
Shif_JISに無い文字の場合は、Asc関数の戻り値は?(63)のようなので
それを利用しています。

Function convert(s As String) As String
    Dim ret As String
    ret = ""
    Dim i As Long
    For i = 1 To Len(s)
        Dim tmp As String
        tmp = Mid(s, i, 1)
        If Asc(tmp) = 63 Then
            ret = ret + "■"
        Else
            ret = ret + tmp
        End If
    Next i
    convert = ret
End Function

Comments

[退会済みユーザー]

回答ありがとうございました。

[hatena19]

質問に対する回答としては適切でないと思います。
「Shif_JISに無い文字の場合」は文字化けするという前提の回答ですが、通常は文字化けしません。
また、このような関数を使わなくても、Replace(s, "?", "■") でまったく同じことができます。

[Zuishin]

Debug.Print で文字化けするという話ではありませんか？
ならば Replace では無理ではないかと思いますが。

[hatena19]

イミディエイトウィンドウは「「Shif_JISに無い文字」に非対応ですが、変数の中身自体は文字化けしていません。
ですので、この質問の関数でも、Replace でも同じ結果です。
文字化けしているかどうかを Debug.Print で判断するのは無意味というのが私の回答です。

[Zuishin]

変数の中身自体は文字化けしていないので、Replace では無理でしょう。
Debug.Print で文字化けする文字、つまり Shift_JIS に変換できない文字を前もって？にしたいという質問だと思います。その文字の判別に Asc 関数を使うのは理にかなっていると思いますが。

[Zuishin]

ただこの回答だと、もともとの ? も変換してしまいそうなので、それが意図していないものなら対応しなければいけないように思います。

[hatena19]

質問が「Shif_JISに無い文字」の判別ということなら、この回答でOKですね。
そうだとしたら、質問の「VBAで文字化けする場合」という表現が適切でないように思います。

[otaks]

If Asc(tmp) = 63 Then
は、
If Asc(tmp) = 63 And tmp <> "?" Then
が正かもしれません

Answer 3

Asc(Cells(1, 1).Value)

上記が「63」を返す場合に全角の？を返すようにしてどうでしょうか？

エクセルの神髄

Comments

[退会済みユーザー]

回答ありがとうございました。