VBAで機種依存文字を含んだ文字列をifの条件とする

Question

前提・実現したいこと

原セル（プルダウン方式にしている）からコピー＆ペーストしても文字化けして完全に一致しないのか、r7の値が確実に0になります。
If文の条件に㎠を使いたいのですが、どうすればいいですか?

該当のソースコード

?の所に㎠を入れる予定です。

If Range("C7") = "（0）なし" Then
  r7 = 0
  ElseIf Range("C7") = "（6）4?未満" Then
  r7 = 6
  ElseIf Range("C7") = "（9）4?以上16?未満" Then
  r7 = 9
  ElseIf Range("C7") = "（12）16?以上36?未満" Then
  r7 = 12
  ElseIf Range("C7") = "（24）36?以上" Then
  r7 = 24
End If

補足情報（FW/ツールのバージョンなど）

microsoft Visual Basic for Aplication 7.0を使用しています。

Answer 1

解決済みですが、参考までに。

VBAのString型は、Office2000以降は Unicodeになってます。
ところが、VBE（コード入力画面）は、いまだに Shift-JIS のままなのです。

ですので、㎠ のようなUnicodeにはあるがShift-JISない文字は、入力しても?に文字化けします。

解決済みの回答では、独自の関数を使って解決していますが、標準でUnicode文字を表現する関数が用意されてます。

例えば、 ㎠ を表現するには、ChrW関数を使って、ChrW(13216) とします。
13216 という文字コードを調べるには、AscW関数を使います。
A1セルに ㎠ を入力して、イミディエイトウィンドウで、
?AscW(Range("A1"))
と入力してEnterキーを押せば 13216 が出力されます。

また、質問のコードですが、同じセルを何度も参照するのは無駄なので，Select Case を使うとシンプルになります。

    Dim cm2 As String    
    cm2 = ChrW(13216)
    
    Select Case Range("C7").Value
    Case "（0）なし" 
        r7 = 0
    Case Replace("（6）4?未満", "?", cm2) 
        r7 = 6
    Case Replace("（9）4?以上16?未満", "?", cm2) 
        r7 = 9
    Case Replace("（12）16?以上36?未満", "?", cm2) 
        r7 = 12
    Case Replace("（24）36?以上", "?", cm2) 
        r7 = 24
    End Select

別案

対象文字列と結果を比べてみると、（ ）内の数値を取り出しているようなので、下記のようなコードでもよさそうです。

    Dim s As String
    s = Range("C7").Value

    If s Like "（#）*" Then
        R7 = Val(Mid(s,2,1))
    ElseIf s Like "（##）*" Then
        R7 = Val(Mid(s,2,2))
    End If

補足

thom.jpさんの回答のリンク先でNBSP(ノーブレークスペース)を通常の半角スペースに変換する自作関数が紹介されていますが、NBSPは、ChrW(160)で表現できます。ということで、
Replace(Range("A1").Value, ChrW(160)," ")
で変換できます。

Comments

[thom.jp]

知りませんでした！すばらしい。
早速ブログ追記します。

Answer 2

Byte型配列を利用すると、実現できます。
以下を試してみてください。

サンプル

Sub Main()
    If Range("C7") = "（0）なし" Then
      r7 = 0
      ElseIf ReplaceCM2(Range("C7")) = "（6）4<CM2>未満" Then
      r7 = 6
      ElseIf ReplaceCM2(Range("C7")) = "（9）4<CM2>以上16<CM2>未満" Then
      r7 = 9
      ElseIf ReplaceCM2(Range("C7")) = "（12）16<CM2>以上36<CM2>未満" Then
      r7 = 12
      ElseIf ReplaceCM2(Range("C7")) = "（24）36<CM2>以上" Then
      r7 = 24
    End If
    MsgBox r7
End Sub

Function ReplaceCM2(target_string) As String
    Dim CM2(0 To 1) As Byte
    CM2(0) = 160
    CM2(1) = 51
    ReplaceCM2 = Replace(target_string, CStr(CM2), "<CM2>")
End Function

解説

VBAにおけるString型は、内部ではバイト型配列として扱われます。2バイトで1文字です。

A1セルに㎠を入力して以下のコードを試すと、0バイト目と1バイト目の数値が取れますので、あとはそのバイトを使ってバイト型配列で文字"㎠"を作成し、"<CM2>"に変換させたのが上記のコードです。

Sub FindBytes()
    Dim targetChar As String
    targetChar = Left(Range("A1"), 1)
    Dim bytes() As Byte
    bytes = targetChar
    Dim i As Long
    For i = LBound(bytes) To UBound(bytes)
        Debug.Print "bytes(" & i & "):" & bytes(i)
    Next
End Sub

手前味噌ですが、以下の記事で近いことをしてるのでどうぞ。
https://thom.hateblo.jp/entry/2016/09/20/150650

Comments

[TanakaHiroaki]

VBAにおけるString型は、内部ではバイト型配列として扱われます。2バイトで1文字です。
よくわからなかったので、写経して実行すると、よく理解できました。