【Unity】自作の一部が透過するシェーダーで非透過部分のみ影を描画するようにしたい

Question

実現したいこと

タイトル通りです、高さによって一部を透過するシェーダーを作ったのですが、非透過部分のみ影が描画さえるようにしたいです。具体的にはStandardシェーダーのCutoutや以下の画像の左側のようにしたいです。

該当のソースコード

Shader "Custom/PartialTransparency-Height"
{
	Properties
	{
		_UpperColor ("Upper Color", Color) = (1,1,1,0)
		_UnderColor ("Under Color", Color) = (1,1,1,1)
		_MainTex ("Albedo (RGB)", 2D) = "white" {}
		_Glossiness ("Smoothness", Range(0,1)) = 0.5
		_Metallic ("Metallic", Range(0,1)) = 0.0
		_SeparationHeight ("Separation Height", Float) = 0.0
	}

	SubShader
	{
		Tags { "RenderType"="TransparentCutout" "Queue" = "AlphaTest" }
		LOD 200

		CGPROGRAM

		#pragma target 3.0
		#pragma surface surf Standard fullforwardshadows alpha:fade

		sampler2D _MainTex;

		struct Input {
			float2 uv_MainTex;
			float3 worldPos;
		};

		fixed4 _UpperColor;
		fixed4 _UnderColor;
		half _Glossiness;
		half _Metallic;
		float _SeparationHeight;

		void surf (Input IN, inout SurfaceOutputStandard o)
		{
			fixed4 c = tex2D (_MainTex, IN.uv_MainTex) * lerp(_UnderColor, _UpperColor, step(_SeparationHeight, IN.worldPos.y));
			o.Albedo = c.rgb;
			o.Metallic = _Metallic;
			o.Smoothness = _Glossiness;
			o.Alpha = c.a;
		}
		ENDCG
	}
	Fallback "Transprent/Cutout/Diffuse"
}

試したこと

http://tsumikiseisaku.com/blog/shader-tutorial-transparent/
このサイトを見て真似してみましたが上手くいきませんでした。

補足情報

Unity2019.1.4f1

Answer 1

そのような影を作るとなると、ShadowCasterパスもカスタマイズしてやる必要がありそうですね。
下記のような形はいかがでしょうか?

Shader "Custom/PartialTransparency-Height"
{
	Properties
	{
		_UpperColor ("Upper Color", Color) = (1,1,1,0)
		_UnderColor ("Under Color", Color) = (1,1,1,1)
		_MainTex ("Albedo (RGB)", 2D) = "white" {}
		_Glossiness ("Smoothness", Range(0,1)) = 0.5
		_Metallic ("Metallic", Range(0,1)) = 0.0
		_SeparationHeight ("Separation Height", Float) = 0.0
	}

	SubShader
	{
		Tags { "RenderType" = "TransparentCutout" "Queue" = "AlphaTest" }
		LOD 200

		CGPROGRAM

		#pragma target 3.0
		#pragma surface surf Standard fullforwardshadows alpha:fade

		sampler2D _MainTex;

		struct Input {
			float2 uv_MainTex;
			float3 worldPos;
		};

		fixed4 _UpperColor;
		fixed4 _UnderColor;
		half _Glossiness;
		half _Metallic;
		float _SeparationHeight;

		void surf(Input IN, inout SurfaceOutputStandard o)
		{
			fixed4 c = tex2D(_MainTex, IN.uv_MainTex) * lerp(_UnderColor, _UpperColor, step(_SeparationHeight, IN.worldPos.y));
			o.Albedo = c.rgb;
			o.Metallic = _Metallic;
			o.Smoothness = _Glossiness;
			o.Alpha = c.a;
		}
		ENDCG

		Pass
		{
			Name "ShadowCaster"
			Tags { "LightMode" = "ShadowCaster" }

			ZWrite On

			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag

			struct appdata
			{
				float4 vertex : POSITION;
				float2 uv : TEXCOORD0;
			};

			struct v2f
			{
				float4 pos : SV_POSITION;
				float2 uv : TEXCOORD0;
				float3 worldPos : TEXCOORD1;
			};

			v2f vert(appdata v)
			{
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				o.uv = v.uv;
				o.worldPos = mul(unity_ObjectToWorld, v.vertex);
				return o;
			}

			sampler3D _DitherMaskLOD;
			sampler2D _MainTex;
			fixed4 _UpperColor;
			fixed4 _UnderColor;
			float _SeparationHeight;

			fixed4 frag(v2f i) : SV_Target
			{
				// メイン描画部分と同様に透明度を求め...
				float alpha = tex2D(_MainTex, i.uv).a * lerp(_UnderColor.a, _UpperColor.a, step(_SeparationHeight, i.worldPos.y));
				
				// 透明度に応じて_DitherMaskLODから網掛け模様をサンプリングし...
				float alphaRef = tex3D(_DitherMaskLOD, float3(i.pos.xy * 0.25, alpha * 0.9375)).a;
				
				// シャドウマップを網掛け模様にすることで透明度に応じた影を作らせる
				clip(alphaRef - 0.01);
				
				// ShadowCasterパスではデプスがどうなるかが重要で、返す色はなんでもいい
				return 0.0;
			}
			ENDCG
		}
	}
	Fallback "Transprent/Cutout/Diffuse"
}

Comments

[Y0241-N]

完璧に理想通りです、Shadow Casterの部分が全く分からなかったので助かりました、ありがとうございます！