ImageのFillを中央からの距離で行いたい

Question

前提

ImageのFillを中央からの距離で行いたいです。

実現したいこと

• ImageのスプライトのFillを中央からの距離(円形)で行いたい

これを

マテリアルを保ったままこうしたい

内径(切り抜く大きさ)と外径(画像自体の大きさ)は時と場合によって変わるので予めテクスチャを加工しておく手段は使えません。
外径が500で内径が200だったり、外径が300で内径が183だったりします。

発生している問題・エラーメッセージ

MaskとUnmask( https://github.com/mob-sakai/UnmaskForUGUI )で画像の中央を切り落とそうとしましたが、Materialが設定されているとUnmaskが適用されません。

該当のソースコード

// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "Custom/2D/Dissolve"
{
    Properties {
        [PerRendererData] _MainTex ("Main texture", 2D) = "white" {}
        _DissolveTex ("Dissolution texture", 2D) = "gray" {}
        _Threshold ("Threshold", Range(0., 1.01)) = 0.
    }

    SubShader {

        Tags { "Queue"="Transparent" }
        Blend SrcAlpha OneMinusSrcAlpha

        Pass {

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            struct v2f {
                float4 pos : SV_POSITION;
                float2 uv : TEXCOORD0;
            };

            sampler2D _MainTex;

            v2f vert(appdata_base v) {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.uv = v.texcoord;
                return o;
            }

            sampler2D _DissolveTex;
            float _Threshold;

            fixed4 frag(v2f i) : SV_Target {
                float4 c = tex2D(_MainTex, i.uv);
                float val = tex2D(_DissolveTex, i.uv).r;

                c.a *= step(_Threshold, val);
                return c;
            }
            ENDCG
        }
    }
}

試したこと

MaskとUnmask( https://github.com/mob-sakai/UnmaskForUGUI )で画像の中央を切り落とそうとしましたが、Materialが設定されているとUnmaskが適用されないようで困っています。
ImageのFillをコントロールすることで画像を任意の形に加工できることはわかりましたが、水平、垂直、Radial360、Radial180、Radial90の5種類しかないため画像の中央からの距離でfillをコントロールする(円形に切り抜く)ことができません。
Fillを中央からの距離で行う方法はないでしょうか。

補足情報（FW/ツールのバージョンなど）

Windows 11 21H2
Unity 2021.3.11f1 Personal

Answer 1

Shaderのほうにスクリプトから半径情報を与えてあげて、内側を描画しないようにすることで解決しました。

// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "Custom/2D/Dissolve"
{
    Properties {
        [PerRendererData] _MainTex ("Main texture", 2D) = "white" {}
        _DissolveTex ("Dissolution texture", 2D) = "gray" {}
        _Threshold ("Threshold", Range(0., 1.01)) = 0.
        _InsideRadius ("Inside Radius", Range(0., 1.)) = 0.
    }

    SubShader {

        Tags { "Queue"="Transparent" }
        Blend SrcAlpha OneMinusSrcAlpha

        Pass {

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            struct v2f {
                float4 pos : SV_POSITION;
                float2 uv : TEXCOORD0;
            };

            sampler2D _MainTex;

            v2f vert(appdata_base v) {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.uv = v.texcoord;
                return o;
            }

            sampler2D _DissolveTex;
            float _Threshold;
            float _InsideRadius;

            fixed4 frag(v2f i) : SV_Target {
                float4 c = tex2D(_MainTex, i.uv);
                float val = tex2D(_DissolveTex, i.uv).r;

                i.uv -= fixed2(0.5, 0.5);
                if (distance(i.uv, fixed2(0, 0)) < _InsideRadius / 2.) {
                    discard;
                }

                c.a *= step(_Threshold, val);
                return c;
            }
            ENDCG
        }
    }
}