ターミナルでの文字列処理

Question

実現したいこと

awkでダブルクォーテーションとカンマで要素を区切って出力する
一番最後のカンマのみ削除する

前提

docker CentOS7
zshシェルで実行しています

出力

"root", "bin", "daemon", "adm", "lp", "sync", "shutdown", "halt", "mail", "operator", "games", "ftp", "nobody", "systemd-network", "dbus", "apache",

問題

一番最後のカンマのみ削除しようとしていますができませんでした。

該当のソースコード

cat /etc/passwd | awk -F':' "BEGIN{ORS = \" \"}{print \"\\\"\" \$1  \"\\\",\"}END{print " "}"

試したこと

インターネット上の情報などをもとに END 変数を追加しましたが求める効果がありませんでした

補足情報（FW/ツールのバージョンなど）

M1MAC
docker desktop Ver 4.21.1
CentOS7
zsh

Answer 1

passwdファイル程度のサイズなら、都度出力せず、変数にセットする手もあります。

cat /etc/passwd |
awk -F':' '{A=A ", \"" $1 "\""}END{print substr(A,3)}'

ギガバイト単位の保存は止めた方が良さそうですが。

Answer 2

一旦出力してしまったものは消せないので、ENDでなんとかするのは無理だと思います。

発想を変えて、「最初の項だけカンマを出力せず、その後は前に出力したものの後にカンマを出力してから項を出力する」ということにします。「"root"」、「, "bin"」、「, "daemon"」、……のように出力するということです。

一行で書くと見辛すぎるので、ソースファイルの形にします。

BEGIN {
  FS = ":"
  ORS = ""
}
NR == 1 {
  print "\"" $1 "\""
}
NR != 1 {
  print ", \"" $1 "\""
}
END {
  print "\n"
}

FS = ... (行2) は-Fオプションを指定するのと同じことです。ORSは要りません (行3) が、一番最後は改行したほうがいいのではないでしょうか (行12)。

NRは入力から読み込んだレコード数、つまり何行目かを表します。1行目か (行5) それ以降か (行8) で出力するものを変えます。

ついでに実行方法について。

• 上のソースコードをファイルに保存して

  cat /etc/passwd | awk -f ファイル名
  

  と実行する。

• ソースコードを1行にして適宜エスケープしてコマンドライン上で実行する (質問者さんの方法)。

  cat /etc/passwd | awk "BEGIN{……中略……"
  

• やや黒魔術っぽいですが、zshではヒアドキュメントを使う方法もあります。次のような内容のシェルスクリプトを作成して実行します。

  #!/bin/zsh
  
  cat /etc/passwd | awk -f <(cat - <<-'EOF'
      BEGIN {
        FS = ":"
        ORS = ""
      }
      NR == 1 {
        print "\"" $1 "\""
      }
      NR != 1 {
        print ", \"" $1 "\""
      }
      END {
        print "\n"
      }
  EOF
  )
  

  他のシェル、たとえばbash、dash、kshなどでは動きませんので注意。詳しくは "Command/Process Substitution" を参照してください。

Answer 3

cat /etc/passwd | awk -F':' '{one = one (NR>1 ? "," : "") "\"" $1 "\""}END{print one}'

Comments

[Moyomoto-pixcel]

解決しました！
ありがとうございました