CSVファイル結合のVBAで、前回の読み込んだデータが残ったままになってしまう

Question

実現したいこと

合体データフォルダ内の
1.csv
2.csv
3.csv
4.csv
の4つのファイルを結合して
同じ合体データフォルダ内に
新しいcsvで出力するというこーどを書きたい

発生している問題・分からないこと

今起きている事象としては

【問題①】
◾︎一回目
1-4のcsvファイルを読み込み、出力できた
◾︎二回目
合体データフォルダ内の1-4のデータは削除し、翌日新しい1-4のデータを入れ実行した所、削除したはずの前日のデータで出力された

読み込むcsvフォルダ名が1.2.3.4のまま読み込む必要があり、変更が出来ないので(こちらの事情で)、どこかでパスのリセットを行う必要があるのかと思いましたが、
何回やっても同じファイルができあがるので
わかる方にアドバイスを頂きたいです。

【問題②】
・合体データフォルダ内に出力したいのですが
1つ上のフォルダに出力されてしまいます。こちらも何度がコードを加えてみたのですが上手くいかず。
アドバイスを頂きたいです。

該当のソースコード

以下コードです
(リセットするコードは一旦抜いています)

Sub csv合体()
    Dim folderPath As String
    Dim fso As Object
    Dim file As Object
    Dim textLine As String
    Dim outputFileName As String
    Dim outputFile As Integer
    Dim inputFile As Integer
    Dim firstFile As Boolean
   
    ' フォルダのパスを指定
    folderPath = "C:\temp\合体データ"
   
    ' 出力ファイル名（指定の名前で保存）
    outputFileName = folderPath & ".csv"
 
    ' ファイルシステムオブジェクトを作成
    Set fso =      CreateObject("Scripting.FileSystemObject")
   
    ' 出力ファイルを作成
    outputFile = FreeFile
    Open outputFileName For Output As #outputFile
   
    firstFile = True
   
    ' フォルダ内のCSVファイルを処理
    For Each file In fso.GetFolder(folderPath).Files
        If Right(file.Name, 4) = ".csv" Then
            inputFile = FreeFile
            Open file.Path For Input As #inputFile
           
            ' 最初のファイルのヘッダーを含める
            If firstFile Then
                firstFile = False
            Else
                ' 2つ目以降はヘッダーをスキップ
                Line Input #inputFile, textLine
            End If
           
            ' 各行を出力ファイルに書き込む
            Do While Not EOF(inputFile)
                Line Input #inputFile, textLine
                Print #outputFile, textLine
            Loop
           
            Close #inputFile
        End If
    Next file
   
    Close #outputFile
   
    MsgBox "CSVファイルの結合が完了しました！", vbInformation
End Sub

試したこと・調べたこと

• teratailやGoogle等で検索した
• ソースコードを自分なりに変更した
• 知人に聞いた
• その他

上記の詳細・結果

chatGptにて3つほどコードを追加提案されましたが上手くいかず。

補足

特になし

Comments

[TakaiY]

> outputFileName = folderPath & ".csv"
上記の処理の結果 outputFileName は 「C:\temp\合体データ.csv」になりますが、これが「1つ上のフォルダに出力されてしまいます」の原因ではありませんか？ どのようなファイル名で出力したいのでしょうか。

For Each の後に、file.nameを表示するなどするとどのような結果が出ますか？
ちなみに、 合体データフォルダに結果ファイルも入れておくとすると、2回目以降にその合体したデータも読んでしまうことになりますが、どのように対応するつもりでしょうか。

[meg_]

> 読み込むcsvフォルダ名が1.2.3.4のまま読み込む必要があり
フォルダですか？
フォルダなのか、ファイルなのか？読みたいファイルが対象になっているか？余分なものが対象になっていないか？等確認されていますか？

ファイル名が固定という意味ならばPowerQueryを使っても良いのではないでしょうか？

[tatsu99]

>何回やっても同じファイルができあがるので
>わかる方にアドバイスを頂きたいです。

こちらで、提示されたマクロを実行してみました。
1.csv 2.csv 3.csv 4.csvの内容を変えて実行すると、変えた内容が合体データ.csvに反映されます。
従って、正しく動作しています。本当にcsvファイルの内容が変えられているか、再度確認してはいかがでしょうか。
あなたが更新したCSVファイルの格納ホルダと実際に読み込むCSVファイルの格納フォルダが違っているような気がします。

[bsdfan]

> 合体データフォルダ内の 1.csv 2.csv 3.csv 4.csv の4つのファイルを結合して同じ合体データフォルダ内に新しいcsvで出力する
とのことですが、質問のコードだと、合体データフォルダ(C:\temp\合体データ)内のファイルを結合して、ひとつ上のフォルダに新しいcsv(C:\temp\合体データ.csv)で出力するという動作になっています。

[退会済みユーザー]

@TakaiY
1つ上のフォルダーに作成されてしまう原因が分かりました。ありがとうございます。の結果、ファイルは毎回実行前に削除する予定です。

@tasu99
格納時に謝っている可能性があるので、再度確認いたします。

@bsdfan
上でもご指摘あったとおり、やはりその箇所が原因なのですね。確認します。ありがとうございます。

Answer 1

copy 1.csv+2.csv+3.csv+4.csv all.csv

をrunしてやればよいのでは？
ただしファイルの文末に改行マークは入ってない場合は工夫が必要

Comments

[tamoto]

質問を読む限りでは、csv の各ファイルがヘッダ行を持つのを取り除く処理が必要そうに見えます。

Answer 2

現行の方法では、フォルダ「c:\temp\合体データ」 内の全てのCSVファイルを読み込んでいます。
従って、合体したデータをフォルダ「c:\temp\合体データ」内に出力すると、2回目以降、その
合体したデータも、CSVファイルとして読み込んでしまいます。

今回は、読み込むべきCSVファイルは、1.csv 2.csv 3.csv 4.csv の4つと決まっているので、
そのファイルのみを決め打ちで読み込むようにします。
そうすれば、合体したデータを読み込まなくなるので、
合体したデータをフォルダ「c:\temp\合体データ」内に出力しても問題ありません。
以下のようにしてしてください。
合体したデータをフォルダ「c:\temp\合体データ」内に出力し、
1.csv 2.csv 3.csv 4.csv の4つのみを読み込むようにしています。

Sub csv合体()
    Dim folderPath As String
    Dim inputFileNames As Variant
    Dim inputFileName As String
    Dim textLine As String
    Dim outputFileName As String
    Dim outputFile As Integer
    Dim inputFile As Integer
    Dim firstFile As Boolean
    Dim i As Long
    ' フォルダのパスを指定
    folderPath = "C:\temp\合体データ"
   
    ' 出力ファイル名（指定の名前で保存）
    outputFileName = folderPath & "\" & "合体データ.csv"
   
    ' 出力ファイルを作成
    outputFile = FreeFile
    Open outputFileName For Output As #outputFile
   
    firstFile = True
    inputFileNames = Array("1.csv", "2.csv", "3.csv", "4.csv")
    ' フォルダ内のCSVファイルを処理
    For i = 0 To UBound(inputFileNames)
         inputFile = FreeFile
         inputFileName = folderPath & "\" & inputFileNames(i)
         Open inputFileName For Input As #inputFile
        
         ' 最初のファイルのヘッダーを含める
         If firstFile Then
             firstFile = False
         Else
             ' 2つ目以降はヘッダーをスキップ
             Line Input #inputFile, textLine
         End If
        
         ' 各行を出力ファイルに書き込む
         Do While Not EOF(inputFile)
             Line Input #inputFile, textLine
             Print #outputFile, textLine
         Loop
        
         Close #inputFile
    Next i
   
    Close #outputFile
    MsgBox "CSVファイルの結合が完了しました！", vbInformation
End Sub