複雑なLinuxコマンド出力結果を必要な行だけを取り出し加工したい

Question

netstat -svコマンドの実行結果から、各”XXX：”にセクションに毎に特定の行のみを抜き出し半角スペースを区切りで一行で繋ぎたいと思っております。
ただセクションが複数ありtabによるインデントがされている構造になっており、”XXX：”にセクションによって抜き出したい箇所が違うのでいい方法が見つからないでいます。以下の様にawkコマンドをパイプでつないでやり方を模索しているのですが、アドバイス頂けますと幸いです。

以下のコマンドだと最初の要件は満たせますが、Ip:と数字の間に余計なスペースが入ってしまう、他の行の抜き出すための応用ができていないとうの壁にぶつかっています。

netstat -sv |awk 'BEGIN{RS="";FS="\n"}{print $1 $8}'
Ip: 19942241 total packets received

抜き出したい行は以下の通りです。
Ip:セクションの一行目と８行目を抜き出し一行に表示
Ip: 19942241 total packets received 3 dropped because of missing route

Icmp:セクション、Icmp input histogram:サブセクションのdestination unreachable:を一行に表示
ICMP input histogram: destination unreachable: 5

Icmp:セクション、Icmp output histogram:サブセクションのdestination unreachable:を一行に表示
ICMP output histogram: destination unreachable: 8

実際のコマンド実行結果：

Answer 1

タブ区切りじゃなくて、空白4つ区切りじゃないですかね。
第一段見出し、第二段見出しをそれぞれ保存して、該当データを表示します。

awk 'BEGIN{FS="    "}
$1~/:$/{
    H1=$1;H2="";N1=NR;next}
$1=="" && $2~/:$/{
    H2=$2;next}
H1=="Ip:" && (NR-N1)==8 {
    print H1  " " $2;next}
H1=="Icmp:" && H2=="ICMP input histogram:" && /destination unreachable:/{
    print H2 $3;next}
H1=="Icmp:" && H2=="ICMP output histogram:" && /destination unreachable:/{
    print H2 $3;next}
'

おそらく、これくらいで十分です。

awk 'BEGIN{FS="    "}
$1~/:$/{
    H1=$1;H2="";N1=NR;next}
$2~/:$/{
    H2=$2;next}
H1=="Ip:" && (NR-N1)==8 {
    print H1  " " $2}
H2~/ICMP .* histogram:/ && /unreachable:/{
    print H2 $3}
'

Comments

[minhouse10]

otn様、素晴らしいアドバイスとコードご教授頂きありがとうございます！、実際にコードを実行して見ました所、以下のようなエラーが発生してしまいました。もう少し自分でも構文をチェックして行きたいと思います。また一行ずつ意味を確かめつつテストし結果またご報告させて頂きます。
awk: test2.awk:1: awk 'BEGIN{FS=" "}
awk: test2.awk:1: ^ invalid char ''' in expression

[otn]

sh で実行せずに awk で実行したとかでしょうか。

[minhouse10]

otn様、申し訳ございません、仰る通りawkで実行しておりました！

Answer 2

考え方としては、

• セクションの区切りの行、Ipセクション内の行、Icmpセクション内の行で場合分けして処理。
• 今どのセクションを処理中なのかの情報を保持する状態変数を設定。

ざっくりこんな感じでどうでしょう。

# test.awk
{sub(" *", "")}

$1~/:$/{
    sect = $1
    if(out != ""){
        print out
        out = ""
    }
    subsect = ""
}

sect=="Ip:"{
    if(/total packets received/) out = $0
    if(/dropped because of missing route/) out = out " " $0 "\n"
}

sect=="Icmp:"{
    if(/:$/) subsect = $0
    if(/destination unreachable:/) out = out subsect " " $0 "\n"       
}

$ netstat -sv | awk -f test.awk

Comments

[minhouse10]

KojiDoi様、素晴らしいアドバイスとコードをご提供頂きまして本当にありがとうございます！ご教授頂きましたコードについて一行ずつ意味を確かめながらテストして行きたいと思います。また結果ご報告させて頂きます。