ESP32のAPモードで複数台のクライアントと同時通信したい

Question

前提・実現したいこと

ESP32をアクセスポイントモードで使用し、内部に立てたTCPサーバと、クライアントモードで動作する2台のESP32と同時にデータをやり取りしたい。

発生している問題・エラーメッセージ

サーバーからメッセージを接続中の2台のクライアントに送信する際、1台のみにしか送信できず。

ESP32のAPモードの仕様

前世代のESP8266では、softAPモードと称したWi-FiDirectモードであったらしく、32については情報を得られず。

該当のソースコード

/*
 * アクセスポイント側
 * サーバーからクライアントに文字を送信してみる
 */

#include <WiFi.h>

static const char *WIFI_SSID = "WROOM32";
static const char *WIFI_PASS = "password";

//サーバー設定-------------------------------------------------
IPAddress ip(192, 168, 1, 10);
WiFiServer server(1337);  //Port番号
//-------------------------------------------------------------

void setup() {
  Serial.begin(115200);
  
  //Wi-Fiアクセスポイント開始--------------------------------------------------------
  WiFi.mode(WIFI_AP);
  WiFi.softAP(WIFI_SSID, WIFI_PASS);
  WiFi.softAPConfig(ip, WiFi.gatewayIP(), WiFi.subnetMask());
  //WiFi.softAPConfig(ip, gateway, netmask);
  server.begin();

  IPAddress myIP = WiFi.softAPIP();
  Serial.println("APStarted. myIP Address:");
  Serial.println(myIP);
  Serial.print("server Mac Address: ");
  Serial.println(WiFi.macAddress());
  Serial.print("Subnet Mask: ");
  Serial.println(WiFi.subnetMask());
  Serial.print("Gateway IP: ");
  Serial.println(WiFi.gatewayIP());
  //------------------------------------------------------------------------------
  delay(500);
}

void loop() {
  WiFiClient client = server.available();

  if(client > 0){
    Serial.println("newclient");
    while(client.connected()){
      client.println("println");
      delay(1000);
      client.println("\n");
    }
  }
  client.stop();
  Serial.println("client disconnected");
  }


/*
 * クライアント側
 * サーバーから文字を受け取って表示してみる
 */

#include <WiFi.h>

#define WIFI_SSID "WROOM32"
#define WIFI_PASS "password"
//接続先設定
const uint16_t port = 1337;             //接続するサーバのポート　
const char * host = "192.168.1.10";      // 接続するipもしくはdns

void setup() {
  Serial.begin(115200);
//Wi-Fi接続----------------------------------------------------------------------
  WiFi.begin( WIFI_SSID, WIFI_PASS );
  Serial.println("Connecting Wifi...");
  while (WiFi.status() != WL_CONNECTED) {
      delay(500);
      Serial.print(".");
  }
  Serial.println("");
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());
  Serial.print("STA Mac Address: ");
  Serial.println(WiFi.macAddress());
  Serial.print("Subnet Mask: ");
  Serial.println(WiFi.subnetMask());
  Serial.print("Gateway IP: ");
  Serial.println(WiFi.gatewayIP());
//------------------------------------------------------------------------------
  delay(500);

}

void loop() {
  WiFiClient client;
  Serial.print("Connecting to ");
  Serial.println(host);
  if(!client.connect(host, port)){
    Serial.println("Connection failed.");
    Serial.println("Waiting 5 seconds before retrying...");
    delay(5000);
    return;
  }

  String rstr;
  if(client > 0){
 if(client > 0){                               // サーバーに接続され、読み取り可能なデータがあるクライアントを取得した場合実行
    Serial.println("NewClient");
    while(client.connected()){                  // クライアントが接続されている間実行
      if(client.available()){                   // クライアントから読み込み可能なバイトがある場合実行
         rstr = client.readStringUntil('\n');   // データを読み込む。\nを受信すると読み込み終了し再度読み込みへループする
         Serial.print("[");
         Serial.print(rstr);                    // 読み込んだデータをシリアル表示
         Serial.println("]");
        }
      }
  }
  
  //----------------------------------------------------------------------------
}
}

試したこと

・当初は複数のクライアントから、AP兼サーバーのESP32に文字を送るものを作っていたが例によって1台分しか表示できず、ネット上の情報でシリアル通信が衝突している可能性が指摘されていたので、送受信を逆にしたが解決できず。

補足情報（FW/ツールのバージョンなど）

クライアント2台とも、APに接続できてはいるが情報の受信が一台のみしか行われない。
APのチャンネルを2つ（1ch, 5ch）指定し、クライアントそれぞれに接続するチャンネルを指定したが解決せず

TCPでなくUDPで行えば解決しましたが、TCPで不可能な技術的な理由（ArduinoIDEで実現できる方法があるのか）がわからないので、しばらく残させていただきます。

Comments

[tmp]

ブログラムがそう組まれているからです。サーバーの接続への接続を受け付け(server.available();)た後、クライアントの通信を終えるまで、次の接続を受け付けないからです。

[moto_short]

ご教授いただきありがとうございます。（回答でされてもよろしかったのではと思いますが）
同時に２台分の受付を行う方法等はありますでしょうか。

[tmp]

回答を考える時間がなかったからです。思い込みだと、それで気づいてしまいます。
ポーリングか、マルチタスクになると思います。

[moto_short]

ありがとうございます。自分でも検討してみます

Answer 1

2022年4月現在で'ESP32 複数 クライアント'でググったらこれがトップでヒットしちゃって...ちょっと恥ずかしいかな。
普通にArduinoライブラリでもできちゃったので、一応そちらも載せておきます。二口分の受け方は「ベタ」に書いているので、実際になにかするなら美しくまとめてください。もちろん、動作中にreadStringUntil()とかでブロックしたりしちゃいけませんよ。

#include <WiFi.h>
WiFiServer server(54321);

void setup() {
    Serial.begin(115200);
    WiFi.begin(); //引数省略で最後に接続したAPにつなぎに行く。WiFiの接続とソケットの接続を混同しないようにしましょう。
    while (WiFi.status() != WL_CONNECTED) {
        delay(500);
    }
    Serial.println(WiFi.localIP());
    server.begin();
}
WiFiClient client[2];
String s[2];
void loop() {
  if( !client[0].connected()){
    client[0]= server.available();
    if(client[0].connected()){
      Serial.println("Connected to 0");
      client[0].println("Connected to 0");
    }
  }else{
    while(client[0].available()){
      char c=client[0].read();
      s[0]+=c;
      if(c=='\n'){
        Serial.println(s[0]);
        client[0].print(s[0]);
      }
    }
  }
  if( !client[1].connected()){
    client[1]= server.available();
    if(client[1].connected()){
      Serial.println("Connected to 1");
      client[1].println("Connected to 1");
    }
  }else{
    while(client[1].available()){
      char c=client[1].read();
      s[1]+=c;
      if(c=='\n'){
        Serial.println(s[1]);
        client[1].print(s[1]);
      }
    }
  }
}

以下原文

既存のライブラリを真面目に探せばもっといい処理もできそうな気がしますが、見つからなかったので原始的にやってみました。WiFiを繋いだあとはCでソケットを扱う場合の定番にほぼ沿ったものです。

#include <sys/select.h>
#include <sys/socket.h>
#include <WiFi.h>

static const char *WIFI_SSID = "WROOM32";
static const char *WIFI_PASS = "password";
const int port = 1337;

int fd, maxfd;
int fd2[2] = { -1, -1}; //二口だけ接続をうけつける
struct sockaddr_in addr;
struct sockaddr_in from_addr;
struct timeval tv;

//サーバー設定-------------------------------------------------
IPAddress ip(192, 168, 1, 10);
//-------------------------------------------------------------

void setup() {
  Serial.begin(115200);
  //Wi-Fiアクセスポイント開始--------------------------------------------------------
  WiFi.mode(WIFI_AP);
  WiFi.softAP(WIFI_SSID, WIFI_PASS);
  WiFi.softAPConfig(ip, WiFi.gatewayIP(), WiFi.subnetMask());
  //WiFi.softAPConfig(ip, gateway, netmask);

  IPAddress myIP = WiFi.softAPIP();
  Serial.println("APStarted. myIP Address:");
  Serial.println(myIP);
  Serial.print("server Mac Address: ");
  Serial.println(WiFi.macAddress());
  Serial.print("Subnet Mask: ");
  Serial.println(WiFi.subnetMask());
  Serial.print("Gateway IP: ");
  Serial.println(WiFi.gatewayIP());
  //------------------------------------------------------------------------------

  if ( (fd = socket(AF_INET, SOCK_STREAM, 0)) < 0) {
    Serial.println("socket error.");
    while (1);
  }
  addr.sin_family = AF_INET;
  addr.sin_port = ntohs(port);
  addr.sin_addr.s_addr = INADDR_ANY;
  if ( bind( fd, (struct sockaddr *)&addr, sizeof(addr)) < 0 ) {
    Serial.println( "bind error" );
    while (1);
  }

}


void loop() {
  if ( listen(fd, 1) < 0) {
    Serial.println("listen error.");
  }

  fd_set fds;
  FD_ZERO(&fds);
  FD_SET( fd, &fds);
  maxfd = fd;
  for (int i = 0; i < 2; i++) {
    if (fd2[i] != -1) {
      FD_SET(fd2[i], &fds);
      if (fd2[i] > fd) {
        maxfd = fd2[i];
      }
    }
  }
  tv.tv_sec = 0;
  tv.tv_usec = 10000;
  int cnt = select(maxfd + 1, &fds, NULL, NULL, &tv);
  if (cnt <= 0) {
    //error or timeout
    for (int i = 0; i < 2; i++) {
      if (fd2[i] >= 0) {
      //既接続のソケットに対して送信
        char buf[32];
        cnt = sprintf(buf, "To %d %ld\n", fd2[i], millis());
        write(fd2[i], buf, cnt);
      }
    }
  }
  if (FD_ISSET( fd, &fds)) {
    for (int i = 0; i < 2; i++) {
      //接続受付
      if (fd2[i] == -1) {
        socklen_t len = sizeof(struct sockaddr_in);
        if ((fd2[i] = accept(fd, (struct sockaddr *)&from_addr, &len)) < 0) {
          Serial.println("accept error.");
          while (1);
        }
        Serial.println("connect " + String( fd2[i]));
        break;
      }
    }
  }
  for (int i = 0; i < 2; i++) {
    if (fd2[i] != -1 && FD_ISSET(fd2[i], &fds) ) {
      //受信&接続断検出
      char buf[256];
      int rcvCnt = recv(fd2[i], buf, sizeof(buf), 0);
      Serial.println("rcvd:" + String(buf));
      if (rcvCnt < 0) {
        Serial.println("disconnect " + String(fd2[i]));
        close(fd2[i]);
        fd2[i] = -1;
      }
    }
  }
}

Comments

[moto_short]

回答ありがとうございます。
Cのソケットライブラリを扱える技量（と時間）が足らず、ご教授頂いたソースが断片的にしか解釈できませんでした。
追記の通り、UDPを使用した通信に変更しましたので、時間ができたときに勉強させていただこうと思います。

[moto_short]

お久しぶりです。1年ほど前はお世話になりました。
もう私は本件に関わることは無くなってしまったのですが、思ったよりもシンプルなコードで実現できたのですね。今更ですがスッキリしました。

Answer 2

MQTTがおすすめです

Comments

[moto_short]

回答ありがとうございます。
今回の制作物の都合により、MQTTプロトコルが扱える通信速度が不足していたため、使用を見送っております。

[退会済みユーザー]

使用できない事情があるのですね。通信速度が足りてないとMQTTが扱えないというのは知りませんでした。