複数の値をシリアル通信で送りたいが０を受け取ってしまう。

Question

前提・実現したいこと

ESP32からシリアル通信で2つの値を送り、ArduinoUNOで2つの値に受け取りたいと思っています。
webの情報を参考に実施したのですが、UNOで受け取れた値が双方とも0です。
（正確に言うと、ヘッダー付きの計3つを送っているのですが、UNO側ではヘッダーにすべての値が入ってしまい、
残り2つの値にはゼロが入ってしまいます。）

発生している問題・エラーメッセージ

ArduinoUNOにて
Serial.println(header);　と記載した場合のシリアルモニタ出力は
255
100
200

Serial.println(lat_dis_c);　と記載した場合のシリアルモニタ出力は
0

Serial.println(lon_dis_c);　と記載した場合のシリアルモニタ出力は
0

該当のソースコード

(ESP32:送信側)

HardwareSerial mySerial1(1); 
void setup() {
  Serial.begin(115200);
  mySerial1.begin(9600, SERIAL_8N1, 32, 33);// ピンを変更 (RX=32, TX=33)
}

void loop() {
     int data = 100;
     int data2 = 200;
     mySerial1.write(255);
     mySerial1.write(data);
     mySerial1.write(data2);
}

(ArduinoUNO:受信側)

#include <SoftwareSerial.h>
#define RX_PIN 3
#define TX_PIN 4

SoftwareSerial mySerial(RX_PIN,TX_PIN);

void setup() {
  Serial.begin(115200);
  mySerial.begin(9600);
}

void loop() {    
  int lat_dis_c;
  int lon_dis_c;
  
  if (mySerial.available()>0){
    uint8_t header = (uint8_t)mySerial.read();
    if (header == 0xFF) // check if incoming byte is header
    {
        uint8_t lat_dis_c = mySerial.read();
        uint8_t lon_dis_c = mySerial.read();
    }     

//     Serial.println(header);　
      //ここだけをコメント復帰させるとシリアルモニタは
      //  255
      //  100
      //  200            で出力

//     Serial.println(lat_dis_c);
      //ここだけをコメント復帰させるとシリアルモニタは
      //  0            で出力

//     Serial.println(lon_dis_c);
      //ここだけをコメント復帰させるとシリアルモニタは
      //  0            で出力
  }
}

試したこと

header が配列のようになっているので、要素（header[1]のような記述）を取り出そうと試みたりしたが、
文法エラーと怒られうまくいかない。

補足情報（FW/ツールのバージョンなど）

ArduinoUNO
ESP32-DevModule

Answer 1

バイナリで送ってるようですが、慣れないうちは文字列に変換し、改行を区切りにして送るようにしましょう
そうすればパソコンで受信確認ができ、デバッグもやりやすいです

んで、available()ってのは受信文字があるかどうかのチェックなので、一文字読み出しごとにこれをチェックしないと意味がないです

Comments

[ISO130]

ありがとうございます。
なんとかバイナリで送れるようになり解決できました。

Answer 2

思い出して下さい。
・9600bpsで1byteのデータ転送にはおおよそ1ms掛かること。
・Serial::read()/SoftSeria::read()はデータを受信していないときは0 -1を返すこと。

いま、シリアルの1バイト、255が受信できたところだとします。
if (mySerial.available()>0){
Serial::available()は受信している文字数を返しますから、1を返してif文の実行に入ります
uint8_t header = (uint8_t)mySerial.read();
で255すなわち0xFFを取り込みました。ここまで何μ秒でしょうか。少なくともmsの時間はかかっていません。そうすると、
uint8_t lat_dis_c = mySerial.read();
uint8_t lon_dis_c = mySerial.read();
は、受信データがないのでそれぞれ0 -1を返します。が、mkgt00さんが他の回答で指摘されているように、ここで宣言された変数は{ }のなかでしか寿命を持たず、関数冒頭で宣言されてSerial.printlnに渡っている変数とは別物。こちらは「たまたま0」だったため、0が表示されている、ということのようです。

続いて100を受信しました。
if (mySerial.available()>0){
uint8_t header = (uint8_t)mySerial.read();
100を受信します。0xffとは異なります。if文の中には入りません。100のデータは捨てられます。

続いて200を受信しました。
if (mySerial.available()>0){
uint8_t header = (uint8_t)mySerial.read();
200を受信します。0xffとは異なります。if文の中には入りません。200のデータは捨てられます。

最初に戻る。

以上の流れで、headerだけに255,100,200が受信されます。

やり方はいろいろあるでしょうが、Serail.read()が確実にデータを受信できるようにしてやって下さい。

Comments

[mkgt00]

SoftwareSerial.read()は、データを受信していないときは-1を返すと思います。

https://www.arduino.cc/en/Reference/SoftwareSerialRead

[ISO130]

大変ありがとうございます！
通信時間のタイミングが重要ということ、大変勉強になりました。
ということで送信側にdelayを与え動きを制御し、受信側でも if (mySerial.available()>2)　として、
3バイト分の情報が来たら処理をするというようにしました。
また、スコープ範囲外にlat_dis_c とlon_dis_c シリアルモニタ表示があったのが原因で0になっていたのもわかりましたので、範囲内に表示コードをおいたところ出力されました。
ありがとうございました！

[thkana]

mkgt00さん
指摘ありがとうございます。修正しました(0の消し線ってなんだかわかりにくいなぁ)。ちなみにSerial.read()も同様ですね。SoftwareSerialはSerialに仕様は合わせているでしょうから当然といえば当然ですが。

Answer 3

変数の有効範囲の問題でしょうか。以下のプログラムを動かしてみました。

void setup() {
  // put your setup code here, to run once:
  int lat_dis_c = 1000;
  int lon_dis_c = 2000;

  Serial.begin(115200);

  {
    uint8_t lat_dis_c = 128;
    uint8_t lon_dis_c = 255;
    
    Serial.println(lat_dis_c);
    Serial.println(lon_dis_c);
  }

  Serial.println(lat_dis_c);
  Serial.println(lon_dis_c);
}

void loop() {
  // put your main code here, to run repeatedly:

}

シリアルモニタの出力は、以下の通りです。

128
255
1000
2000

Uno側のloop()の開始直後の変数定義を、int lat_dis_c = 1000; とかにしてみたら、どうなりますか?

あと、以下では、1バイト以上のデータがバッファにあることはわかりますが、3バイトあるかはわからないと思います。とはいえ、> 2にしていいかは考えないといけないですが。

if (mySerial.available()>0)

また、SoftwareSerial.read()の戻り値は、int です。送られてくるデータは uint8_t ですが、データがない場合は、-1 が返ります。

Comments

[ISO130]

ありがとうございます！
ご指摘の通り、変数の有効範囲が重要でした。if文の外では入ったいた値が捨てられて0になっていたようです。
スコープ範囲内で処理するようにしてみます！
ありがとうございました！