【Processing】当たり判定が二重で表示される

Question

現在、Processingで避けゲーを作っていて
マウスカーソルが
●に当たるとダメージ
■に当たるとスコアアップ
▲に当たるとライフ回復
という仕様なのですが
今書いているプログラムですと、各種ドロップにマウスカーソルが当たったときに判定が二重になることが多く発生してしまいます

例えば50ダメージを受ける設定なのに一度に100ダメージ受けてしまうなど
何か御意見頂けると助かります

DropBall[] db = new DropBall[50];
PointRect[] pr = new PointRect[15];
LifeTriangle[] lt = new LifeTriangle[15];
float[] posX = new float[50]; 
float[] posY = new float[50];  
float[] posRX = new float[15];  
float[] posRY = new float[15];  
float[] posSX = new float[15];  
float[] posSY = new float[15];  
int i = 0,j = 0,k = 0;
float time = 0,elapsedTime = 0,timeStamp =0,clearTime = 0;
int state = 0,score = 0,life = 100,point_count = 0;
PFont font;
PImage img;

//ゲームの初期化、ゲームセット
void gameInit(){
    for (i = 0; i < 50; i++) { 
    db[i] = new DropBall(random(0, 600), 0, random(1,5));
  }
  for (j = 0; j < 15; j++) { 
    pr[j] = new PointRect(random(0, 600), 0, random(1, 5));
  }
  for (k = 0; k < 15; k++) { 
    lt[k] = new LifeTriangle(random(0, 600), 0, random(1, 5));
  }
}

void setup() {
  size (800, 600);
  frameRate(60);
  textAlign(CENTER, CENTER);
  font = createFont("HGSｺﾞｼｯｸE" , 50);
  textFont(font);
  gameInit();
  state = 0;
  score = 0;
  img = loadImage("jet.png");
  life = 100;
  point_count = 0;
}


void draw() {
  background(0);
  elapsedTime = float(millis()) / 1000;
  time = elapsedTime - timeStamp;
  fill(255);
  rect(610, 0, 800, 600);
  switch (state) {
    case 0:
      text("push Enter", 300, 300);
      break;
    case 1:
      //noCursor(); //カーソル表示した方が良いかもしれない
      image(img,mouseX - 16, mouseY - 16);
      fill(0);
      text(time, 700, 100);
      text(life, 700, 300);
      for (j = 0; j < 15; j++) {
        pr[j].update();
        pr[j].display();
        pr[j].PlusPoint();
      }
      for (k = 0; k < 15; k++) {
        lt[k].update();
        lt[k].display();
        lt[k].LifePlus();
      }
      for (i = 0; i < 50; i++) {
        db[i].end();
        db[i].update();
        db[i].display();
      }
      break;
      
    case 2:
      cursor();
      fill(0); 
      rect(0, 0, 610, 800); 
      fill(255);
      score = int(clearTime * 50) + point_count * 50;
      text("Game Over", 300, 250);
      text("スコア：" + score, 300, 350);
      text(point_count,300,400);
      break;
    
    }
}

  class DropBall {
    PVector location;
    PVector velocity;
    int drop_hp;
    DropBall(float x, float y, float dy) {
      location = new PVector(x, y);
      velocity = new PVector(0, dy);
      drop_hp = 50;
    }
    void update() {
      location.add(velocity);
      if (location.y > height) {
        location.y = 0;
      }
      if (drop_hp < 0 ){
        location.y = 0;
        drop_hp = drop_hp + 50; 
      }
    }
    void display() {
      noStroke();
      fill(255, 0, 0);
      ellipse(location.x, location.y, 15, 15);
      posX[i] = location.x;
      posY[i] = location.y;
    }
    void end() {
      if (mouseX + 15 > posX[i] && mouseX - 15 < posX[i] && mouseY + 15 > posY[i] && mouseY - 15 < posY[i]) {
        drop_hp = drop_hp - 50;
        life = life - 50;
        if(life < 0){
          clearTime = time;
          state = 2;
          life = 100;
        }
      }
    }
  }

  class PointRect {
    PVector location;
    PVector velocity;
    int point_hp;
    PointRect(float x, float y, float dy) {
      location = new PVector(x, y);
      velocity = new PVector(0, dy);
      point_hp = 50;
    }
    void update() {
      location.add(velocity);
      if (location.y > height) {
        location.y = 0;
      }
      if (point_hp < 0 ){
        location.y = 0;
        point_hp = point_hp + 50; 
      }
    }
    void display() {
      noStroke();
      fill(255, 255, 255);
      rect(location.x, location.y, 15, 15);
      posRX[j] = location.x;
      posRY[j] = location.y;
    }
    void PlusPoint() { 
      if (mouseX + 15 > posRX[j] && mouseX - 15 < posRX[j] && mouseY + 15 > posRY[j] && mouseY - 15 < posRY[j]) {
        point_hp = point_hp - 50;
        point_count++;
      }
    }
  }

  class LifeTriangle {
    PVector location;
    PVector velocity;
    int life_hp;
    LifeTriangle(float x, float y, float dy) {
      location = new PVector(x, y);
      velocity = new PVector(0, dy);
      life_hp = 50;
    }
    void update() {
      location.add(velocity);
      if (location.y > height) {
        location.y = 0;
      }
      if (life_hp < 0 ){
        location.y = 0;
        life_hp = life_hp + 50; 
      }
    }
    void display() {
      noStroke();
      fill(255, 255, 0);
      triangle(location.x, location.y, location.x + 7.5, location.y + 15, location.x - 7.5, location.y + 15);
      posSX[k] = location.x;
      posSY[k] = location.y;
    }
    void LifePlus() { 
      if (mouseX + 15 > posSX[k] && mouseX - 15 < posSX[k] && mouseY + 15 > posSY[k] && mouseY - 15 < posSY[k]) {
        life_hp = life_hp - 50;
        life += 50;
      }
    }
  }

  void keyPressed() {
    if (key == ENTER && state == 0) {
      timeStamp = elapsedTime;
      time = elapsedTime - timeStamp;
      point_count = 0;
      state = 1;
    }
    if (key == ENTER && state == 2) {
      state = 0;
      gameInit();
    }
  }

Answer 1

50ダメージを受ける設定なのに一度に100ダメージ受けてしまう

3つとも同じですが、代表して●で説明します。
カーソルに当たった時にdrop_hp = drop_hp - 50;としています。
update()の中の、

if (drop_hp < 0 ) {
  location.y = 0;
  drop_hp = drop_hp + 50;
}

で位置のリセットのつもりですが、drop_hpは0なのでifの中には入りません。
次のフレームでもまだカーソル付近にいるので、もう一度当たります。
-50になって初めてifに入り、位置がリセットされるのでlifeが2回減るのが頻発します。

if (drop_hp <= 0 )にすれば直ります。
そもそもupdate()で判断するまでもなく、end()でlocation.y = 0;すればよいのではありませんか？
それならdrop_hpも不要になりますが、この後「弾を出して撃ち落とす」等の構想ですかね。

---

i・j・kがグローバル変数なのは、さすがによくないです。
end()のif (mouseX + 15 > posX[i] 。。。で必要だからですが、よく見てください。
display()でposX[i] = location.x;としています。

つまりif (mouseX + 15 > location.x。。。でいいのです。posX等は必要ないのです。
これでかなりのグローバル変数を減らせます。クラスを作った意味が出てきました。

time・elapsedTime・scoreあたりもローカル変数にできるはずです。
いろいろなところに散らばった変数の再初期化も、gameInit()に集約すると見通しが良くなると思います。