Arduinoの感圧センサからProcessingで複数の音を再生したいです。

Question

当方、processingとarduinoを連携させて作品を作ろうと考えております。

【構想】
arudino側のブレッドボードに感圧センサ（使用：ALPHA-MF01-N-221-A01）を接続し、検知した数値（arduinoのシリアルモニターでは0～350位は値が動きました）によって、複数の音声データを再生したいです。

値が100のときは〇〇〇.mp3、200のときは△△△.mp3が再生されるようなイメージです。
また、値が200→100に戻った時には、再生している音声データも△△△.mp3→〇〇〇.mp3へと戻るようにしたいと考えています。

現状で、感圧センサの値→音声データ再生すらできていない状況で、リファレンスや似たようなスケッチを参考にしているのですが、まったく回答がわかっていません・・・。

＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊
以下、作成しているスケッチ

【arduino側】

void setup() {
  Serial.begin(9600);
}

void loop() {
  // センサーの値を取得
  val = analogRead(0);

  // 一度に送れるデータ(1byte)に変換
  map(val, 0, 1023, 0, 255);

  // シリアルデータ送信
  Serial.write(val);

  delay(50);
}

【processing側】

import ddf.minim.*;
import ddf.minim.analysis.*;
import ddf.minim.effects.*;
import ddf.minim.signals.*;
import ddf.minim.spi.*;
import ddf.minim.ugens.*;
import processing.serial.*;

Serial port;
 
Minim minim = new Minim(this);
AudioPlayer player;
 
void setup() {
  size(480, 240);
    port = new Serial(this, "COM3", 9600);
  player = minim.loadFile("〇〇〇.mp3");
}
 
void draw() {
   if (port.available() > 0 ) {
    // シリアルデータ受信
    in_data = port.read();

  player.play();
 
　}

}

こういった質問の仕方は良くないと思うのですが、どなたか知恵をお貸しいただければ幸いです。

https://detail.chiebukuro.yahoo.co.jp/qa/question_detail/q11219716691

↑上記サイト【yahoo知恵袋】にても、ご意見をいただきたかったため、マルチポストを行っておりますので、ご了承ください。

何卒宜しくお願い致します。

Comments

[thkana]

https://detail.chiebukuro.yahoo.co.jp/qa/question_detail/q11219716691
'マルチポスト'についてはルールがありますので、適宜処置してください。
https://teratail.com/help#posted-otherservice

[Shinchama]

承知致しました。マルチポストの件、申し訳ございません。

[thkana]

謝ればいいという話ではなくて、然るべき処置をしてください。

[Shinchama]

マルチポストの件に関し、teratailのルールに則り、質問内容を変更しております。

Answer 1

  // 一度に送れるデータ(1byte)に変換
  map(val, 0, 1023, 0, 255);

の部分は

  // 一度に送れるデータ(1byte)に変換
  val = map(val, 0, 1023, 0, 255);

の間違いじゃないでしょうか？（Arduinoが手元にないので確認できませんが）

201～300＝Ｃと割り当てたとして

送受信処理を簡略化させるため、データを１バイト（0～255）に圧縮（センサーの値が0だったら0 1023だったら255 512だったら127に）している（ちょうど↑のコードのところ）ので、256以上は来ません。

arduinoのシリアルモニターでは0～350位は値が動きました

これがセンサーの値なら、Processing側は0～87くらいしか変動しないことになります（数段階の音を出すなら十分すぎですが）

気になった点は以上です。

---

参考コード
Arduinoがないのでセンサーの代わりに、マウスX座標にさせていただきました（画面内でマウスを左右に動かすと曲が変わります）
データ受信のところをコメント化しましたが、元に戻せばおそらく動くと思います。

素直に書いてみた場合

import ddf.minim.Minim;
import ddf.minim.AudioPlayer;
import processing.serial.Serial;

Serial port;
Minim minim;
AudioPlayer sound0; // 曲 いっこ目
AudioPlayer sound1; // 曲 にこ目
AudioPlayer sound2; // 曲 さんこ目

void setup() {
  size(480, 240);
  // ↓コメント解除
  //port = new Serial(this, "COM3", 9600);
  minim = new Minim(this);
  sound0 = minim.loadFile("groove.mp3");
  sound1 = minim.loadFile("jingle.mp3");
  sound2 = minim.loadFile("groove.mp3");
}

void draw() {
  // ↓コメント解除
  //if (port.available() > 0 ) {
  //  // シリアルデータ受信
  //  int in_data = port.read();
  int in_data = int(map(mouseX, 0, width, 0, 255)); // これは削除

  if (in_data < 100) { // sound0の範囲だったら...
    if (!sound0.isPlaying()) { // sound0を再生中でなかったら...（再生中ならそのまま何もしない）
      sound1.pause(); // 他をポーズ（再生していなくてもポーズを呼ぶこと自体は問題ない）
      sound2.pause();
      sound0.loop(); // ポーズ位置から再度ループ再生
    }
  } else if (in_data < 200) { // 以下同じように
    if (!sound1.isPlaying()) {
      sound0.pause();
      sound2.pause();
      sound1.loop();
    }
  } else {
    if (!sound2.isPlaying()) {
      sound0.pause();
      sound1.pause();
      sound2.loop();
    }
  }
  //} // ここもコメント解除
}

配列と関数を使ってみた場合

import ddf.minim.Minim;
import ddf.minim.AudioPlayer;
import processing.serial.Serial;

Serial port;
Minim minim;
AudioPlayer[] sounds; // 曲の配列
AudioPlayer playing; // 再生中の曲（最初はnull）

void setup() {
  size(480, 240);
  // ↓コメント解除
  //port = new Serial(this, "COM3", 9600);
  minim = new Minim(this);
  sounds = new AudioPlayer[]{
    minim.loadFile("groove.mp3"),  // 曲 いっこ目（配列の番号は0）
    minim.loadFile("jingle.mp3"),  // 曲 にこ目（1）
    minim.loadFile("groove.mp3"),  // 曲 さんこ目（2）
  };
}

void draw() {
  // ↓コメント解除
  //if (port.available() > 0 ) {
  //  // シリアルデータ受信
  //  int in_data = port.read();
  int in_data = int(map(mouseX, 0, width, 0, 255)); // これは削除

  if (in_data < 100) { // sounds[0]の範囲だったら...
    changeSound(sounds[0]); // changeSound関数にsounds[0]を渡して呼ぶ
  } else if (in_data < 200) { // 以下同じように
    changeSound(sounds[1]);
  } else {
    changeSound(sounds[2]);
  } 
  //} // ここもコメント解除
}

void changeSound(AudioPlayer sound) {
  if (playing == sound) return; // 再生中の曲と同じならそのまま何もしない

  if (playing != null) playing.pause(); // 再生中の曲がnullでない（何か再生している）ならポーズ
  playing = sound; // 再生中の曲を引数で渡された曲に変更
  if (playing != null) playing.loop(); // その曲がnullでないならポーズ位置から再度ループ再生（changeSound(null);とすれば何も再生されないようになる）
}

---

微妙にやっている内容が違うのがなんですが^^; ２，３曲ならどちらでもいい気がします。

Answer 2

感圧センサの値→音声データ再生すらできていない

全然そういう動作をするプログラムになってませんから当然でしょう。

arudinoの感圧センサからprocessingへの値の反映ですが、感圧センサを押すと、押す強さによって図形の大きさが変わるプログラムには成功しました。

ちょっとそのプログラム見せていただけますか?

Comments

[Shinchama]

そうですよね…。
感圧センサの検知する値の強弱→図形の大きさが変わるプログラム

【arduino側】
int val = 0;

void setup() {
Serial.begin(9600);
}

void loop() {
// センサーの値を取得
val = analogRead(0);

// 一度に送れるデータ(1byte)に変換
map(val, 0, 1023, 0, 255);

// シリアルデータ送信
Serial.write(val);

delay(50);
}

【processing側】
import processing.serial.*;

Serial port;

float x;
float y;

int in_data;

void setup() {
size(300, 300);
port = new Serial(this, "COM3", 9600);
background(0, 0, 0);
}

void draw() {
// 描画エリア設定
fill(255, 10);
noStroke();
rect(0, 0, width, height);

// シリアルポートからデータを受け取ったら
if (port.available() > 0 ) {
// シリアルデータ受信
in_data = port.read();

// 描画
x = width / 2 + random(-3, 3);
y = height / 2 + random(-3, 3);

noFill();

stroke(random(255), random(255), 255);

ellipse(x, y, in_data, in_data);
}
}

圧力センサを押すと、何もない画面から強弱によって円が描画されるプログラムです。

https://l-w-i.net/t/arduino/processing_001.txt
↑こちらのサイトのものを使用させていただき、手元のarduinoとproccessingでも成功しました。

ちなみに複数の音を）processing上で再生することには昨夜成功しております。（圧力センサの検知した値によって指定した音声ファイルが再生される…というところまでは到達しておりませんが…。）

[thkana]

通信は問題なさそうですね。

つまり、「ある変数がある値のときにある動作をする」というプログラムの構造がわからない、ということですか? (わからないことが悪いというわけじゃありません。あなたがわからないところがはっきりしないとどういう説明をすべきかが変わるということです)

[Shinchama]

おっしゃる通りです。

具体的には、圧力センサにて検知した値（1～100、101～200、201～300）といったくくりを、1～100＝Ａ、101～200＝Ｂ、201～300＝Ｃと割り当てたとして、Ａの範囲でセンサが値を検知した場合は〇〇〇.mp3を再生する、Ｂの場合は△△△.mp3を再生する…といった実行結果を得たく、そのプログラム構造（できれば具体的なスケッチ）が知りたいところです。

[thkana]

「条件で分岐する」といえば、まずはif文を思い出して下さい。
とりあえず、

if(圧力センサで検知した値が1～100の範囲){
(再生中の他の音源を停止する)
〇〇〇.mp3を再生する
}
if(圧力センサで検知した値が101～200の範囲){
(再生中の音源を停止する)
△△△.mp3を再生する
}
if(圧力センサで検知した値が200～255の範囲){ //1byteのデータが持てる値は0～255の範囲。300はありえない
(再生中の音源を停止する)
xxx.mp3を再生する
}

いろいろと無駄があったりしますが、これを考えられないようだと先に進めませんから。

Answer 3

質問にもありますのでシリアルで値は正常に受信できていると考えます。
従って値によってMp3のどれを再生するか？という質問と理解します。
また値は常に受信されているので、その切替のタイミングを考慮する必要があると思います。
恐らく希望の動作は複数のチェックポイント（値）を用意、例えば0-100までを範囲0、101-200までを範囲1、201-300までを範囲2の様に条件式を用意して現在の範囲の値が別の範囲に変わった時にmp3のデータを変えて再生で良いのでは？

Answer 4

まずは受信側で、再生どーこーは考えないで受信した数値を表示させるなりして、感圧センサの値がきちんと通信で表示されるのをしっかり確認しましょう。
それが出来なければ考え直す必要が出てきます。

はなしはそれからですねー

Comments

[Shinchama]

有難うございます。

arudinoの感圧センサからprocessingへの値の反映ですが、感圧センサを押すと、押す強さによって図形の大きさが変わるプログラムには成功しました。

通信はできていると思うので、あとは【特定の値になる】→【音が再生される】状況にできればと思っております。