Arduino USBキーボードから送られてくるキーコードが格納されてる変数を見つけたい。

Question

前提・実現したいこと

USBキーボードから送られてくるキーコードをArduinoで取得したいと考えています。

接続順は 【USBキーボード】 → 【USBホストシールド】 → 【Arduino Pro Micro】 → 【PC】の順で

現在は下記のブログの記事を参考に、キーボード入力をArduinoを経由させてPCへ出力する所まで作成することができました。

ですが、どの変数にキー情報が格納されているかがわからず、開発が行き詰まっています。

もし分かる方が居られましたら、何卒宜しくお願いいたします。

【参考とさせて頂いた記事及びコード】
Pro Microにmini USB Hostシールドを付けてUSBキーボードを接続する

現状の理解

間違っている可能性も高いのですが、
下記の関数sendReport()がキー情報をPCへ送る関数と予想しています。
・2はID(1がマウス用のIDらしいのでキーボード用のIDと予測)
・&KeyReportがキー情報(←このアドレスの値を取得できれば解決？)
・sizeofの出力結果は8

//HIDクラスを使ってレポートを送信する関数
void sendReport() {
  HID().SendReport(2, &keyReport ,sizeof(KeyReport));
}

試したこと及び現在の状況

&keyReportを、print関数で出力しようとしたり、変数に格納しようと試して見たもののエラーが発生。
内部がどのような値になっているのかや、どのようにすれば取得できるかがわからずにいます。

###質問者のプログラミング経験
VBA,GAS,UWSCと操作の自動化でしか取り扱いの経験がなく、
Arduino(C/C++)言語は初めてまだ日が浅いため、修練中の身です。
###参考とさせて頂いてるコード

#include "HID.h"
 
#include <hidboot.h>
#include <usbhub.h>
#include <SPI.h>
 
static const uint8_t _hidReportDescriptor[] PROGMEM = {
  0x05, 0x01, // USAGE_PAGE (Generic Desktop)
  0x09, 0x06, // USAGE (Keyboard)
  0xa1, 0x01, // COLLECTION (Application)
  0x85, 0x02, //   REPORT_ID (2) --- Mouse.cppがID==1。
 
  0x05, 0x07, //   USAGE_PAGE (usage = keyboard page)
    // モデファイヤキー(修飾キー)
  0x19, 0xe0, //     USAGE_MINIMUM (左CTRLが0xe0)
  0x29, 0xe7, //     USAGE_MAXIMUM (右GUIが0xe7)
  0x15, 0x00, //   LOGICAL_MINIMUM (0)
  0x25, 0x01, //   LOGICAL_MAXIMUM (1)
  0x95, 0x08, //   REPORT_COUNT (8) 全部で8つ(左右4つずつ)。
  0x75, 0x01, //   REPORT_SIZE (1) 各修飾キーにつき1ビット
  0x81, 0x02, //   INPUT (Data,Var,Abs) 8ビット長のInputフィールド(変数)が1つ。
    // 予約フィールド
  0x95, 0x01, //   REPORT_COUNT (1)
  0x75, 0x08, //   REPORT_SIZE (8) 1ビットが8つ。
  0x81, 0x01, //   INPUT (Cnst,Var,Abs)
    // LED状態のアウトプット
  0x95, 0x05, //   REPORT_COUNT (5) 全部で5つ。
  0x75, 0x01, //   REPORT_SIZE (1)  各LEDにつき1ビット
  0x05, 0x08, //   USAGE_PAGE (LEDs)
  0x19, 0x01, //     USAGE_MINIMUM (1) (NumLock LEDが1)
  0x29, 0x05, //     USAGE_MAXIMUM (5) (KANA LEDが5)
  0x91, 0x02, //   OUTPUT (Data,Var,Abs) // LED report
    // LEDレポートのパディング
  0x95, 0x01, //   REPORT_COUNT (1)
  0x75, 0x03, //   REPORT_SIZE (3)　　残りの3ビットを埋める。
  0x91, 0x01, //   OUTPUT (Cnst,Var,Abs) // padding 
    // 押下情報のインプット
  0x95, 0x06, //   REPORT_COUNT (6) 全部で6つ。
  0x75, 0x08, //   REPORT_SIZE (8) おのおの8ビットで表現
  0x15, 0x00, //   LOGICAL_MINIMUM (0) キーコードの範囲は、
  0x25, 0xdd, //   LOGICAL_MAXIMUM (221) 0～221(0xdd)まで
 
  0x05, 0x07, //   USAGE_PAGE (Keyboard)
  0x19, 0x00, //     USAGE_MINIMUM (0はキーコードではない)
  0x29, 0xdd, //     USAGE_MAXIMUM (Keypad Hexadecimalまで)
  0x81, 0x00, //   INPUT (Data,Ary,Abs)
  0xc0    // END_COLLECTION
};
 
#define REPORT_KEYS 6
typedef struct {
  uint8_t modifiers;
  uint8_t reserved;
  uint8_t keys[REPORT_KEYS];
} KeyReport;
 
KeyReport keyReport;
 
void sendReport() {
  HID().SendReport(2, &keyReport ,sizeof(KeyReport));
}
 
void releaseAll() {
  memset(&keyReport, 0, sizeof(KeyReport));
  sendReport();
}
 
void report_press(uint8_t key, uint8_t mod) {
  if (key != 0) {
    bool already = false;
    int empty_slot = -1;
    for(int i = 0; i < REPORT_KEYS; i++) {
      if (keyReport.keys[i] == key)
        already = true;
      if (keyReport.keys[i] == 0 && empty_slot < 0)
        empty_slot = i;      
    }
    if (empty_slot < 0)  // error condition.
      return;
    if (!already)
      keyReport.keys[empty_slot] = key;
  }
  keyReport.modifiers = mod;
  sendReport();  
}
 
void report_release(uint8_t key, uint8_t mod) {
  if (key != 0) {
    for(int i = 0; i < REPORT_KEYS; i++) {
      if (keyReport.keys[i] == key) {
        keyReport.keys[i] = 0;
        break;
      }
    }
  }
  keyReport.modifiers = mod;
  sendReport();  
}
 
class KeyboardEvent : public KeyboardReportParser {
  protected:
    void OnControlKeysChanged(uint8_t before, uint8_t after);
    void OnKeyPressed(uint8_t key) {};
    void OnKeyDown  (uint8_t mod, uint8_t key) { report_press(key, mod);  };
    void OnKeyUp  (uint8_t mod, uint8_t key) { report_release(key, mod); };
};
 
void KeyboardEvent::OnControlKeysChanged(uint8_t before, uint8_t after) {
  uint8_t change = before ^ after;
  if (change != 0) {
    if (change & after)
      report_press(0, after);
    else
      report_release(0, after);      
  }
}
 
USB Usb;
HIDBoot<USB_HID_PROTOCOL_KEYBOARD>    HidKeyboard(&Usb);
KeyboardEvent kbd;
 
void error_blink(int period) {
  for(;;) {
    TXLED1; delay(period); TXLED0; delay(period);
    RXLED1; delay(period); RXLED0; delay(period);
  }  
}
 
void setup() {
  static HIDSubDescriptor node(_hidReportDescriptor, sizeof(_hidReportDescriptor));
  HID().AppendDescriptor(&node);
  delay(200);
  releaseAll();
  if (Usb.Init() == -1)
    error_blink(400);
  delay( 200 );
  HidKeyboard.SetReportParser(0, &kbd);
}
 
void loop() {
  Usb.Task();
}

###追記
・12/20　一度変数に格納することでコンパイル成功、どのキーを押しても169と表示されるので、1byte×8個の表記にするにはどうすればいいか、どこに問題があるのか模索中。

Serial.println(&keyReport);//コンパイル時にエラー

//↓一度変数に格納するとコンパイル成功

uint8_t a =&keyReport;  
Serial.println(&keyReport);//169 の数値が固定でログに表示される。

 

Comments

[y_waiwai]

コードがないと答えようもないですが

[nakapy0918]

リンク先の参考とさせて頂いてるコードを追記致しました。

Answer 1

nakapy0918さん、

USB keyboardは、こんな感じで、8バイトのデータを送ります。
( https://wiki.osdev.org/USB_Human_Interface_Devices#USB_keyboard )

この辺がわかると...、というか、わかってないと、何やってるか、わからないですよね？
まずは、この辺から、調べてみるとよいかと思います。

Comments

[nakapy0918]

mt08さん回答ありがとうございます。

2番目のReserved field.(予約フィールド)の理解がまだ出来ずにいますが、
1番目が修飾キー(LeftCtrl(0)やRightShift(5))で3~8番目が複数押しを想定したキー情報(aなら4、bなら5)
16進数表記で1byteの情報が、8つ連なってレポートとして送られていると理解したのですが、あっていますでしょうか？

配列形式で格納されているのならと、Serial.println(keyReport[0]);と記述すればログに表示できるのではないかと、試したもののエラーとなってしまったため、質問させて頂いています。

どうにかログに表示させる方法はないでしょうか？

[mt08]

nakapy0918さん、

> 2番目のReserved field.(予約フィールド)の理解がまだ出来ずにいますが、

は、使用されてないので、無視して大丈夫です。

> 16進数表記で1byteの情報が、8つ連なってレポートとして送られていると理解したのですが、あっていますでしょうか？

はい。
1バイト目の８ビットそれぞれで、８つの修飾キー（modifier key：モディファイアキー)。２バイト目は予約(無視)、のこり６バイトで普通のキーです。ね。

動作の流れとしては、setup()中の、↓で、イベントハンドラを登録してます。

> HidKeyboard.SetReportParser(0, &kbd);

KeyboardEvent kbd;なので、class KeyboardEvent : public KeyboardReportParser {　のあたりを見ると、それっぽいメソッドが並んでるかと。
キーが押されると(ArduinoがUSBホストとして、デバイスのキーボードからデータ取得)、OnKeyDown()が実行され、report_press()がよばれて、
(ArduinoがUSBデバイスとして)うまくパケットを作って、PCにデータを送る、ってかんじですね。

みたところ、イベント(OnKeyDown() / OnKeyUp())では、modとkey、それぞれ一個ずつで呼ばれるので、修飾キーと、一つのキーのイベント(押された・離された)がわかるだけなので、それをもとに、現在押されているキーをうまくまとめて、送ってるんじゃないかと思います。

あと、KeyReporyは、構造体なので、printするなら、KeyReport.keys[0] でしょうか？

[nakapy0918]

mt08さん、詳しく解答ありがとうございます。

sendReport()内に下記の記述をしたところ、
キー入力時に16進数表記で8個の情報をログに出力。

Serial.print(keyReport.modifiers, HEX);
Serial.print(" ");
Serial.print(keyReport.reserved, HEX);
Serial.print(" ");
for (int i = 0; i < REPORT_KEYS; i++) {
Serial.print(keyReport.keys[i], HEX);
Serial.print(" ");
}
Serial.println();

おかげさまでキー入力情報を得るための理解が叶いました。
加えて今まで理解できてなかった他関数も、1つの理解から辿るように見ていくと、何をしてるか理解できるように…。とても助かりました、mt08さん本当にありがとうございました。