if文でループを停止、再開させるには

Question

Arduinoとprocessing間のシリアル通信を利用した作品を作っています。
Arduinoに接続した2つのタクトスイッチから得たスイッチのON/OFFのデータをProcessingに送っています。2つのタクトスイッチをそれぞれ停止用、再開用として使いたいです。
Processing側では画像を20枚読み込み、それを表示させています。

やりたいこととしては、Processing側の画像の読み込みを、Arduinoから送られてきたスイッチの値によって停止・再開することです。
以下のコードでは、停止用スイッチを押すとsensors = 1 が送られ、if文の中のnoLoop()により画像の読み込みは停止します。しかし、もう片方の再開用スイッチを押した時に送られる値sensors = 2 で再開することができません。
mousePressed()の中のloop()によって、マウスをクリックすれば再開は可能ですが、今回はArduinoからの値を使って再開させたいです。

回答よろしくお願いいたします。

import processing.serial.*;
Serial myPort;

int numFrames = 20;
int  sensors; //センサーの値を格納

PImage[] images = new PImage[numFrames];

void setup() {
  background(255);
  size(1280, 800);
  frameRate(40);
  imageMode(CENTER);
  for (int i=0; i<images.length; i++) {
    images[i] = loadImage("animation-"+nf(i, 3)+".png");
    images[i].resize(1280, 800);
  }

  myPort = new Serial(this, "/dev/cu.usbmodem143401", 9600);
}

void draw() {

  int frame = frameCount % numFrames;
  if (sensors == 0) {

    image(images[frame], width/2, height/2);
  } 
  if (sensors == 1) {
    //image(images[frame], width/2, height/2);
    noLoop();
  } 
  if (sensors == 2) {
    loop();
  }
}

void serialEvent(Serial p) {
  sensors = p.read();
  println(sensors);
}

void mousePressed() {
  loop();
}

Answer 1

Arduino持っておりませんのであてずっぽうですが、これでいいのでは？外していたらすいません。

void draw() {
  int frame = frameCount % numFrames;
  if (sensors == 0) {
    image(images[frame], width/2, height/2);
  } 
// serialEventに移動
//  if (sensors == 1) {
//    noLoop();
//  } 
//  if (sensors == 2) {
//    loop();
//  }
}

void serialEvent(Serial p) {
  sensors = p.read();
  println(sensors);
  
  if (sensors == 1) {
    noLoop();
  } 
  if (sensors == 2) {
    loop();
  }
} 

Comments

[退会済みユーザー]

回答ありがとうございます！！仰る通りプログラムを書き換えたら、無事思っていたように動きました！こちらはシリアル通信で受け取る値自体をnoLoop()したりloop()しているという認識で大丈夫でしょうか？

[TN8001]

drawの中にif (sensors == 1) noLoop();とif (sensors == 2) loop();がありましたが、noLoop状態だとdraw自体が呼ばれなくなるんだと思います。
mousePressedはnoLoopでも来るということなので、serialEventも来るんだと思い、ifをdrawからserialEventに移動すればよいのでは?ということです。

[退会済みユーザー]

なるほど、確かにmousePressedはnoLoopした後も動いてましたし、serialEventも動くかもと予想できますね。その発想は無かったので助かりました…！ありがとうございました。

Answer 2

全く異なる方法ですが、一応自己解決にも至りました。
事前に20枚の画像自体を一つの動画として書き出し、それを読み込んでpause()とplay()で停止・再開する方法です。
しかしいちいち動画を読み込むのは重い気がするので、TN8001さんの回答がベストな方法だと思います。

import processing.serial.*;
Serial myPort;

import processing.video.*;
Movie myMovie;

int sensors = 0;

void setup(){
  size(1920, 800);
  background(0);
  frameRate(60);
  myMovie = new Movie(this, "myMovie.mov");
  myMovie.loop();
    myPort = new Serial(this, "/dev/cu.usbmodem143401", 9600);
}

void draw(){
  background(255);
  if (sensors == 0) {

    image(myMovie, width/2, height/2);
  } 
  if (sensors == 1) {
     myMovie.pause();
  } 
  if (sensors == 2) {
    myMovie.play();
  }
}

void movieEvent(Movie m){
  m.read();
}

void serialEvent(Serial p) {
  sensors = p.read();
  println(sensors);
}

Answer 3

loop()/noLoop()で制御するのってあまり好きじゃ無いなぁ。
やりたいのは画が変わるのを止めたいことであって、ループを止めることじゃないはず。draw()を繰り返し実行する、というのはProcessingの動作の基礎構造だから、そこに手を入れるってのは余程のことだと思う。いわば、明かりを消すのに手元のスイッチじゃなくて発電所を止めちゃう、みたいな。(ちょっと大げさ)
実際、noLoop()で処理が止まってうまくいかなかくなったわけでしょ。

私だったら

int sensors=2; //1か2、二つの値しか取らないはずの変数なら、そのどちらかを与えておくべきでは。
int frame;

としておいて、

void draw() {
  if (sensors == 1) {
    frame = (frame+1)%images.length; //sensors==2ならframeは変化しない
  } 
  image(images[frame], width/2, height/2);
}

とするかなぁ。