ProcessingでCSVデータを読み込みデータの計算をする方法

Question

前提・実現したいこと

Processingにおいて、Excelでつくったデータを読み込みそれをもとにグラフを作成しようとしています。データは読み込めたものの、そのデータを表示させることしかできなく、何をしたら良いかわからない状態です。
実現したいことは
①データを読み込む
②読み込んだデータ内で適当に選んだ数値と数値を足す
③データ内の数値すべてに共通の数値をかける
ことです。

発生している問題・エラーメッセージ

今のところ、実行するとデータの数値が実行結果として表示されてしまいます

該当のソースコード

void setup(){
background(255);
size(800,400);

   Table csvData = loadTable("2.csv","csv");  
     
   fill(0);  
     
   //1行目  
   text(csvData.getString(0,0), 10,20);  
   text(csvData.getString(0,1), 50,20);  
   text(csvData.getString(0,2), 90,20);  
     
   //2行目  
   text(csvData.getString(1,0), 10,40);  
   text(csvData.getString(1,1), 50,40);  
   text(csvData.getString(1,2), 90,40);  
     
   //3行目  
   text(csvData.getString(2,0), 10,60);  
   text(csvData.getString(2,1), 50,60);  
   text(csvData.getString(2,2), 90,60);  
     
   noLoop();   //ループしない  
     

}

void draw(){
stroke(0,25,62);

}

試したこと

配列を作ってみようと思いましたが、うまくいきませんでした。

補足情報（FW/ツールのバージョンなど）

Processing3.5.3

Comments

[azuapricot]

CVS　× CSV ◎

[退会済みユーザー]

ご指摘ありがとうございます。コンビニエンスストアになっていたのを修正いたしました

[Y.H.]

非道い質問者ですね。。。

Answer 1

グラフを書くならExcelのほうが早いし簡単ですよね？
学習目的か、なにか別の目的があるのかがわかったほうが回答しやすいです。

自力で描きたい場合は、こちらがわかりやすそうです。
棒グラフをプログラムで作ってみる – Yasushi Noguchi Class

手っ取り早く表示するなら、このライブラリが参考コードもあってわかりやすそうでした。
giCentre utilities — giCentre

適当にｇｇっただけなので、他にもっといいものがあるかもしれません。

配列で詰まっておられるようなので、簡単にサンプルを作ってみました。

自力版

void setup() {
  background(255);
  size(800, 400);
  noLoop();

  Table csvData = loadTable("2.csv", "header,csv");
  int rowCount = csvData.getRowCount(); // ヘッダを除いた行数（データ件数）

  // データ分の配列を作成
  String[] names = new String[rowCount]; // 名前の配列
  int[] heights = new int[rowCount]; // 身長の配列
  int[] weights = new int[rowCount]; // 体重の配列
  float[] bmis = new float[rowCount]; // BMIの配列

  // データを配列に代入
  for (int i = 0; i < rowCount; i++) {
    names[i] = csvData.getString(i, "名前");
    heights[i] = csvData.getInt(i, "身長");
    weights[i] = csvData.getInt(i, "体重");
    bmis[i] =  weights[i] / ((heights[i] * 0.01) * (heights[i] * 0.01)); // 体重(kg) / (身長(m) * 身長(m))

    println("名前:" + names[i] + "  身長:" + heights[i] + "cm  体重:" + weights[i] + "kg  BMI:" + bmis[i]);
  }

  // 表の表示
  fill(0);
  for (int i = 0; i < rowCount; i++) {
    int y = 20 + i * 20;
    text(names[i], 10, y);
    text(heights[i], 50, y);
    text(weights[i], 90, y);
    text(bmis[i], 130, y);
  }

  // グラフ背景の表示
  int scale = 10; // 数字が小さいので引き延ばす倍率
  fill(250, 100, 100); // 肥満の色
  rect(180, 0, 40 * scale, rowCount * 23);

  fill(250, 250, 200); // 普通の色
  rect(180, 0, 25 * scale, rowCount * 23);

  fill(170, 250, 250); // 痩せの色
  rect(180, 0, 18.5 * scale, rowCount * 23);

  // グラフの表示
  fill(127);
  for (int i = 0; i < rowCount; i++) {
    int y = 5 + i * 22;
    rect(180, y, bmis[i] * scale, 15);
  }
}

ライブラリ版

import org.gicentre.utils.stat.*; // グラフライブラリを使えるようにする

// 各関数（setupとdraw）で使えるようにBarChart型の変数を宣言
BarChart barChart;

void setup()
{
  size(800, 400);

  Table csvData = loadTable("2.csv", "header,csv");
  int rowCount = csvData.getRowCount(); // ヘッダを除いた行数（データ件数）

  // データ分の配列を作成
  String[] names = new String[rowCount]; // 名前の配列
  int[] heights = new int[rowCount]; // 身長の配列
  int[] weights = new int[rowCount]; // 体重の配列
  float[] bmis = new float[rowCount]; // BMIの配列

  // データを配列に代入
  for (int i = 0; i < rowCount; i++) {
    names[i] = csvData.getString(i, "名前");
    heights[i] = csvData.getInt(i, "身長");
    weights[i] = csvData.getInt(i, "体重");
    bmis[i] =  weights[i] / ((heights[i] * 0.01) * (heights[i] * 0.01)); // 体重(kg) / (身長(m) * 身長(m))

    println("名前:" + names[i] + "  身長:" + heights[i] + "cm  体重:" + weights[i] + "kg  BMI:" + bmis[i]);
  }

  // BarChartの作成・データをセット
  barChart = new BarChart(this);
  barChart.setData(bmis);
  barChart.setBarLabels(names);

  // 最大値・最小値の設定
  barChart.setMinValue(0);
  barChart.setMaxValue(40);

  // 色の設定
  barChart.setAxisColour(0);
  barChart.setAxisLabelColour(0);
  barChart.setAxisValuesColour(0);

  // 軸の表示
  barChart.showValueAxis(true);
  barChart.showCategoryAxis(true);
} 

void draw()
{
  background(255);

  // 表示範囲を決めグラフの表示
  barChart.draw(15, 15, width - 30, height - 30);
  noLoop();
}

2.csv

名前,身長,体重
Aさん,182,80
Bさん,167,48
Cさん,170,98

Comments

[退会済みユーザー]

回答ありがとうございます。
拙い質問に答えてくださったこと非常に嬉しく思います。

大変恐縮ではございますが、回答を実行してみたところ、うまく表示されませんでした。自力版のデータを配列に代入のfor文の中身を教えていただきたいです。

[TN8001]

自力版のコードと私の"2.csv"（回答の最後についています）で表示されませんか?
csvをUTF-8で保存してください。思い当たるのはそれくらいです。
それでも回答コードが動かない場合は、エラーが出ているならばそれをコピペしていただいてコメントください。

forの内容ですが
まずヘッダー付きのcsv（1行目に各桁の名前が付いているもの）を読み込む場合、Table csvData = loadTable("2.csv", "header,csv");とheader,と入れる必要があります。
csvData.getString(0, "名前")等、そのヘッダーを指定してアクセスができます。
この場合csvData.getString(0, 0)と同じ意味です。ヘッダーを飛ばして2行目の最初の桁 "Aさん"になります。

heights[i] = csvData.getInt(i, "身長");（csvData.getInt(i, 1);）
を例にとりますと
heights[0] = csvData.getInt(0, "身長");
heights[1] = csvData.getInt(1, "身長");
heights[2] = csvData.getInt(2, "身長");
とやっていることになります。
同じように名前・体重も取得し何か計算をされたいようだったので、例としてBMI（Body Mass Index 肥満度を表す指数のひとつ）を計算しました。

回答コードは動いてmimaiさんのcsvにうまく適用できない時や、配列やforについての疑問があれば新たに質問を立てていただけたらと思います。

[退会済みユーザー]

ご丁寧に解説ありがとうございます。勉強になりました。
また、csvをUTF-8で保存したら上手くいきました。

TN8001さんのおかげでなんとか自分がつくりたいと思っていたプログラムが完成しました。
本当にありがとうございました。

Answer 2

コンピュータはあなたが指示した通りにしか動きません。「適当に」とか「同じ数を」とかいう指示は通用しません。
まず、あなたが「何をさせたいのか」をはっきり把握しましょう。なにをさせたいのかがわからなければどういう指示を出せばいいのか(どういうプログラムを与えればいいのか)がわかる訳ありませんから。

Comments

[退会済みユーザー]

回答ありがとうございます。
もっとたくさん考えて、やってみます。

本当にありがとうございました。