Excel VBA 0と空白の比較

Question

前提・実現したいこと

Excelで表を作り、VBAで比較を行うようにしたいのですが、0と空白セルの比較が同じになり、比較がうまくいきません。
例1か例2に1以上の数字があったら空の判定は出来るのですが、どちらかに0があると空の判定が出来ません。。
どちらかに空のセルがあったら判定が空にしたいです。
理想形↓

列1	列2	判定
1	1	正
1	2	誤
1		空
0		空

該当のソースコード

If (Cells(ii, 1).Value = Cells(ii, 2).Value) Then
 Cells(ii, 3).Value = "正"
 ElseIf (Cells(ii, 1).Value = Empty) Or (Cells(ii, 2).Value = Empty) Then
    Cells(ii, 3).Value = "空"
 Else
    Cells(ii, 3).Value = "誤"
  End If

結果

列1	列2	判定
1	1	正
1	2	誤
1		空
0		正

試したこと

空白の比較などを調べてみて.Value = ""、.HasFormula、.Formula = ""などを試してみましたが、同じでした。

補足情報（FW/ツールのバージョンなど）

Excel 2016

Comments

[takasima20]

(チェックの順番的な意味で)最初に empty を確認したら?

[nuko3]

確認の順番を変えるという方法は試していませんでした...これが正解でした。ありがとうございます。

Answer 1

takasima20さんも書いてますが、先にemptyを見ればいいような気がします。
その他の案としては、文字列として比較すればいけます。
最初のIf文を次のようにしてみてください。

' 方法１：Valueを文字列に変換する
If CStr(Cells(1, 1).Value) = CStr(Cells(1, 2).Value) Then

' 方法２：Textプロパティで比較する
If Cells(1, 1).Text = Cells(1, 2).Text Then

Answer 2

Cells().Value = Empty ではなく、
IsEmpty(Cells())で判定するべきですね。

空文字も含めて、空かどうか判定したい時は、
CStr(Cells().Value) = ""　と、自分は書きます。
※型を意識して、明示的に文字列型で判定させましょう。

Comments

[imihito]

IsEmpty関数が用意されている意味、セルがエラー値の場合を想定すると、私もこの方法がベストだと思います。

Answer 3

以下のようにしてください。
0のセルの場合もEmptyが成立しますので、空白セルは""で判定してください。
msgboxへ表示しているのは、0の場合に、Emptyが成立が成立することを確認する為です。

Public Sub 空白試験()
    Dim ii As Long
    For ii = 1 To 4
        If Cells(ii, 1).Value = "" Or Cells(ii, 2).Value = "" Then
            Cells(ii, 3).Value = "空"
        ElseIf Cells(ii, 1).Value = Cells(ii, 2).Value Then
            Cells(ii, 3).Value = "正"
        Else
            Cells(ii, 3).Value = "誤"
        End If
        If Cells(ii, 1).Value = Empty Then
            MsgBox (Cells(ii, 1).Address & "=Empty")
        End If
    Next
End Sub

Comments

[nuko3]

ありがとうございます。空の判断を先にしてみると、0も空になってしまいましたが、書いてある通り、=Enptyを=""にしてみると理想の形になりました。

Answer 4

まあ、取りあえずは評価順序を変更するのが手っ取り早くはあります。

If (Cells(ii, 1).Value = Empty) Or (Cells(ii, 2).Value = Empty) Then
  Cells(ii, 3).Value = "空"
ElseIf (Cells(ii, 1).Value = Cells(ii, 2).Value) Then
  Cells(ii, 3).Value = "正"
Else
  Cells(ii, 3).Value = "誤"
End If

Answer 5

追記・修正の依頼にてtakasima20さんがおっしゃっている通りなので回答として改めて記載するのも恐縮ですが…
以下の通りチェックの順番を入れ替えることで解決すると思います。

If (Cells(ii, 1).Value = Empty) Or (Cells(ii, 2).Value = Empty) Then
  Cells(ii, 3).Value = "空"
ElseIf (Cells(ii, 1).Value = Cells(ii, 2).Value) Then
  Cells(ii, 3).Value = "正"
Else
  Cells(ii, 3).Value = "誤"
End If