そのUnlitシェーダー内で、ピクセルのワールド座標を使って何かしたいということでしょうか?
sakura_hanaさんにご紹介いただいた【Unityシェーダ入門】ポリゴンをポイント(点)で表現する - おもちゃラボの中で、ピクセルのY座標に応じて色を付けている箇所がありますが、これと同じ手法が使えるのではないでしょうか。
たとえば下記のようにすると...
ShaderLab
1Shader "Unlit/WorldPosition"
2{
3 Properties
4 {
5 _MainTex ("Texture", 2D) = "white" {}
6 }
7 SubShader
8 {
9 Tags { "RenderType"="Opaque" }
10 LOD 100
11
12 Pass
13 {
14 CGPROGRAM
15 #pragma vertex vert
16 #pragma fragment frag
17 // make fog work
18 #pragma multi_compile_fog
19
20 #include "UnityCG.cginc"
21
22 struct appdata
23 {
24 float4 vertex : POSITION;
25 float2 uv : TEXCOORD0;
26 };
27
28 struct v2f
29 {
30 float2 uv : TEXCOORD0;
31 UNITY_FOG_COORDS(1)
32
33 // v2fにワールド座標伝達用のfloat3を追加
34 // セマンティクスは適当なTEXCOORDを使えばいいでしょう
35 // (「TEXCOORD」という名前ですが、テクスチャ座標に限らず自由に使って構わないかと思います)
36 // すでにTEXCOORD0はテクスチャUV用、TEXCOORD1はフォグ効果用に使われてしまっているので
37 // TEXCOORD2を使うことにしました
38 // もしテクスチャ座標やフォグ効果が不要なら削除してしまい、空いたTEXCOORDを利用してもOKです
39 float3 worldPos : TEXCOORD2;
40
41 float4 vertex : SV_POSITION;
42 };
43
44 sampler2D _MainTex;
45 float4 _MainTex_ST;
46
47 v2f vert (appdata v)
48 {
49 v2f o;
50 o.vertex = UnityObjectToClipPos(v.vertex);
51 o.uv = TRANSFORM_TEX(v.uv, _MainTex);
52 UNITY_TRANSFER_FOG(o,o.vertex);
53
54 // モデルの頂点座標をモデル変換行列(unity_ObjectToWorld)で変換し
55 // ワールド座標にして、それのxyzをworldPosに渡す
56 o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
57
58 return o;
59 }
60
61 fixed4 frag (v2f i) : SV_Target
62 {
63 // sample the texture
64 fixed4 col = tex2D(_MainTex, i.uv);
65 // apply fog
66 UNITY_APPLY_FOG(i.fogCoord, col);
67
68 // 先ほどのo.worldPos(頂点のワールド座標)は頂点間で線形補間され、フラグメントシェーダー内で
69 // 取り出したi.worldPosは「ピクセルのワールド座標」になっている
70 // 試しに、xyzそれぞれに2を足して4で割り、-2~2 → 0~1となるようにして、
71 // これでcolのrgbを上書きしてみると、ワールド座標に応じてピクセルがカラフルに塗られる
72 // なお、-2~2の範囲を超えた部分は0~1の範囲から外れるため、色が飽和して変化がなくなる
73 col.rgb = (i.worldPos + float3(2.0, 2.0, 2.0)) / 4.0;
74
75 return col;
76 }
77 ENDCG
78 }
79 }
80}
81
下図のように、ピクセルのワールド座標を色として可視化することができました。