指定範囲で選択されたセルの行を塗りつぶしたい

Question

いつもこちらのサイトでは、お世話になっております。

Excelのマクロについて質問させてください。

指定範囲で選択されたセルの行を塗りつぶしたいのですが、
方法はありますでしょうか？

例えば、Range("A4:E9999")の範囲で
選択されたセルの行だけを塗りつぶしたいと思っております。

それ以外の範囲はマクロが適用されないようにしたいと思っております。

以下のコード1で試したところ、
選択されたセルの行全体が塗りつぶされてしまうので、
コード2を試すとコンパイルエラーが出ました。

■コード1

Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
  Dim highlight As Integer
  highlight = 6
 
  Cells.Interior.ColorIndex = 0
  Rows(Target.Row).Interior.ColorIndex = highlight

End Sub

■コード2

Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
  Dim highlight As Integer
  highlight = 6
  Cells.Interior.ColorIndex = 0

  If Range("A4:E999999").Select Then
  Rows(Target.Row).Interior.ColorIndex = highlight
   End If

End Sub

アドバイスいただけると幸いです。
どうぞよろしくお願い申し上げます。

Answer 1

今出先なので試せていませんが、下記のような感じでどうですか？

Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
  Dim highlight As Integer
  highlight = 6

  Cells.Interior.ColorIndex = 0

  Set tr = Intersect(Target.EntireRow, Range("A4:E999999"))
  If Not tr Is Nothing Then
    tr.Interior.ColorIndex = highlight
  End If

End Sub

Intersect は、２つの範囲が共有しているセルを返すメソッドです。
それで、共有部分があれば（Nothingでなければ）その範囲を色付けします。
ちなみに tr は Target Range の略のつもりで、Range型変数です。

Comments

[hirororo]

素早いご回答ありがとうございます！

作成頂いたプログラムを入力したところ、
指定範囲のセルの行を塗りつぶすことができました。

出先でいらっしゃる中、
的確なアドバイスありがとうございます。

ここで出た問題について、
一つ質問させて頂いてもよろしいでしょうか？

指定範囲以外で塗りつぶしたセルの背景色も
デフォルトの白に戻ってしまいますので、
こちらを元に戻らないようにする方法はありますでしょうか？

条件付き書式を試してみたのですが、
デフォルトの白に戻ってしまいます。

アドバイスいただけると幸いです。
どうぞよろしくお願い申し上げます。

[pi-chan]

それはプログラム内で下記のように指定しているからでは？
> Cells.Interior.ColorIndex = 0
指定範囲内だけをリセットしたいなら
> Range("A4:E999999").Interior.ColorIndex = 0
とすれば良いです。

[hirororo]

ご回答ありがとうございます！
おかげさまで無事、解決できました。

的確なアドバイスありがとうございますm(__)m

Answer 2

Target.Row で、該当行が取得できますよね？
そして、列はA～Cが対象。

「999999」は意味のある数字でしょうか？
今は特に意識せず進めます。

セル範囲は、RangeとCellsを組み合わせる事でも指定できます。
詳細はご自分で調べてくださいね。
With Me
.Range(.Cells(Target.Row , 1), .Cells(Target.Row , 3)).Interior.ColorIndex = highlight
End With

Comments

[hirororo]

素早いご回答ありがとうございます！

「999999」は列の下まで指定範囲が届くように、
この数字にさせて頂きました。

RangeとCellsについては詳しく調べて、
作成頂いたコードで試したいと思います。

アドバイスありがとうございますm(__)m

Answer 3

選択した選択した範囲を　for each 構文で処理してはどうでしょうか。

Range("A4:E999999").Select

Dim r as Range
for each r in Selection
r.Interior.ColorIndex = highlight
next

Comments

[ExcelVBAer]

何の解決にもなっていませんよ。。。
問題の意図は、「選択した行の指定した列範囲を塗り潰したい」、ということかと。

[hirororo]

素早いご回答ありがとうございます！
コードを理解するために、ご提案頂いた
for each 構文を勉強させて頂きたいと思います。

[TanakaHiroaki]

for each r in Selection　は役に立つと思います。

必要なセル範囲が都度変わる場合、事前にセル範囲を
選択しマクロを実行して、処理させることも可能です。