引数でactiveXのコンボボックスが渡せない

Question

環境
Window10
Excel2010

Option Explicit

Private settingSheet As Worksheet                           '設定シート
Private row As Long                                         'Excel行



Private Sub Workbook_Open()



    'コンボボックスにメニューをセットする
    Dim cmbStaff1Skill  As ComboBox
    
    Set cmbStaff1Skill = ThisWorkbook.Worksheets("予約").OLEObjects.Item("cmbStaff1Skill")

    createComboBox(cmbStaff1Skill,1,1,1)
    
    'コンボボックスに時間をセットする
    
End Sub
'--------------------------------------------------------------
'コンボボックスにリストを詰める
'--------------------------------------------------------------
Sub createComboBox(cbmBox As ComboBox, stRow As Long, edRow As Long, col As Long)

    '操作シートの設定
    Set settingSheet = ThisWorkbook.Worksheets("設定")
    
    For row = stRow To edRow
    
        
     cbmBox.AddItem (settingSheet.Cells(row, col).Value)
     
    
    
    Next row
    

End Sub

上記のコードで【createComboBox(cmbStaff1Skill,1,1,1)】の箇所でコンパイルエラー（構文エラー）となるのですが
なにがいけないのでしょうか？

Answer 1

    'コンボボックスにメニューをセットする
    Dim cmbStaff1Skill  As ComboBox

    Set cmbStaff1Skill = ThisWorkbook.Worksheets("予約").OLEObjects.Item("cmbStaff1Skill").Object

    Call createComboBox(cmbStaff1Skill2, 1, 1, 1)

または、

    'コンボボックスにメニューをセットする
    Dim cmbStaff1Skill  As ComboBox

    Set cmbStaff1Skill = ThisWorkbook.Worksheets("予約").cmbStaff1Skill

    Call createComboBox(cmbStaff1Skill2, 1, 1, 1)

で、いいかと。

Answer 2

コードでかっこを使用する

VBAでは、プロシージャの結果が返されない場合、結果を使用しない場合は引数に括弧をつけてはいけません。
括弧をつけていいのは、結果を使用する場合及び、Callステートメントを使用する場合のみです。

今回はSubプロシージャのため、結果が返されません。

そのため括弧を外すかCallを付ける必要があります。

createComboBox cmbStaff1Skill2, 1, 1, 1

Call createComboBox(cmbStaff1Skill2, 1, 1, 1)

同様のことがcreateComboBox内のcbmBox.AddItem (settingSheet.Cells(row, col).Value)にも言えます。

こちらの処理も括弧は不要です。
現在ついている括弧は、引数の指定とは異なる意味の括弧となっています。

---

追記

ローカルウィンドウ等を使えば確認出来ることですが、[Worksheet].OLEObjects.Item()の返り値はExcel.OLEObjectとなります。

実際に組み込まれているオブジェクト（今回はComboBox）は[OLEObject].Objectプロパティから参照できます。

Comments

[sobue]

callを付けましたが、型が一致しませんとなりました。

[sobue]

comboBOXの型をObjectに変えてみましたが、変えるとプロパティがありませんと、実行時エラーになってしまいます。

[imihito]

回答に追記をしました。ローカルウィンドウなどを表示して、変数の中を確認するとなぜエラーになったかがわかるかと思います。