指定したpixelの太さの線を描画するShader

Question

指定したpixelの太さの線を描画するShaderそのものがネット上に探してもなかったため、下記サイトのShaderを改修して、指定したPixelの太さの線を描画するShaderを実装しようとしているのですが、当方Shaderど素人につき、行き詰まったため質問を投稿いたしました。
【Unity】カメラからどれだけ離れても、最低1ピクセルは表示されるように保障する - 神様は有休消化中です。

上記サイトのShaderを使ったMeshに対してズームすると、当然ながらそのObjectが大きく表示されます。
指定したpixelの太さの線を描画することが目的のため、ズームしても大きくならないようにする方法を自分なりに調べたところ、UnityObjectToClipPos(v.vertex)によってズーム後の頂点座標になってしまっているからだと考えているのですが、正しいでしょうか？

その場合、指定したpixelの太さにするために、ズーム後の頂点座標にしないようにするためにはどうすればよろしいでしょうか？

初歩的な質問となりますが、どうぞよろしくお願いいたします。

使用しているMesh生成のコード

    public static Mesh CreateLineMesh(Vector3 center, float length, float thickness)
    {
        var mesh = new Mesh();
        var triangles = new int[6];
        triangles[0] = 0;
        triangles[1] = 1;
        triangles[2] = 2;
        triangles[3] = 2;
        triangles[4] = 3;
        triangles[5] = 0;
        var vertices = new Vector3[4];

        var left = center.x - length / 2.0f;
        var right = center.x + length / 2.0f;
        var bottom = center.y - thickness / 2;
        var top = center.y + thickness / 2;

        vertices[0] = new Vector3(left, bottom, center.z);
        vertices[1] = new Vector3(left, top, center.z);
        vertices[2] = new Vector3(right, top, center.z);
        vertices[3] = new Vector3(right, bottom, center.z);

        var nornals = vertices.ToArray();

        mesh.SetVertices(vertices);
        mesh.SetTriangles(triangles, 0);
        mesh.SetNormals(nornals);

        mesh.RecalculateBounds();

        return mesh;
    }

Answer 1

最初から2つの三角形が組み合わさって線になっているメッシュに対してUnityObjectToClipPos(v.vertex)で変換すると、確かにズーム後の位置へ変換されてしまうかと思います。
メッシュ自体は太さのない線（MeshTopologyがLinesまたはLineStripのメッシュ）としておいて、シェーダー上で線の頂点をクリップ空間に変換した後で、線が太さを持つ長方形になるよう三角形を生成させるのはどうでしょうか。

Shader "Unlit/ConstantWidthLine"
{
    Properties
    {
        _Color ("Color", Color) = (1.0, 1.0, 1.0, 1.0)
        _LineWidth ("Line Width", Range(0.0, 16.0)) = 4.0
    }
    SubShader
    {
        Tags { "RenderType" = "Opaque" }

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma geometry geom
            #pragma fragment frag
            #include "UnityCG.cginc"

            struct v2g
            {
                float4 screenPos : TEXCOORD0;
            };

            struct g2f
            {
                float4 vertex : SV_POSITION;
            };

            v2g vert(float4 vertex : POSITION)
            {
                v2g o;

                // バーテックスシェーダー上で折れ線の各頂点をクリップ座標に変換する
                o.screenPos = UnityObjectToClipPos(vertex);
                
                // さらに、ついでにスクリーンの大きさに合わせて引き伸ばしておく
                o.screenPos.xy *= _ScreenParams.xy * 0.5;
                
                return o;
            }

            float _LineWidth;

            // トポロジーが線のメッシュ（太さのない線）から線分の両端の2頂点を受け取り、
            // トポロジーが三角形のメッシュ（太さを持つ長方形）として4隅の頂点を出力する
            [maxvertexcount(4)]
            void geom(line v2g input[2], inout TriangleStream<g2f> outStream)
            {
                // 線分の両端の座標をwで割ってスクリーン座標を求める
                float2 p0 = input[0].screenPos.xy / input[0].screenPos.w;
                float2 p1 = input[1].screenPos.xy / input[1].screenPos.w;

                // 線分に平行なベクトルを求めておく
                float2 tangent = p1 - p0;
                float sqrLength = dot(tangent, tangent);
                if (sqrLength > 0.0)
                {
                    // tangentを90°回転してnormalとする
                    float2 normal = tangent.yx * float2(-1.0, 1.0);
                    
                    // normal、tangentの長さを線幅の半分にして...
                    float scale = (_LineWidth * 0.5) / sqrt(sqrLength);
                    normal *= scale;
                    tangent *= scale;

                    // p0とp1をtangent、normalの方向にずらした4頂点を作り、
                    // クリップ座標に戻して出力する
                    g2f o;
                    float2 s = (_ScreenParams.zw - 1.0) * 2.0;
                    o.vertex = input[0].screenPos;
                    o.vertex.xy = (p0 + normal - tangent) * o.vertex.w * s;
                    outStream.Append(o);
                    o.vertex.xy = (p0 - normal - tangent) * o.vertex.w * s;
                    outStream.Append(o);
                    o.vertex = input[1].screenPos;
                    o.vertex.xy = (p1 + normal + tangent) * o.vertex.w * s;
                    outStream.Append(o);
                    o.vertex.xy = (p1 - normal + tangent) * o.vertex.w * s;
                    outStream.Append(o);
                }
            }

            fixed4 _Color;

            fixed4 frag(g2f i) : SV_Target
            {
                return _Color;
            }
            ENDCG
        }
    }
}

ただしこの方法ですと、「ジオメトリシェーダ・コンピュートシェーダのモバイル対応状況【Unity】｜アマガミナブログ」で挙げられているような一部環境（たとえばグラフィックスシステムにMetalが使われているような）では動かないかと思います。その場合は別の手を考えてみようと思いますが、おそらくメッシュの作り方にも手を加える必要があるように予想されますので、メッシュを作る部分のスクリプトもご提示いただけると参考になりそうです。

追記

まず、メッシュ生成部分を下記のようにしてみました。

    // CreateLineMeshの引数のthicknessは廃止し、マテリアル側で設定することにする
    public static Mesh CreateLineMesh(Vector3 center, float length)
    {
        var mesh = new Mesh();
        var triangles = new int[6];
        triangles[0] = 0;
        triangles[1] = 1;
        triangles[2] = 2;
        triangles[3] = 2;
        triangles[4] = 3;
        triangles[5] = 0;
        var vertices = new Vector3[4];

        // bottomとtopはcenter.yとし、現時点では太さのない潰れた長方形の状態にしておく
        var left = center.x - length / 2.0f;
        var right = center.x + length / 2.0f;
        var bottom = center.y;
        var top = center.y;

        vertices[0] = new Vector3(left, bottom, center.z);
        vertices[1] = new Vector3(left, top, center.z);
        vertices[2] = new Vector3(right, top, center.z);
        vertices[3] = new Vector3(right, bottom, center.z);

        var nornals = vertices.ToArray();

        // 各頂点に追加情報を埋め込む
        // まずXYZには線分の逆末端の座標をいれておく
        // （left側頂点にはright側の、right側頂点にはleft側の座標）
        var otherVertices = new Vector4[vertices.Length];
        for (var i = 0; i < otherVertices.Length; i++)
        {
            otherVertices[i] = vertices[vertices.Length - i - 1];
        }

        // そしてWには0～3の数値を入れておく
        // これは各頂点が4隅のうちどれであるかを特定する目的のもので、さしあたり
        // 1ビット目がbottomかtopかを、2ビット目がleftかrightかを示すことにした
        otherVertices[0].w = 0;
        otherVertices[1].w = 1;
        otherVertices[2].w = 3;
        otherVertices[3].w = 2;

        mesh.SetVertices(vertices);
        mesh.SetTriangles(triangles, 0);
        mesh.SetNormals(nornals);

        // 追加情報の埋め込み先はUVを使わせてもらうことにした
        mesh.SetUVs(0, otherVertices);

        mesh.RecalculateBounds();

        return mesh;
    }

そしてマテリアルは下記のようにしました。

Shader "Unlit/Line"
{
    Properties
    {
        _Color ("Color", Color) = (1.0, 1.0, 1.0, 1.0)
        _Thickness ("Thickness", Range(0.0, 128.0)) = 4.0
    }
    SubShader
    {
        Tags { "RenderType" = "Opaque" }

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float4 otherVertex : TEXCOORD0;
            };

            float _Thickness;

            float4 vert(appdata v) : SV_POSITION
            {
                float4 p0 = UnityObjectToClipPos(v.vertex);
                float4 p1 = UnityObjectToClipPos(float4(v.otherVertex.xyz, 1.0));

                // 線分の両端の座標をスクリーン座標に変換する
                float2 sp0 = (p0.xy * _ScreenParams.xy) * (0.5 / p0.w);
                float2 sp1 = (p1.xy * _ScreenParams.xy) * (0.5 / p1.w);

                // 線分に平行なベクトルを求めておく
                // このとき、頂点がleftかrightかによって向きを調整する
                float2 tangent = (sp0 - sp1) * (((int)v.otherVertex.w & 2) - 1);
                float sqrLength = dot(tangent, tangent);
                if (sqrLength > 0.0)
                {
                    // tangentを90°回転してnormalとする
                    float2 normal = tangent.yx * float2(-1.0, 1.0);
                    
                    // normalの長さを線幅の半分にして...
                    normal *= (_Thickness * 0.5) / sqrt(sqrLength);

                    // 頂点をnormalの方向にずらす
                    // このとき、頂点がbottomかtopかによって向きを調整する
                    p0.xy = (sp0 - normal * (((int)v.otherVertex.w & 1) * 2 - 1)) * p0.w * (_ScreenParams.zw - 1.0) * 2.0;
                }

                return p0;
            }

            fixed4 _Color;

            fixed4 frag() : SV_Target
            {
                return _Color;
            }
            ENDCG
        }
    }
}

Comments

[concern12]

ご回答ありがとうございます。
そうですね。私もそのリンク先を読んでジオメトリシェーダーはではない手法(質問文の頂点シェーダー)を使おうとしていました。
質問文に記載するべきでした。申し訳ありません。

Meshのコードにつきましては、質問の方に追記いたしました。
お手数をおかけし申し訳ありませんが、よろしくお願い致します。

[Bongo]

コードご提示ありがとうございます。ジオメトリシェーダー抜きの案を検討してみましたがいかがでしょうか。
メッシュ側の各頂点に追加情報として線分の末端座標や長方形上の角の位置を埋め込むことで、vert上で頂点を移動させる際の手がかりにする方針でやってみました。

[concern12]

コードと理解にしやすい詳細なコメントありがとうございます!

実際に試したところ、Game View上では、Edit->Project Settings->Anti Aliasingの設定がDisabledだと描画されません。
どうやら`x2 Multi Sampling`以上であれば描画されるようです。
これはどういった理由によるものでしょうか？
重ねての質問になり恐縮ですが、もしご存知であれば教えていただければ幸いです。

[Bongo]

すみません、まだ私の方で描画されない現象を再現できておらず（Windows版2022.1.4f1とMac版2022.1.11f1で試してみたのですが、マルチサンプリングありでもDisabledでも描画されていたようでした）、原因不明な状態です...
何か手がかりを掴みたいところですが、新規にプロジェクトを作成して今回の線関係のファイルだけ用意し、シーンに線オブジェクトを配置しただけの状態でもアンチエイリアスの有無によって描画されたりされなかったりするでしょうか?
あるいは、消えてしまう現象はカメラと線の位置関係だとかが関係ありそうですかね?回答のコードでは考慮していなかったのですが、「線の末端の一方がカメラの前方、もう一方がカメラの後方」という状況だと座標計算が狂って線が欠けてしまうかもしれません。

[concern12]

検証してくださりありがとうございます。

色々と試してみました。
すべてUnity 2021.2.19f1で実行しました。

新規3D Projectで設定変更なし→描画される
新規3D ProjectでAnti Aliasing Disabled→描画される

新規3D ProjectでProject Settings->Qualityの設定をすべて新規2D Projectのものにする→描画される

新規2D Projectで設定変更なし→描画される
新規2D ProjectでAnti Aliasing Disabled→描画されない
新規2D ProjectでAnti Aliasing Disabledでビルド→描画されない

新規2D ProjectでProject Settings->Editor->Modeを2Dに切り替えて1回目の再生→描画されない
新規2D ProjectでProject Settings->Editor->Modeを3Dに切り替えて2回目以降の再生→描画される

(Project Settings->Editor->Modeの切り替えは切り替えた直後の再生では反映されないのかもしれません)

カメラの位置を調整してもとくに変化はありませんでした。

2D設定か3D設定かで、レンダリングの工程が違うのかもしれません。
ただ、下のサイトを読んでも特にそれっぽい記述はありませんでした。
[2D/3D モード設定 \- Unity マニュアル](https://docs.unity3d.com/ja/2019.4/Manual/2DAnd3DModeSettings.html)

[Bongo]

お待たせしてしまいすみません。さまざまな条件をご提示いただいて参考になりました。
おっしゃるようにレンダリング工程の違いが起因しているかもしれません。アンチエイリアスの設定だとか2D/3Dモードの違いによっては（確かにマニュアルでは特に言及されていないようですね）、メッシュをダイレクトにスクリーンへレンダリングするか、または一旦レンダーテクスチャ上にレンダリングしてから後処理を加えつつスクリーンへレンダリングするかが切り替わっているように見えました。

「様々なグラフィックス API のシェーダーの作成 - Unity マニュアル」（https://docs.unity3d.com/ja/current/Manual/SL-PlatformDifferences.html ）の説明にありますように、レンダーテクスチャ上への描画の場合は環境に応じて座標系の上下が反転される場合があり、反転の有無によって線を太くする際の引き伸ばし方向が影響を受け、メッシュが裏返った場合は線が消えてしまうんだろうと思います。
とりあえず、シェーダーコード中の...

float2 normal = tangent.yx * float2(-1.0, 1.0);

という部分を、

float2 normal = tangent.yx * float2(-1.0, 1.0) * -sign(UNITY_MATRIX_P._22);

に変更するとどうなるかお試しいただけますでしょうか。normalの向きにY軸の符号を反映させればいいんじゃないかと考えまして、私の試した限りではこれでアンチエイリアスの有無によらず描画できたように見えました。ですがまだ見落としがあるかもしれませんので、もし不具合を見つけましたらコメントください。

[concern12]

ご回答ありがとうございます。
描画されることを確認しました。
とても助かりました！
親切ご丁寧に対応いただきありがとうございました。