ExcelのVBAからAS/400のCLプログラムを実行し、戻り値を取得したい。

Question

前提・実現したいこと

ExcelのVBAからストアドプロシージャ経由でCLコマンドを実行し、結果を戻り値として取得したい。
パラメータを含めて実行すると、実行はされるのですが戻り値が返ってきません。

エラー無く動いてしまっている為、特定できず困っているのですが、戻り値を取得する場合に下記コードで不足している箇所はありますでしょうか。
INは出来ているので処理は動くのですが、結果件数が得られず困っております。
ご教示のほどよろしくお願いいたします。

Dim con As ADODB.Connection
Dim cmd As ADODB.Command
Dim ReturnField As String

Set con = New ADODB.Connection
Set cmd = New ADODB.Command

con.Open "Provider=IBMDA400; Data Source=xxx.xxx.xxx.xxx", "user", "pass"

Set cmd.ActiveConnection = con

With cmd
    .CommandText = "CALL TESTLIB.TESTCL(?,?)"
    .Prepared = True
    .Parameters.Append cmd.CreateParameter("Parm1", adChar, adParamInput, 2)
    .Parameters.Append cmd.CreateParameter("Parm2", adChar, adParamInputOutput, 2)
End With

With cmd
    .Parameters(0).Value = "A1"
    .Parameters(1).Value = ""
End With

'*-- IBM i 処理実行 --*
cmd.Execute 　' Rcds, Parms, adCmdText 
　　　　　　　' ↑参考URLに記載があったが、エラーが出るのでコメントアウト

'*-- 戻り値の取得 --*
ReturnField = cmd.Parameters(1).Value

Cells(1, 1) = ReturnField

'*-- connectionのクローズ、開放 --*
cmd.ActiveConnection.Close
Set con = Nothing

End Sub

CREATE PROCEDURE TSTLBS/TESTS1(IN P1 CHAR ( 2), INOUT P3 CHAR ( 2)) 
LANGUAGE CL NOT DETERMINISTIC MODIFIES SQL DATA EXTERNAL NAME 
TESTLIB/TESTCL PARAMETER STYLE GENERAL       

0001.00              PGM        PARM(&IN1 &OUT1)
0002.00              DCL        VAR(&IN1) TYPE(*CHAR) LEN(2)  
0003.00              DCL        VAR(&OUT1) TYPE(*CHAR) LEN(2) 
0004.00              CHGVAR     VAR(&OUT1) VALUE('11')
0005.00 ENDPGM

試した・確認したこと

・AS/400単体でCLを実行すると正常に戻り値が返ってくることを確認。
・追加仕様のCLに変えた所、ExcelからINするパラメータ値はDBに登録されていた。
・INOUT値なので値'10'をセットして実行すると、変更の無いまま'10'が表示される。
・ストアドプロシージャの記述に問題があるのかと、ストアド記述で一通り考えられる組み合わせを試してみたのですが上手く行くことはありませんでした。

参考：http://side-as400.seesaa.net/article/264485967.html

Answer 1

ADO の Command オブジェクトに CommandType というプロパティがあります。
これに adCmdStoredProc を指定して試してもらえますか？
AS/400 は使ったことがありませんが、SQL Server であれば、下記の方法で Output 引数の値を取得できることを確認しました。

With cmd
    .CommandText = "SP_TEST"
    .CommandType = adCmdStoredProc
    .Prepared = True
    .Parameters.Append cmd.CreateParameter("Parm1", adChar, adParamInput, 2)
    .Parameters.Append cmd.CreateParameter("Parm2", adChar, adParamInputOutput, 2)
End With

＜参考＞
■ ADO を使用してSQL Serverストアド プロシージャの値を取得する
https://docs.microsoft.com/ja-jp/troubleshoot/sql/connect/retrieve-values-stored-procedure

Comments

[DANGAN-X]

回答頂きありがとうございます。
早速試してみた所、実行時エラーが出てしまいました。
調べてみるとAS/400側のエラーみたいで、この方法では実行できないようです。

実行時エラー '-2147467259(80004005)':
SQL0104: トークンTESTLIBは正しくない。有効なトークンは( INTO USINGです。

[cx20]

IBM のサポートページに以下のページを見つけました。こちらの情報が参考になるかもしれません。

■ ADO Stored Procedure Calls with MSDASQL
https://www.ibm.com/support/pages/ado-stored-procedure-calls-msdasql

このページで紹介されている方法としては、DB ドライバに「IBMDA400」ではなく ODBC ドライバ「MSDASQL」を用いた方法のようです。

[cx20]

以下、他のサンプルになります。DBドライバで「IBMDA400」を使用して adCmdStoredProc パラメータも使用しているようです。

■ Need to Call RGP from ASP - RPG (Report Program Generator) - Tek-Tips
https://www.tek-tips.com/viewthread.cfm?qid=1179429

> objConn.Open "Provider=IBMDA400;Data Source=My_AS400_IP;Default Collection=MYLIB ", "", ""
>
> Set objCmd.ActiveConnection = objConn
> objCmd.CommandText = "MYSP"
> objCmd.CommandType = adCmdStoredProc

[cx20]

上記の例に倣うと、使用方法としては以下のような感じでしょうか？
------------------------------------------------------------
con.Open "Provider=IBMDA400; Data Source=xxx.xxx.xxx.xxx;Default Collection=TESTLIB", "user", "pass"

With cmd
　.CommandText = "TESTCL"
　.CommandType = adCmdStoredProc
　　:
End With
------------------------------------------------------------

[DANGAN-X]

AS/400の経験が無いにも関わらず親身にアドバイスを頂きありがとうございます。
サンプルで挙げて頂いたサイトを見て試行錯誤した所、無事戻り値を得る事が出来ました。
INパラメータだけなら最初の仕様で動くのですが、OUTパラメータを指定する場合はCommandTextの{}が必須という事に気付きました。
結果凡ミスで大変お手数をお掛けして申し訳ございませんでした。

With cmd
.CommandText = "{CALL TESTLIB.TESTCL(?,?)}"
.Prepared = True
.Parameters.Append cmd.CreateParameter("Parm1", adChar, adParamInput, 2)
.Parameters.Append cmd.CreateParameter("Parm2", adChar, adParamInputOutput, 2)
End With

[cx20]

> {}が必須
なるほど。了解です。解決されたようで何よりです。