[Unity] Orthographic camera で高低差を可視化したい

Question

　現在、Unity 3Dでトップビューのゲームを作成しています。オブジェクトの側面を見られたくないのでカメラのProjectionをOrthographic(平行投影法)にしています。
しかし実際にビルドして遊んでみると高低差がわかりづらくなってしまいました。

そこで上の画像のようにプレイヤーより上のテクスチャーは青っぽく、下のテクスチャは赤っぽくして(段差は急に色が変わる)高低差を可視化したいと考えています。
Fogで実装しようとしたのでうが、奥行は表現できても手前の色が表現できません。
何かいい方法はありませんか？教えいてください。

PC: mac
Unity2021.3.4f1 Appleシリコン
言語：C#

Comments

[bboydaisuke]

マルチポスト
https://detail.chiebukuro.yahoo.co.jp/qa/question_detail/q11263439606

[0711TM]

マルチポストという言葉を今日初めて知りました。URLの質問を削除しました。申し訳ありません。

Answer 1

一例として、床のマテリアルを下記のようにしてみてはいかがでしょうか?

Shader "Custom/VisualizeRelativeElevation"
{
    Properties
    {
        _Color ("Color", Color) = (1.0, 1.0, 1.0, 1.0)
        _PositiveColor ("Positive Color", Color) = (0.0, 0.0, 1.0, 1.0)
        _NeutralColor ("Neutral Color", Color) = (1.0, 1.0, 1.0, 1.0)
        _NegativeColor ("Negative Color", Color) = (1.0, 0.0, 0.0, 1.0)
        _HeightScale ("Height Scale", Range(0.0, 4.0)) = 1.0
        _MainTex ("Albedo (RGB)", 2D) = "white" {}
        _Glossiness ("Smoothness", Range(0.0, 1.0)) = 0.5
        _Metallic ("Metallic", Range(0.0, 1.0)) = 0.0
    }
    SubShader
    {
        Tags { "RenderType" = "Opaque" }
        LOD 200

        CGPROGRAM
        #pragma surface surf Standard addshadow fullforwardshadows
        #pragma target 3.0

        sampler2D _MainTex;

        struct Input
        {
            float2 uv_MainTex;
            float3 worldPos;
        };

        half _Glossiness;
        half _Metallic;
        fixed4 _Color;
        fixed4 _PositiveColor;
        fixed4 _NeutralColor;
        fixed4 _NegativeColor;
        float _ReferenceHeight;
        float _HeightScale;

        void surf(Input IN, inout SurfaceOutputStandard o)
        {
            fixed4 c = tex2D(_MainTex, IN.uv_MainTex) * _Color;

            // プレイヤーのワールドY座標(_ReferenceHeight)に対する
            // ピクセルのワールドY座標(IN.worldPos.y)に応じて
            // アルベドに色を上乗せする
            float deltaHeight = IN.worldPos.y - _ReferenceHeight;
            c.rgb *= lerp(
                _NeutralColor.rgb,
                deltaHeight > 0.0 ? _PositiveColor.rgb : _NegativeColor.rgb,
                saturate(abs(deltaHeight) / _HeightScale));
            
            o.Albedo = c.rgb;
            o.Metallic = _Metallic;
            o.Smoothness = _Glossiness;
            o.Alpha = c.a;
        }
        ENDCG
    }
    FallBack "Diffuse"
}

そしてプレイヤーには下記のようなスクリプトをアタッチし、プレイヤーの位置をシェーダーに伝達させてはいかがでしょう。

using UnityEngine;

public class ReferenceHeightSetter : MonoBehaviour
{
    private static readonly int ReferenceHeight = Shader.PropertyToID("_ReferenceHeight");

    private void Update()
    {
        Shader.SetGlobalFloat(ReferenceHeight, this.transform.position.y);
    }
}

Comments

[0711TM]

回答有難うございます！理想の動きです！こちらで試しても動きました！
床のテクスチャーの入れるスペース(?)もあって最高です！
自分で試行錯誤している時にシェーダーグラフを使うとできるっぽい、というところまでしか分かりませんでした
有難うございます！

[0711TM]

Bongo様のほかの回答を見ましたがとても物知りですね！
初めてのゲームを作っているのですが、壁にぶちあたってばかりです。
その領域に達するまでにどんな事をしましたか？
宜しければ教えてくれませんか？

[Bongo]

私としてはアマチュアの趣味の域だと思っており、そんな風に評価していただいて恐縮ですが、私の場合ですと今回のようなご質問に挑戦してみるのがちょうどいい刺激になると感じております。ご質問者さんの場合は、おそらく「壁にぶちあたってばかり」とおっしゃる部分が知識習得のチャンスになるんじゃないかと思います。調べ回ってみても行き詰まってしまうようでしたら遠慮なくご質問いただければ、どなたか案をお持ちの方から意見をいただけるかもしれません。そうすれば次回からは同じような事例に対処できるようになり、一歩上達したと言えるんじゃないでしょうか。

[0711TM]

貴重なアドバイス有難うございます！
私はまだまだ経験不足ですが一歩ずつ進んでいいゲームを作れるように頑張ります
お世話になりました！