感圧センサーによるLED制御

Question

実現したいこと

感圧センサーを用いて，一定時間の圧力を検知したら，緑色のLEDを消灯し，赤色のLEDを点灯させたいです．一定時間の圧力を検知しない場合，緑色のLEDは消灯し，赤色のLEDを点灯し続けたいです．

ブレッドボード

発生している問題・エラーメッセージ

一回目に感圧センサーを8秒間押したときは緑色のLEDが3秒間点灯し，赤色のLEDが消灯します．しかし，二回目以降の感圧センサーを押しても，一定時間の圧力がかかっていないのに，すぐに緑色のLEDが点灯し，赤色のLEDが消灯してしまいます．感圧センサーの押された時間の計測方法が適切ではないという予想はしていますが，どのように改善すればよいかわかりません.押された時間のリセットが必要なのでしょうか．ご教授お願い致します．

該当のソースコード

const int green = 13;
const int red = 2;
const int vol = 0;
int startTime;

void setup() {
  pinMode(green,OUTPUT);
  pinMode(red,OUTPUT);
}

void loop() {
  int sensorValue = analogRead(vol);
  if(sensorValue < 1000){
    startTime = millis();
    if(startTime >= 8000){
      digitalWrite(green,HIGH);
      digitalWrite(red,LOW);
      delay(5000);
    }
  }
  else{
    digitalWrite(green,LOW);
    digitalWrite(red,HIGH);
  }
}

試したこと

startTime = 0;により計測された時間のリセットを試みましたが，うまくいきませんでした．

Answer 1

millis()の意味を勘違いしているか、ロジックが間違えています。

millisは以下にあるとおり、arduinoの電源を入れたときからの経過時間を表わしています。
http://www.musashinodenpa.com/arduino/ref/index.php?f=0&pos=2518

なので、以下のように書いてしまうと、単に「電源を入れてから8秒経っていたら」という判定をしていることになり、質問のような動作になってしまいます。

    startTime = millis();
    if(startTime >= 8000){

ボタンが押されている時間を計測するのであれば、ざっくりと以下のような処理にする必要があります。
ポイントは、ボタンが押されていないときに、スタート時間をリセットしつづけるところです。

if(sensorValue < 1000){
     # 時間計測処理
     if millis() - button_on_time > 8000 {
        # 8秒経ったときの処理
    }
} else {
    # ボタンが押されていないときは、常に時刻をリセットする
   button_on_time = millis()
}

考えたかとしては、押されていない状態から、押された状態になったときの時刻を取るのが正しいのですが、状態の変化を管理するのが面倒なのでこうしてます。
この方式でやってみるのもいいと思います。

Comments

[power-chan]

回答ありがとうございます．仰るとおりmillis()の仕様を勘違いしていました．提示いただいたコードも理解することができました．

Answer 2

以下のコードを試してみて下さい

const int green = 13;
const int red = 2;
const int vol = 0;
unsigned long startTime = 0;

void setup() {
  pinMode(green, OUTPUT);
  pinMode(red, OUTPUT);
}

void loop() {
  int sensorValue = analogRead(vol);
  
  if (sensorValue < 1000) {
    if (startTime == 0) {
      startTime = millis();
    }
    
    if (millis() - startTime >= 8000) {
      digitalWrite(green, HIGH);
      digitalWrite(red, LOW);
      delay(5000);
    }
  } else {
    digitalWrite(green, LOW);
    digitalWrite(red, HIGH);
    startTime = 0;
  }
}

Comments

[power-chan]

回答ありがとうございます．理想通りに動きました！質問なんですが，提示いただいたコードの19行目のmillis()はどのタイミングから計測が始まるのですか？millis() - startTime の記述がよくわかりません．

[退会済みユーザー]

19行目の millis() 関数は、Arduinoボードが起動してからのミリ秒単位の経過時間を返す関数です。この値はArduinoが動作している間、一貫して増加し続けます。

startTime 変数は、プログラム内で一定の条件が満たされると、millis() の値が記録されるタイミングを示すために使用されます。具体的には、以下のコードを考えてみましょう：

if (sensorValue < 1000) {
if (startTime == 0) {
startTime = millis();
}

if (millis() - startTime >= 8000) {
// 一定時間経過したときの処理
}
} else {
// 条件を満たさない場合の処理
startTime = 0; // startTimeをリセット
}

上記のコードブロックで、センサーの値が1000未満である場合、以下の2つの条件文があります：

if (startTime == 0)：もし startTime がまだ初期化されていない（0である）場合、現在の時間を millis() で取得し、startTime に記録します。これにより、カウントが始まるタイミングが記録されます。

if (millis() - startTime >= 8000)：もし millis() から startTime を引いた結果が8000ミリ秒（8秒）以上の場合、特定の条件が8秒以上継続していることを意味します。この条件が満たされると、緑色のLEDが点灯し、その後の遅延が行われます。

要するに、millis() - startTime は、startTime に記録された時間から現在の経過時間を引いた値で、特定のアクションがある時間以上経過したかどうかを判断するために使用されています。

[power-chan]

ご返事ありがとうございます．miilis()の仕様を勘違いしていました．ご丁寧な解説感謝いたします．