バッチから外部コマンドを呼んだ際に、文字列の戻り値とerrorlevelを同時に取得したい

Question

外部コマンドが文字列を１つ返すものだった場合、例えばPythonだと、
for /f "delims=" %%A in ('python test.py') do set result=%%A
とか書けば戻り値は取れますが、直後のerrorlevelはfor文に対してなのでpythonでエラーが有っても1を返しません。

pythonでエラーがあったときにはバッチからリトライさせて、戻り値を取りたいのですが、どうすればよいでしょうか？

python側でprint(戻り値)を処理の最後に書いて、それ以前でエラーが起きていたら何も帰ってこない、か、戻り値はファイル渡し、というのは思いつくのですが、変な縛りになるし、できればバッチ側だけで処理したいと思っています。よろしくお願いします。

追記：
Copilot君も「戻り値をファイル渡しにするしか無理じゃね？」と言っているのでそうなのかもしれませんが、そうなるとtmpファイル名の重複を避けるために命名規則を決めなきゃならず、守っていないコードを見つけ出すのがとても難儀なのです。。

Answer 1

出力をファイルに書くのが簡明です。一時ファイル名は、%0と%RANDOM%と%TIME%とかで、どうにかする。あるいは、mkdirを使って占有するディレクトリーを作ってその中に書くか。

副作用の無いプログラムだと、出力取得と、戻り値取得で、2回実行するのも分かり易いです。実行時間がそんなに長くなければですが。

それらが難しそうなら、他の手段はあります。
本来の出力の後で、戻り値を出力して、取得してから分ける。
お書きのコードからして、出力は必ず1行限定のようなので、その場合はわりと分かり易いです。
（ダブルクォートとシングルクォートを両方使うのでusebackqでバッククォートも使う）

setlocal enabledelayedexpansion
for /f "usebackq delims=" %%A in (
    `python -c "import os;print(os.system('python test.py'))"`
    ) do set RESULT=!CC!&set CC=%%A
echo OUTPUT=%RESULT% CC=%CC%

出力が複数行あるなら少し変えないと。

参考：占有のディレクトリーを作る

setlocal
set WORK_DIR=～～～～
:LOOP
set MY_WORK=%WORK_DIR%\%~n0-%RANDOM%
rem すでに別に処理で同名の物が作られていれば失敗するので別の名前でやり直す
mkdir %MY_WORK% 2>NUL
if ERRORLEVEL 1 goto LOOP

python test.py >%MY_WORK%\foo.txt
set CC=%ERRORLEVEL%
type %MY_WORK%\foo.txt

rmdir /s /q %MY_WORK%

追記：最初の案で遅延環境変数展開を使わずサブルーチンを使う

setlocal
for /f "usebackq delims=" %%A in (
    `python -c "import os;print(os.system('python test.py'))"`
    ) do call :SUB "%%~A"
echo OUTPUT=%RESULT% CC=%CC%
exit /b

:SUB
set "RESULT=%CC%"
set "CC=%~1"
exit /b

Comments

[AkiOsawa]

今まで遅延嫌いでしたが、こんな使い方があるとは、目からウロコです。大規模開発になればなるほどファイル渡しは使いたくないので、こちらを極めようと思います。ありがとうございました！

[otn]

変数を順繰りにずらせば良いだけなので、遅延環境変数展開を使わなくてもその部分をサブルーチンにすれば出来ます。追記しました。

> 今まで遅延嫌いでしたが
ほとんどの場合は、サブルーチンにすることで、遅延環境変数展開は不要です。
変数値を引数で渡す時に、CMDの特殊記号がいろいろ含まれていると面倒or不可能ですが。

> 大規模開発になればなるほどファイル渡しは使いたくないので
ストレージ経由を避けるとしたら速度要因くらいですが、速度を気にするなら、バッチファイルで良いのか？という気もします。