Wordのマクロでマクロ設定ファイルのみナビゲーションウィンドウを表示したい

Question

前提

word 2021

目次を作成したwordファイル表示時に自動的にナビゲーションを表示して
PDFのしおりのように使用したいと思い、マクロでナビゲーションの自動表示を設定しました。
しかし、マクロを設定したファイルのみナビゲーションを表示したいのですが、
一旦マクロの設定があるファイルを開いてナビゲーションが表示されると、
他のwordファイル(マクロ設定なし)を開いた時にもナビゲーションが表示されてしまいます。

実現したいこと

あくまでもマクロの範囲はマクロ設定ファイルのみにしておきたいのですが、
何か方法はありますでしょうか？

該当のソースコード

Private Sub Document_Open()
   ThisDocument.ActiveWindow.DocumentMap = True
End Sub
Private Sub Document_Close()
    ThisDocument.ActiveWindow.DocumentMap = False
End Sub

試したこと

Document_Open()の部分でナビゲーションは表示されるので
同じくDocument_Close()でFalseを設定すればナビゲーションが非表示になって終わればいいなと思ったんですが駄目でした。
Project配下のThisDocumentファイルに記述しています。

何か方法はありますでしょうか？

Answer 1

WithEvents 変数を使用して、Word.Application オブジェクトでの各イベントの発生時にナビゲーションウィンドウを非表示化する処理を実行なさればよろしいでしょう。

'ThisDocumentモジュール
Option Explicit

'WithEvents 変数の宣言
Private WithEvents appWord As Word.Application

'このドキュメントが開かれた時
Private Sub Document_Open()
    
    'ナビゲーションウィンドウを表示
    Application.ActiveWindow.DocumentMap = True
    
    'Word アプリケーションの参照
    Set appWord = Application

End Sub

'このドキュメントが閉じられる時
Private Sub Document_Close()
    
    Dim docNew As Word.Document

    '現在開かれているドキュメントが1つだけ（このドキュメントのみ）である場合
    If appWord.Documents.Count = 1 Then
        'ナビゲーションウィンドウを非表示に
        appWord.ActiveWindow.DocumentMap = False
        '画面の更新をオフに
        appWord.ScreenUpdating = False
        'ダミー用新規ブックの作成
        Set docNew = appWord.Documents.Add
        'ナビゲーションウィンドウを非表示に
        appWord.ActiveWindow.DocumentMap = False
        '新規ブックを保存せずに閉じる
        docNew.Close False
        Set docNew = Nothing
        '画面の更新をオンに
        appWord.ScreenUpdating = True
    End If

    'Word アプリケーションの参照を解放
    Set appWord = Nothing

End Sub

'Word アプリケーションによって新規の Word ドキュメントが作成された時
Private Sub appWord_NewDocument(ByVal Doc As Document)
    
    'ナビゲーションウィンドウを非表示に
    appWord.ActiveWindow.DocumentMap = False

End Sub

'Word アプリケーションによって既存の Word ドキュメントが開かれた時
Private Sub appWord_DocumentOpen(ByVal Doc As Document)

    '開かれたドキュメントがこのドキュメントではない場合
    If Doc.FullName <> Me.FullName Then
        'ナビゲーションウィンドウを非表示に
        appWord.ActiveWindow.DocumentMap = False
    End If

End Sub

2023/02/01 15:22 追記:

マクロ有効ブックのみが開かれている状況においてそのブックが閉じられた時に、次に開かれたブック上においてナビゲーションウィンドウが表示されないようにするよう、Document_Close プロシージャのコードを修正しました。

Comments

[mimon]

ご回答ありがとうございます！
大変勉強になります。

確かにマクロ設定ファイルを開いたまま別のWordファイルを開いた場合はナビゲーションは表示されませんでしたが、マクロ設定ファイルを一旦閉じて別のWordファイルを開いた場合はナビゲーションが表示されてしまいました。
ファイルに設定したマクロが次回word起動時のデフォルトになってしまうイメージです。

[sk.exe]

> 確かにマクロ設定ファイルを開いたまま別のWordファイルを開いた場合は
> ナビゲーションは表示されませんでしたが、マクロ設定ファイルを一旦閉じて
> 別のWordファイルを開いた場合はナビゲーションが表示されてしまいました。

基本的に、新規ブックが作成された際や既存のブックが開かれた際において
そのブック上にナビゲーションウィンドウが初期表示されるか否かは、
その直前にアクティブだったブックにおけるナビゲーションウィンドウの
表示状態に左右されます。

例えば、マクロ有効ブックとは別に開かれているブックにおいて
既にナビゲーションウィンドウが表示されていて、前者のブックを閉じた後に
後者のブックがアクティブになっている状態でその更に別のブックを開けば
おっしゃるような結果になるでしょう。

マクロ有効ブックが開かれる前や閉じられた後のWordの挙動まで制御することはできませんし、
またユーザーの操作によって任意のブック上でナビゲーションウィンドウが
表示されることもありますので、それはそういうものだと割り切った方が
よいのではないかと思います。

[mimon]

度々のご回答ありがとうございます。
修正版もありがとうございます。試したところ希望通りの動きになっていました。
確かにあまり気にしなくてもよい制御かもしれませんが、
VBAの勉強にもなりましたので大変感謝しております。
お時間いただきありがとうございました！

[sk.exe]

コード修正後に再テストしてみたところ、ダミー用新規ブックを作成→閉じるまでの処理はなくてもよくて、ScreenUpdatingの制御だけでも何とかなるかもしれません。

[mimon]

度々ありがとうございます！
ちょっとネチネチやってみます。