processingの文字色を変えたい

processingで文字列からcharAt()メソッドで呼び出した文字の色を
時間で変化させたいのですがよくわかりません。

fillの変数（i）に数値を加算して変化させようとしたところ
文字列の長さが変わってしまいます。
うまくできないので修正をお願いしたいです。よろしくお願いします。

String s = new String("All is well that ends well.");
int x;
 void setup(){
 size(400, 100);
 
 textFont(createFont("Harrington", 24));
 colorMode(HSB, s.length() - 1);
 
 }
 int dh = 1;
 void draw(){
 background(s.length() - 1);
 int offset = 0;
 for(int i = 0; i < s.length(); i++){
     fill(i, s.length() - 1, s.length() - 1);
     text(s.charAt(i), (width - textWidth(s)) / 2 + offset, height / 2);
     offset += textWidth(s.charAt(i));
     i += dh;
   }
 }

行動規範の内容に同意します

回答1件

processingで文字列からcharAt()メソッドで呼び出した文字の色を
時間で変化させたいのですがよくわかりません。

「グラデーションを流れるように変化させる」といった感じでしょうか。

今のところ時間で変化する要素がありません。
dhも常に１ですし、ほかの変数の変化も一定です。

時間で変化する変数はframeCountがありますから、それを使いましょうか。

fillの変数（i）に数値を加算して変化させようとしたところ
文字列の長さが変わってしまいます。

i += dh;ここのところの話でしょうか。
iはループに使う変数ですからいじってはいけません。
fillに入れる値だけをいじります（わかりにくかったら別の変数を作ります）

fill(i + frameCountとすると、時間が経つほど大きくなっていきます。
しかし大きくなりすぎてしまうので、剰余（%）を使って制限します。

これで流れるようにはなりました。しかし右から左に流れて見えます。
左から右にするには引き算に変えますが、マイナスにならないように調整する必要があります。

println等で予定通りの値になっているか、確認しながら式を完成させましょう^^

Processing
1String s = "All is well that ends well.";
2int max = s.length() - 1;
3
4void setup() {
5  size(400, 100);
6  frameRate(5);
7  textFont(createFont("Harrington", 24));
8  colorMode(HSB, max, 1, 1);
9}
10
11void draw() {
12  background(max);
13
14  int offset = 0;
15  for (int i = 0; i < s.length(); i++) {
16    //int h = (i + frameCount) % max; // <<<
17    int h = (max + i - (frameCount % max)) % max; // >>>
18    //int h = (max + frameCount - i) % max; // 色の順番にこだわりがなければこれでも
19    //println(i, h);
20
21    fill(h, 1, 1);
22    text(s.charAt(i), (width - textWidth(s)) / 2 + offset, height / 2);
23    offset += textWidth(s.charAt(i));
24  }
25}