DHT22で取得した温度と湿度をArduinoを使ってLINEに通知したい

Question

DHT22で取得した温度と湿度をArduinoと使ってLINEに通知したい

ここに実現したいことを箇条書きで書いてください。
１　DHT22で温度と湿度を取得する
２　取得した温度と湿度をLINEで通知する

前提

Arduinoを使い、本体のBOOTボタンを押すと、あらかじめ設定した文字列
（const char* message = "aaaaaa";）をLINEに通知するまではできました。

発生している問題・エラーメッセージ

送信する文字列はchar型でなくてはいけないようですが、
LINEに送信したい文字列はDHT22で取得した温度と湿度なので、
messageはString型でなくてはいけないのですが、String型の文字列をchar型に変換することはできますか？
無理やり、

// 湿度を取得
float humidity = dht.readHumidity();
// 温度を取得
float temperature = dht.readTemperature();

ondo = String(temperature) + String("ﾟC、");
shitsudo = String(humidity) + String("%です。");

message = String("現在の室温は") + String(ondo) + String("湿度は") + String(shitsudo);

としたところ、エラー（35？）が出てしまいLINE送信できません。
String型をchar型に変換する方法はありませんか？

該当のソースコード

#include <WiFi.h>
#include <WiFiClientSecure.h>
#include <DHT.h>
#include <DHT_U.h>

// WiFi設定
const char* ssid     = "自宅WiFiのSSID";
const char* password = "自宅WiFiのパスワード";

// ピン設定
const int swPin = 0; 
const int PIN_DHT = 23;

String ondo = "";
String shitsudo = "";
String soushin = "";

// LINE Notify設定
const char* host = "notify-api.line.me";
const char* token = "LINEのトークン";
const char* message = "aaaaaa";
DHT dht(PIN_DHT,DHT22);

void setup()
{
    Serial.begin(115200);
    delay(10);

    // dhtライブラリの初期処理
    dht.begin();

    // We start by connecting to a WiFi network
    Serial.println();
    Serial.println();
    Serial.print("Connecting to ");
    Serial.println(ssid);

    WiFi.begin(ssid, password);

    while (WiFi.status() != WL_CONNECTED) {
        delay(500);
        Serial.print(".");
    }

    Serial.println("");
    Serial.println("WiFi connected");
    Serial.println("IP address: ");
    Serial.println(WiFi.localIP());

    // ピンを入力状態にする
    pinMode(swPin, INPUT_PULLUP);
}

// line通知
void send_line() {

  // HTTPSへアクセス（SSL通信）するためのライブラリ
  WiFiClientSecure client;

  // サーバー証明書の検証を行わずに接続する場合に必要
  client.setInsecure();
  
  Serial.println("Try");
  
  //LineのAPIサーバにSSL接続（ポート443:https）
  if (!client.connect(host, 443)) {
    Serial.println("Connection failed");
    return;
  }
  Serial.println("Connected");

  // リクエスト送信
  String query = String("message=") + String(message);
  String request = String("") +
               "POST /api/notify HTTP/1.1\r\n" +
               "Host: " + host + "\r\n" +
               "Authorization: Bearer " + token + "\r\n" +
               "Content-Length: " + String(query.length()) +  "\r\n" + 
               "Content-Type: application/x-www-form-urlencoded\r\n\r\n" +
                query + "\r\n";
  client.print(request);
 
  // 受信完了まで待機 
  while (client.connected()) {
    String line = client.readStringUntil('\n');
    if (line == "\r") {
      break;
    }
  }
  
  String line = client.readStringUntil('\n');
  Serial.println(line);
}

// スイッチの変数宣言
int sw_val = 0;

void loop()
{
  // put your main code here, to run repeatedly:
  int sw_state = digitalRead(swPin);

  dht.readHumidity();
  dht.readTemperature();

  if (sw_state==LOW)
  {
   // 湿度を取得
   float humidity = dht.readHumidity();
   // 温度を取得
   float temperature = dht.readTemperature();

   ondo = String(temperature) + String("ﾟC、");
   shitsudo = String(humidity) + String("%です。");

   soushin = String("現在の室温は") + String(ondo) + String("湿度は")  + String(shitsudo);

  message = soushin;

   send_line();  
  }
}

試したこと

char[] charArray = message.ToCharArray();

message = soushin.c_str()

Answer 1

118行目を
message = soushin.c_str();
とすることで少なくとも(ESP32 Devmoduleとして)コンパイルは通りますけれど? (動作チェックまではしていません)
それでなにか不都合があるのですか?

---

・エラーメッセージは(内容を損なわない自信があるのでない限り)全文を転記してください。それは、何故エラーになったのかという重要な情報です。不完全な転記では、結局回答者が追試験してみなければいけなくなります(まぁ、ちゃんと転記されていても大抵追試験はすることになるのですが、必要な情報が省略されて一手間余計感は否めません)
・試したことは、「試したこと」と「その結果」まで(できれば、なぜそうしてみたのかも)記してください。あなたが頑張ったことのアピールではなく、解決への情報とするためです。
・Arduinoには各種ボードがあり、それぞれコンパイラ設定や機種別ライブラリに癖があったりします。また、同じデバイスに対していくつかのライブラリがあったり、またボードやライブラリのバージョンで変更があったりもします。使用するハードウェアと、使用したライブラリ、バージョンを明らかにしてください。
(以上の「お願い」には今回は解決に寄与しない部分もあるかも知れませんが、一般にそれだけの情報が欲しいと思うもの、ということでご理解ください)

---

別解的に。たまたま今似たようなことをやっていて、自分の送信ルーチンは以下のようになっています。ご参考まで。

const String lineToken = "_your_line_token";

    WiFiClientSecure client;
    client.setInsecure();
    HTTPClient http;
    http.begin(client, "https://notify-api.line.me/api/notify");
    String host = "notify-api.line.me";
    String query = String("message=") + str;
    http.addHeader("Host", host, false, false);
    http.addHeader("Authorization", "Bearer " + lineToken, false, false);
    http.addHeader("Content-Length", String(query.length()), false, false);
    http.addHeader("Content-Type", "application/x-www-form-urlencoded", false, false);
    http.POST(query);
    http.end();

---

コメントのやりとりより、
"Content-Type: application/x-www-form-urlencoded\r\n\r\n"ということで、%はエスケープ文字になるということです。
'%'自身を表示したければ%35と表記するということのようで。

Comments

[tomohiro.camper]

thkanaさん
コメントありがとうございます。
まずは、いろいろとご指摘いただいたこと、大変勉強になりました。
今後も質問させていただく機会があると思いますので、できるだけ詳細に記述しようと思います。

118行目を
message = soushin.c_str();
としたところ、コンパイルまではうまくいくのですが、
Try
Connected
35
という表示が出て、LINE通知は送られません。

この記述をなくし、21行目の
const char* message = "aaaaaa";
のみで送信すると、
Try
Connected
1d
という表示され、通知を送ることができます。

この「35」というのは何かのエラー番号なのかと思い、LINE notifyについて調べてみたのですが、
見つけることができませんでした。

当方の環境です。
ボード　WayinTop ESP32開発ボード
ライブラリ
DHT-sensor-library（1.4.6）
ESP-Line-Notify（2.1.1）

よろしくお願いいたします。

[thkana]

では、まず
message = "現在の室温は12.3ﾟC、湿度は34.5%です。"
としてどうなるか確かめてみたらいかがですか? もしかしたら、℃(これは一文字)の表記にいわゆる半角カナ記号を使っているのがよくないのかも知れません。
(これはあてずっぽですが...)

当然、逆に
soushin = String("aaaaaa");
message = soushin.c_str();
としたらどうなるかも試してみたくなりますね。

[tmp]

application/x-www-form-urlencodedだから、パーセントエンコーディングですね。

[thkana]

では%記号自体は%25に置換すればよい、ということかしら(試してたソースを消しちゃったので...)

[tomohiro.camper]

tmpさん
thkanaさん

114行目を
shitsudo = String(humidity) + String("%です。");
↓
shitsudo = String(humidity) + String("%25です。");

にしたところ、無事に温度と湿度を取得してLINEに通知雨を送ることができました。
ありがとうございました。
パーセントエンコーディング、勉強になりました。

参考までに、tmpさん、application/x-www-form-urlencodedというのは、
どこからわかる情報なのでしょうか。何か参照した方が良いドキュメント等がありましたら、
教えていただけると勉強になります。

[thkana]

横から言っちゃうと、あなたが質問に上げたソースの79行目に書いてある。
> "Content-Type: application/x-www-form-urlencoded\r\n\r\n" +

[tomohiro.camper]

thkanaさん
ありがとうございます。
使いたいソースをつぎはぎで作ったのですが、1行ずつしっかりと読み直して、意味を勉強しようと思います。

この度はありがとうございました。とても勉強になりました。