Arduinoのセンサ反応回数を調べたい

前提

Arduino　Unoでホールセンサ（磁石を感知するセンサ）を利用しています。

実現したいこと

磁石をタイヤにくりつけ、タイヤが何周したのかを1秒ごとに図りたいと考えています。
より精密に測る為に、タイヤには複数個の磁石を付けております。

実現したいこととしては1秒間にセンサが何回反応したのかを数えたいです。またタイヤが動いているときは勿論オンとオフが激しく複数回切り替わると思いますが、止まっているときは常にオンもしくはオフとなることが予想されるため、1秒間常にオンもしくはオフの時は０を返すようなプログラムを作成したいです。

発生している問題・エラーメッセージ

エラーは出ませんが、例えばセンサが1回反応した、はどのように記述すればよいか困っています。
下記コード以外でもよい方法等があれば伺いたいです。

該当のソースコード

Arduino
1prev = 0;         // 前回実行時刻を初期化
2interval = 1000;   //1秒をミリ秒で表す
3count = 0;  // ここで何周かカウント
4
5void loop() {
6  unsigned long curr = millis();    // 現在時刻を取得
7  val=digitalRead(SENSOR);
8  if (val==LOW){  //磁石が近くにある
9    if (val==HIGH) { //磁石が遠ざかる
10      count=count+1;
11      if ((curr - prev) >= interval) {
12        Serial.println(count); 
13        count=0;
14        prev = curr;                    // 前回実行時刻を現在時刻で更新
15      }
16    }
17  } else if (val==HIGH) {  //磁石が近くにない
18      if ((curr - prev) >= interval) {
19        Serial.println(count); 
20        count=0;
21        prev = curr;                    // 前回実行時刻を現在時刻で更新     
22     }  
23  }else if (val==LOW) {  //磁石が近くにある
24      count=0;
25      if ((curr - prev) >= interval) {
26        count=0;
27        Serial.println(count); 
28        count=0;
29        prev = curr;                    // 前回実行時刻を現在時刻で更新     
30     }  
31  }

試したこと

色々なサイトを閲覧しここまで来ました。

補足情報（FW/ツールのバージョンなど）

ここにより詳細な情報を記載してください。

y_waiwai

2022/10/11 11:29

提示のコードではどういう動作をするんでしょうか。また、それをどのようにしたいんでしょうか

TakaiY

2022/10/11 11:50

タイヤはどれくらいの速度で回ることを想定していますか？ 1秒に何回転くらい？また、磁石はタイヤにいくつくらい付けていますか？

oishi

2022/10/11 12:10

y_waiwai様コメントありがとうございます。該当コードでは磁石が近くにないときのみ1秒おきに０が出力され、磁石を近づけると何も出力されなくなってしまいます。やりたいことはタイヤにくっつけた磁石に何回か反応するので、その1秒間の反応回数を調べたいです。（これは1つ目のif文に相当します）また、タイヤが動いていないときは1秒間常に反応している、もしくは反応していないはずなので、その時は０を出力したいです。（これは2つのelse if文に相当します。） 2つのelse if文のみを動作させれば(1秒間常にオンかオフ)うまくいっているので、1つ目のif文、磁石に反応したらカウントするプログラムの記述の仕方が分からないです。よろしくお願いいたします。

oishi

2022/10/11 12:11

TakaiY様コメントありがとうございます。タイヤは直径5センチほどで等間隔で4つつけています（もちろんセンサで測るときにお互いが干渉しない程度で離しています）。回転は大体ですが、1秒に2回転ほどです。

行動規範の内容に同意します

回答2件

まずは、タイヤが止っているときのことを忘れましょう。

タイヤは1秒に数回しか回らないということですから、loopでセンサをチェックする間隔は充分狭く、磁石が通過するまでに複数回 LOWを検出すると期待できます。
また、質問のソースを見ても、「LOWがHIGHになったときに1回と数える」ということにしようとしているようですから、以下のような感じにすれば回数を数えることができそうですよね。

c++
1void loop() {
2  unsigned long curr = millis();    // 現在時刻を取得
3  val=digitalRead(SENSOR);
4  if (val==LOW){  //磁石が近くにある 
5    while (digitalRead(SENSOR) == LOW);  // HIGHになるのを待つ
6    count=count+1;
7    curr = millis();
8    if ((curr - prev) >= interval) {
9        Serial.println(count); 
10        count=0;
11        prev = curr;                    // 前回実行時刻を現在時刻で更新
12    }     
13  }  
14  // val == HIGHのときは何もしない。
15}

LOWになったのを検出したら、 HIGHになるまで待つ(=LOWの間は空回り)するということです。

投稿2022/10/11 13:30

TakaiY

総合スコア14286

oishi

2022/10/12 02:09

ありがとうございます。大変勉強になりました。教えていただいたコードで実行してみると確かにタイヤが回っているときはしっかりと計測できました。ここから、タイヤが止まっている時にはどのようにすればよろしいのでしょうか？よろしくお願いいたします。

行動規範の内容に同意します

ベストアンサー

止まっているときは常にオンもしくはオフ

レベルでなくエッジで考える話でしょう。
ホール素子ならチャタリングもないでしょうから、ホール素子の出力の立ち上がりまたは立ち下がりエッジで割り込みを掛けることにすれば、自分でエッジ検出をする必要もないです。
割り込みのかかった回数を一秒間数えればよいように思います。

単純に割り込み(H->Lへの変化)の回数を数えるサンプル

Arduino
1const int INP = 3; //入力ピン(UNOでは2と3がピン割り込み対応)
2
3unsigned long t0;
4volatile int cnt;
5
6void countInc() {
7    cnt++;
8}
9
10void setup() {
11    Serial.begin(115200);
12    pinMode(INP, INPUT_PULLUP); //PULLUPは必要に応じて
13    attachInterrupt(digitalPinToInterrupt(INP), countInc, FALLING);
14    t0 = millis();
15}
16void loop() {
17    unsigned long t = millis();
18    if (t - t0 >= 1000) {
19        Serial.print(t);
20        Serial.print(':');
21        noInterrupts(); //cntの操作の競合を避けるため割り込み禁止
22        Serial.println(cnt);
23        cnt = 0;
24        interrupts();//割り込み再開
25        t0=t;
26    }
27}