フラグメントシェーダでテクスチャの一部をクリッピングする方法

Question

フラグメントシェーダで_MainTexの一部の範囲をクリップしたいのですが、先ほど初めてシェーダについて勉強し始めたばかりで詰まってます。お力添えいただけないでしょうか。
fixed4 frag(v2f i) : SV_Target
{
fixed4 col = tex2D(_MainTex, i.uv);
clip(i.uv.y - 0.5);
return col;
}
のように書くと_MainTexのテクスチャの上から半分がクリッピングされると思うのですが、画像で言うと黒い範囲をクリッピングする場合はどのように指定すればいいのでしょうか？
画像は分かりやすく説明するために作ったもので、実際はこの黒い範囲はスクリプトから数値を変えられるようにしたいです。なのでクリッピング用のテクスチャは使用せずスクリプトから数値を変更してクリッピング範囲を変えていくことになります。

Answer 1

外部から幅を設定できるようにプロパティを追加して、それをもとにclipを行うことになるかと思います。
一例としては、下記のような形はいかがでしょうか。

Shader "Unlit/ClipTopCenterBottom"
{
	Properties
	{
		_MainTex ("Texture", 2D) = "white" {}

		// 切り取り幅を設定するためのプロパティを追加
		_Top ("Top", Range(0.0, 1.0)) = 0.1
		_Center ("Center", Range(0.0, 1.0)) = 0.2
		_Bottom ("Bottom", Range(0.0, 1.0)) = 0.1
	}
	SubShader
	{
		Tags { "RenderType" = "Opaque" }
		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag

			#include "UnityCG.cginc"

			struct appdata
			{
				float4 vertex : POSITION;
				float2 uv : TEXCOORD0;
			};

			struct v2f
			{
				float2 uv : TEXCOORD0;
				float4 vertex : SV_POSITION;
			};

			sampler2D _MainTex;
			float4 _MainTex_ST;

			v2f vert(appdata v)
			{
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				o.uv = TRANSFORM_TEX(v.uv, _MainTex);
				return o;
			}

			// 切り取り幅を受け取る変数を追加
			// スクリプトから値を設定したい場合、これら「_Top」「_Center」「_Bottom」の名前を引数に
			// Material.SetFloatなどのユニフォーム変数設定用メソッドを使用する
			float _Top;
			float _Center;
			float _Bottom;

			fixed4 frag(v2f i) : SV_Target
			{
				// 下側...ご質問者さんの例示なさった「clip(i.uv.y - 0.5);」を可変にした形
				clip(i.uv.y - _Bottom);

				// 上側...V座標の上下を逆転し、下側と同様にクリッピングする形
				clip(1.0 - i.uv.y - _Top);

				// 中央...V座標の中央からの距離を求め、それをもとにクリッピングする形
				clip(abs(i.uv.y - 0.5) - _Center * 0.5);

				return tex2D(_MainTex, i.uv);
			}
			ENDCG
		}
	}
}