digitalWrite()とSerial1.write()の切り替えについて

Question

実現したいこと

Arduino DueでdigitalWrite()とSerial1.write()の切り替えをしたいです。
しかしdigitalWrite()からSerial1.write()を実行すると正しくシリアル通信をすることができません。
シリアルデータを送信すると1回目の送信には成功しますが、2回目以降は0が送信されてしまいます。
ちなみにArduino Megaでは切り替えをすることができていて、通信することができます。
原因と下記の理想の受信データにする方法を教えていただきたいです。
※この対象Dueの通信相手は別DueのSerial1のtx/rxで、その別DueはSerial1で受信したデータをそのまま16進数でUSBケーブルで接続したPCのシリアルモニタに送っています。

該当のソースコード

void setup() {
    const byte txData[6] = { 0xAA, 0xBB, 0xCC, 0xDD, 0xEE, 0xFF };

    //Serial1.write (1回目)
    Serial1.begin(9600);
    Serial1.write(txData, 6);
    Serial1.end();
    delay(1000);

    //digitalWrite
    pinMode(18, OUTPUT);
    digitalWrite(18, LOW);
    delay(50);
    digitalWrite(18, HIGH);
    delay(100);

    //Serial1.write (2回目以降)
    for(byte i = 0; i < 5; i++)
    {
        Serial1.begin(9600);
        Serial1.write(txData, 3);
        Serial1.flush();
        Serial1.end();
        delay(1000);
    }
}

void loop() {
    
}

シリアルモニタ(理想の受信データ)

AA BB CC DD EE FF
AA BB CC
AA BB CC
AA BB CC
AA BB CC
AA BB CC

シリアルモニタ(実際の受信データ)

AA BB CC DD EE FF
00

接続図

補足情報

【Arduino Due】
https://store-usa.arduino.cc/collections/boards/products/arduino-due
https://content.arduino.cc/assets/A000056-full-pinout.pdf

【データシート】
https://ww1.microchip.com/downloads/en/DeviceDoc/Atmel-11057-32-bit-Cortex-M3-Microcontroller-SAM3X-SAM3A_Datasheet.pdf

マルチポスト

https://teratail.com/questions/h3km9w6nkmhjgm
https://qiita.com/alyn/questions/78d9963e81f53ab13f75
https://ja.stackoverflow.com/questions/91802/digitalwrite%e3%81%a8serial1-write%e3%81%ae%e5%88%87%e3%82%8a%e6%9b%bf%e3%81%88%e3%81%ab%e3%81%a4%e3%81%84%e3%81%a6

Comments

[ozwk]

マルチポスト
https://ja.stackoverflow.com/questions/91802/digitalwrite%e3%81%a8serial1-write%e3%81%ae%e5%88%87%e3%82%8a%e6%9b%bf%e3%81%88%e3%81%ab%e3%81%a4%e3%81%84%e3%81%a6

https://qiita.com/alyn/questions/78d9963e81f53ab13f75

[Alyn]

質問を閉じれば回答いただけますか？

[ozwk]

こちらご確認ください
https://teratail.com/help#posted-otherservice

[ozwk]

stackoverflowの「マルチポストとはなんですか？何か問題があるのでしょうか？」も参考に対応してください

https://ja.meta.stackoverflow.com/questions/2418/%e3%83%9e%e3%83%ab%e3%83%81%e3%83%9d%e3%82%b9%e3%83%88%e3%81%a8%e3%81%af%e3%81%aa%e3%82%93%e3%81%a7%e3%81%99%e3%81%8b-%e4%bd%95%e3%81%8b%e5%95%8f%e9%a1%8c%e3%81%8c%e3%81%82%e3%82%8b%e3%81%ae%e3%81%a7%e3%81%97%e3%82%87%e3%81%86%e3%81%8b

[ozwk]

なお、質問を閉じても私は回答できない(実機がないから検証できない)ので
そんなやつの言うことは聞かないというのも質問者さん次第です。

[Alyn]

あまりにもここが過疎でしたので2つ登録して投稿しました。全部に貼り付けておきました

[ozwk]

シリアルUSB変換ICなどを使ってPCと通信しているかと思います。
何を使っていますか?
また、それはmegaのときと同じですか?

[Alyn]

このDueの通信相手は別のDueのSerial1のtx/rxで、その別DueはSerial1で受信したデータをそのまま16進数でUSBケーブルで接続したPCのシリアルモニタに送っています。

[ozwk]

DueとDue、MegaとMegaでやっているということでしょうか。
その場合であれば、送信と受信のどちらに問題(※)があるのかわからないので
Dueで送信したものをMegaで受信できませんか?

※そもそもSerialとdigitalWriteで線を共有することがあまり想定されていないので、これを問題とするのはArduinoが可哀想な気がする

[Alyn]

図を追加しました

[ozwk]

Megaでできたときの構成はどうなってますか?

[Alyn]

DueとMegaをそのまま入れ替えた構成で、書き込むプログラムは同じです

[ozwk]

2つともMegaに置き換えてますか?

[Alyn]

はい、電圧が異なるので交換しています

[ozwk]

dueが3.3VでMegaが5VなのでdueからMegaに送る分には過電圧にはなりません。
ロジックH/Lが正しく判定できるかは微妙ですが
dueのTxとMegaのRxを接続(もちろんGNDも)してどうなりますか?

[Alyn]

前提として1回目(6bytes)のデータ送信はできていて、しかしながら2回目以降のデータ送信ができなくなっています。

[ozwk]

それはわかっています。
2回目以降の挙動が受信側がDueだから発生しているのか、送信側がDueだから発生しているのかを切り分けたいのです

[Alyn]

UARTを利用した別の通信プロトコルのトランシーバで電圧変換して送っていますが、受信側はDueとMegaどちらも同じ挙動でした。しかし送信側をMegaに変えると受信側をDueとMegaどちらでも受信できています。

[ozwk]

根掘り葉掘り聞いて申し訳ありません
「UARTを利用した別の通信プロトコルのトランシーバ」とはなんですか?

[Alyn]

接続図で言えばTx1-Rx1間にそれぞれそのトランシーバーを介して送受信しており、それにより異なる電圧のマイコン同士で通信可能としています。ただしビット単位で全く同じ信号を送信していますので、オシロスコープで波形を見た時にはUARTと同じ波形ですので気にしないでください。

Answer 1

解決済ということなのでさらっと。

ちょっと追ってみると、pinMode -> Serial1.beginでGPIOからUSARTにピン割当が戻っていない様子。
ピン制御のレジスタを覗いてみると、pinModeの前で0x400e0e09の値がc0だったのがpinModeの後でc8になり、Serial1.beginの後でもc0に戻っていません。0x400e0e08～はPIO Controller PIO Status Registerで、この状態を変えるには0x400e0e04～(PIO Controller PIO Disable Register)に書き込めば良い様子。なので、

    digitalWrite(18, HIGH); //D18はPA11
    delay(100);
    *(uint32_t*)0x400e0e04=0x0800;//PA11 DISABLE
    //Serial1.write (2回目以降)

としてみると、シリアルが復活しました。まぁ、ライブラリの不具合といえばそうですね。Arduino DueのボードライブラリのリポジトリにIssueを投げておくとArduinoコミュニティへの貢献になるかもしれません。

なお、ブレーク(TXラインL)送出は、USARTにきっとそういう機能があるはず、と調べてみたらやっぱりあったので試してみました。
Serial1が生きている(beignの後、endの前)状態で
*(uint32_t*)0x40098000=0x0200;//USART Control RegisterにBRKSTT設定
でUSART0(Serial1)のTXラインがLになり
*(uint32_t*)0x40098000=0x0400;//BRKSTP設定
でHになりました。但し、Lになる期間はバイト送信の期間で量子化されて、9600bps設定で0.5msのパルスを出すようなことはできないみたいです。

詳細はSAM3X8Eのデータシートを確認してください。

(以前、ESP32のライブラリでSerial.begin()を繰り返すとプログラムが止まるという不具合があったりして(現状修正済)beignを繰り返すのにちょっと及び腰...でも、Arduinoライブラリでボーレート変更だけの仕組みって用意されていないんですよね)

Comments

[Alyn]

ありがとうございます！元々意図していた解答そのものです！データシートの読み方が分からず私はこの解答に至れませんでした。

[thkana]

Issueも投げておきました。Arduino-SAM (Due)のボードライブラリはあまりメンテされていないようですが、なにかの機会に正式版に取り込んでもらえるかも知れません。

Answer 2

なぜそのような挙動の違いが起きるのかはわからないので質問の直接の回答になりませんが、

シリアル通信する相手が、「一定時間RxをLにする」という操作を要求するのであれば
間にマルチプレクサなどを挟んで接続先をTxとGNDとで切り替えるという方法を提案します。

AND回路でも実現可能です。
TXとデジタル出力のANDを取ればデジタル出力がHの間はTXが出力に表れ、デジタル出力がLの間は出力がLになります

---

どうも"Serial Break"を送りたいという感じですので
これでできたりしません?

void setup() {
    const byte txData[6] = { 0xAA, 0xBB, 0xCC, 0xDD, 0xEE, 0xFF };

    //Serial1.write (1回目)
    Serial1.begin(9600);
    Serial1.write(txData, 6);
    Serial1.flush();
    delay(1000);

    //send serial break
    // わざと低速で0を送る
    Serial1.begin(300);
    Serial1.write(0);
    Serial1.flush();

    //Serial1.write (2回目以降)
    Serial1.begin(9600);
    for(byte i = 0; i < 5; i++)
    {
        Serial1.write(txData, 3);
        delay(1000);
    }
}

void loop() {
    
}

Comments

[Alyn]

ありがとうございます。おっしゃるとおり『シリアル通信する相手が、「一定時間RxをLにする」という操作』を必要としています。恐らくDueの入出力レジスタか何かのレジスタにリセットのような何かが必要ではないかと考えていますが、その記述とArduinoでそれを実行可能かが分からない状況です。。

[ozwk]

ただの興味なんですけどその相手とはなんですか?
差し支えなければ教えてください

[Alyn]

xxx通信です

[Alyn]

breakフィールドもですが、一番はウェイクアップシグナルフレームの5msのドミナントです

[ozwk]

ウェイクアップのドミナントであれば0.25ms~5msとあるので
0を1ビットだけ送ればスタートビット含め9ビット分Lが持続します。
9600bpsならおおよそ0.9msになり要件を満たしていそうです

[Alyn]

ありがとうございます！32000-1600bpsで1byteのSerial1.write(Zero, 1);で解決できそうです。※uint8_t Zero[1] = { 0 };

[ozwk]

Serial1.write(0, 1);はアドレス0 にあるデータを1byte送信ですので注意してくださいね

[Alyn]

訂正しました。ありがとうございました。