Arduino Nano キッチンタイマー作成

Question

前提

タイトルの通り、Arduinoとマイコンボードを利用して、キッチンタイマーを作成しています。

実現したいこと

A2ボタンを押したときに、カウントダウンを開始させたい。
つまり、if (st==0)内のswitch文のcase 0:(144行目)を実行したい。ちなみに、case 1: とcase 2:は実行される。

発生している問題・エラーメッセージ

カウントダウンが開始されない。つまり。st=1に切り替わらない。analogRead()を使っていることに関しては指摘しないでほしいです。仕様で決められているので。
ちなみに、switch文の内容をiで条件分岐せずに、for文に直接書く(つまり、i=0~3毎回実行する)となぜかcase 0 の内容が実行されます。

該当のソースコード

20~102行目はエラーとはあまり関係ないです。

#define SEG_G 3
#define SEG_F 4
#define SEG_E 5
#define SEG_D 6
#define SEG_C 7
#define SEG_B 8
#define SEG_A 9
#define SEG7_BIN0 10
#define SEG7_BIN1 11

#include <TimerOne.h>
#include "pitches.h"

unsigned int timecount = 0;
byte st = 0; // ステータス0~2
// 0：時間設定用モード(起動時)
// 1：カウントダウン開始
// 2：カウントダウン終了。1度Beepが鳴ると、時間設定用モードに切り替わる。

struct note {
  unsigned int frequency;
  unsigned long duration;
};

struct note melody[] = {
  {NOTE_D5, 500}
};

void setup() {
  // 7SEG用pinの設定
  pinMode(SEG_G, OUTPUT);
  pinMode(SEG_F, OUTPUT);
  pinMode(SEG_E, OUTPUT);
  pinMode(SEG_D, OUTPUT);
  pinMode(SEG_C, OUTPUT);
  pinMode(SEG_B, OUTPUT);
  pinMode(SEG_A, OUTPUT);

  // 欠けているピンの設定を行う
  pinMode(SEG7_BIN1, OUTPUT);
  pinMode(SEG7_BIN0, OUTPUT);

  pinMode(2, OUTPUT);

  pinMode(16, INPUT); //A2 モード切り替え用ボタン
  pinMode(17, INPUT); //A3　インクリメント
  pinMode(A6, INPUT); // デクリメント
  pinMode(A7, INPUT);
  Serial.begin(9600);

  Timer1.initialize(1000000);
  Timer1.attachInterrupt(count_down);
  Serial.begin(9600);
}

void write_a_digit(byte digit, byte data) {

  // 2bit で表示桁を指定するためのエンコード
  static const byte SEG7_DIG0[] = {1, 0, 1, 0};
  static const byte SEG7_DIG1[] = {1, 1, 0, 0};

  // 2bit で表示桁を指定
  digitalWrite(SEG7_BIN0, SEG7_DIG0[digit]);
  digitalWrite(SEG7_BIN1, SEG7_DIG1[digit]);

  // 対応する数字               　0  1  2  3  4  5  6  7  8  9
  static const byte SEG_GP[] = {0, 0, 1, 1, 1, 1, 1, 0, 1, 1};
  static const byte SEG_FP[] = {1, 0, 0, 0, 1, 1, 1, 0, 1, 1};
  static const byte SEG_EP[] = {1, 0, 1, 0, 0, 0, 1, 0, 1, 0};
  static const byte SEG_DP[] = {1, 0, 1, 1, 0, 1, 1, 0, 1, 1};
  static const byte SEG_CP[] = {1, 1, 0, 1, 1, 1, 1, 1, 1, 1};
  static const byte SEG_BP[] = {1, 1, 1, 1, 1, 0, 0, 1, 1, 1};
  static const byte SEG_AP[] = {1, 0, 1, 1, 0, 1, 1, 1, 1, 1};

  if (data < 10) { // 0～9 の時はその数字を表示
    digitalWrite(SEG_G, SEG_GP[data]);
    digitalWrite(SEG_F, SEG_FP[data]);
    digitalWrite(SEG_E, SEG_EP[data]);
    digitalWrite(SEG_D, SEG_DP[data]);
    digitalWrite(SEG_C, SEG_CP[data]);
    digitalWrite(SEG_B, SEG_BP[data]);
    digitalWrite(SEG_A, SEG_AP[data]);
  } else { // 10 以上の時は数字でも文字でも無いパターンを表示
    digitalWrite(SEG_G, 1);
    digitalWrite(SEG_F, 0);
    digitalWrite(SEG_E, 0);
    digitalWrite(SEG_D, 1);
    digitalWrite(SEG_C, 0);
    digitalWrite(SEG_B, 0);
    digitalWrite(SEG_A, 1);
  }
}

void clear_7seg() {
  digitalWrite(SEG_G, 0);
  digitalWrite(SEG_F, 0);
  digitalWrite(SEG_E, 0);
  digitalWrite(SEG_D, 0);
  digitalWrite(SEG_C, 0);
  digitalWrite(SEG_B, 0);
  digitalWrite(SEG_A, 0);
}

void count_down() {
  if (st == 1) {
    timecount--;
  }
}


void loop() {
  static unsigned long clicked = 0; // スイッチ押し始めの時刻
  static unsigned long last_beat = 0; // キーリピートした時刻
  unsigned int now; // 現在時刻
  unsigned int tmp; // 10 進数に変換するための一時変数
  int tmp_sw[4]; // 一時的に読み取った値を保持
  byte current_sw[4] ; // 現在のスイッチの状態を保持
  static byte last_sw[] = {0, 0, 0, 0}; // 一つ前のスイッチの状態を保持
  static byte digit[] = {0, 0, 0, 0}; // 各スイッチに対応する値を保持
  byte i; // ループ制御変数
  const unsigned long repeat_delay = 1000;
  const unsigned long interval = 200;

  now = millis(); // 現在時刻を記憶

  // 統一して扱うために全てアナログで読む。
  // index と表示位置の関係は一対一。 0 右端の桁、3 左端の桁
  tmp_sw[0] = analogRead(A2);
  tmp_sw[1] = analogRead(A3);
  tmp_sw[2] = analogRead(A6);
  tmp_sw[3] = analogRead(A7);

  if (st == 0) {
    for (i = 0; i <= 3; i++) { // 全てのタクトスイッチ(桁)について
      // 読み取った値が閾値以上なら current_sw[i] の値を 1 にする。
      if (200 <= tmp_sw[i]) {
        current_sw[i] = 1;
      } else {
        current_sw[i] = 0;
      }
      last_sw[i] = current_sw[i]; // 一つ前のキーの値を今の値で更新

      switch (i) {
        case 0:
          if (last_sw[i] == 0 && current_sw[i] == 1) {
            // カウントダウン開始
            st = 1;
          }
          break;

        case 1:
          if (last_sw[i] == 0 && current_sw[i] == 1) {
            // timecountのインクリメント
            timecount += 1;
            clicked = now;
          }
          if (last_sw[i] == 1 && current_sw[i] == 1) {
            if ( repeat_delay <= now - clicked && interval <= now - last_beat  ) {
              timecount += 1;
              last_beat = now;
            }
          }
          break;

        case 2:
          if (last_sw[i] == 0 && current_sw[i] == 1 && timecount > 0) {
            // timecountのディクリメント
            timecount -= 1;
            clicked = now;
          }
          if (last_sw[i] == 1 && current_sw[i] == 1 && timecount > 0 ) {
            if ( repeat_delay <= now - clicked && interval <= now - last_beat  ) {
              timecount -= 1;
              last_beat = now;
            }
          }
          break;
      }
    }
  }

  if ( st == 1) {
    if (last_sw[0] == 0 && current_sw[0] == 1 && timecount > 0) {
      // 時間設定モードになる
      st = 0;
    }
  }


  /**********************************************************/
  /***** ここで count の値を 4 桁の 7segment LED に表示 *****/
  /**********************************************************/
  tmp = timecount % 3600;

  unsigned int minu = tmp / 60;
  digit[3] = minu / 10;
  minu -= digit[3] * 10;
  digit[2] = minu;

  unsigned int sec = tmp - minu * 60;
  digit[1] = sec / 10;
  sec -= digit[1] * 10;
  digit[0] = sec;

  if (st == 1 && timecount == 0) {
    st = 2;
    if (st == 2) {
      tone(2, melody[0].frequency); // 音を出力
      delay(melody[0].duration);
      noTone(2);
      st = 0;
    }
  }

  for (i = 0; i <= 3; i++) { // ここがダイナミック点灯の部分
    write_a_digit(i, digit[i]); // 一桁出力
    delay(1);
    clear_7seg(); // 一度全セグメントを消灯する。
    // delayMicrosecond(10);
  }
}

試したこと

文法ミスがないか、またロジックに変な箇所がないかの確認をしました。
ボードに数字は正しく点灯されていることの確認もしました。

補足情報（FW/ツールのバージョンなど）

Arudino 1.8.19
Windows10

Answer 1

141行目で、 last_sw[i] と current_sw[i] の値を同じにしているので、 case 0 の中の 条件が成立することはないからではないでしょうか。

      last_sw[i] = current_sw[i]; // 一つ前のキーの値を今の値で更新
      switch (i) {
        case 0:
          if (last_sw[i] == 0 && current_sw[i] == 1) {
            // カウントダウン開始
            st = 1;
          }
          break;

Comments

[yama_u]

そうでした。キーの更新はswitch文の後でした。ありがとうございます。

[yama_u]

すいません、`last_sw[i] = current_sw[i];`をfor文内のswitch文が閉じた後に書いたのですが、結果が変わりませんでした。。

[TakaiY]

指摘したように、状態の変化とその状態になったときにどのような動作をするかについて、ログを仕込むなどして確認してみるのがいいのではないこと思いますよ。
たとえば、ちょっと見ただけで、133行目 if (st == 0) があって判定で st = 1 と したとすると、182行目の if (st == 1) も同レベルなので、ここに入ってしまいますけどいいんですか？、いろいろありそうです。

[yama_u]

はい、if (st==1){}が原因でした。見直してみます。

[yama_u]

if(st==0||st==1)のくくりにs==0とs==1のif文を入れ、countdown()が始まると、boolean型のisCountDownというグローバル変数がtrueになり、s==1の条件にisCountDownを追加して、カウントダウンが始まったあとにA2ボタンを押すと、再度st==0(時間設定モード)に戻るようにしたところ、上手く実装できました。
ありがとうございました。