VBAで配列に入れた値の一括出力について

Question

列A1と列B1の文字を組み合わせて一つの文字列を作り、出力するマクロを作成しております。
処理速度向上のために配列に手を出してみたのですが、うまく出来ずに困っております。

＜前提＞
配列(1)にはAという文字列、配列(2)にはBという文字列・・・というように作成して入れ込むところまでは出来ました。
※順次デバッグに出力することで確認済み

＜問題点＞
配列(1)の文字列だけが指定した出力先すべてに出力される
例）「太郎はやさしい」という文字列がA1～A100の全てに出力されてしまう

＜やりたいこと＞
配列に入れた値を一括で各セルに出力したい
例）A1は「太郎はやさしい」、A2は「花子は明るい」のようなイメージです

---

Sub sample()

    Dim Renkei() As String, i As Integer, outRow As Integer
    Dim endCnt As Long, Skill1Cnt As Long
    outRow = 1
    'endCnt = Sheet4.Range("A1").End(xlDown).Row - 1
    endCnt = 10               'とりあえずテスト用
    ReDim Renkei(endCnt ^ 2)  '配列に入る容量。2つの組み合わせのため2を設定
    
    For Skill1Cnt = 2 To endCnt
        For i = 2 To endCnt
            Renkei(outRow) = Sheet4.Range("C" & Skill1Cnt).Value & Sheet4.Range("D" & i).Value
            'Cells((outRow), 1) = Renkei(outRow)
            Debug.Print "renkei(" & outRow & ")の中身は" & Renkei(outRow) & "です。"
            outRow = outRow + 1
        Next i
    Next Skill1Cnt
    
    Range("A1:A" & outRow).Value = Renkei()
    Debug.Print "renkei()は" & Renkei(outRow) & "個"
    Debug.Print "outRowは" & outRow & "個"
    
    
End Sub

おそらく下から3行目の

   Range("A1:A" & outRow).Value = Renkei()

ここを修正すればいいと思うんですが、どのように修正すべきかがわからない状態です。
ご教授のほど、よろしくお願いいたします。

Answer 1

Range("A1:A" & outRow).Value = Renkei()

を下記に変更すればいいでしょう。

Range("E1:E" & outRow).Value = WorksheetFunction.Transpose(Renkei)

ReDim Renkei(endCnt ^ 2) でできる配列は1次元配列です。
下記のようなイメージの配列です。

1	2	3	・・・・
C2&D2	C2&D3	C2&D4	・・・・

シート上では行方向の並びになります。
代入するなら、Range("A1:Z1").Value = Renkei というように行方向の範囲に代入する必要があります。

列方向の並びは、下記のような二次配列になります。

Index	1
1	C2&D2
2	C2&D3
3	C2&D4
・	・・・・

WorksheetFunction.Transpose は縦横変換の関数です。1次元配列を上記のような2次元配列に変換してくれます。

Comments

[choco_mint]

おかげさまで要望通りの動きになりました！
ありがとうございます！！