[VBA初心者] 複数のエクセルブックから、一つの新規シートにまとめる際に、値のみの貼付けができない

Question

前提

VBAで、あるフォルダに格納されている複数のブックの特定のシート（同一名・同一構造）からデータを抜き出し、
別のブックのシートに順次貼り付けて、それらを用いて集計を行いたいと考えております。

書式や文字列はうまく貼り付けられているようなのですが、
コピー元のシートで数式を含んでいるセルは、数式だけが貼り付けられて参照エラーとなり、値が貼り付けられていません。

実現したいこと

• 　コピー元のシート数式ではなく、値のみを貼り付けたい

試したこと

Sub 複数のシートを一つのブックにまとめる()
  Dim A
  'フォルダ内のブック名を取得
  A = Dir(ThisWorkbook.Path & "\対象シートフォルダ\*")
  Do While A <> ""
    'ブックを開く
    Workbooks.Open ThisWorkbook.Path & "\対象シートフォルダ\" & A
    With ActiveWorkbook
      'シートをコピーして取得
      .Worksheets("対象シート").Copy After:=ThisWorkbook.Worksheets(ThisWorkbook.Worksheets.Count)
      'シート名をブック名に変更
      ThisWorkbook.Worksheets(ThisWorkbook.Worksheets.Count).Name = .Name
      'On Error Resume Next
      
      .Close False 'ブックを閉じる
    End With
    A = Dir() '次のブック名を取得
  Loop
End Sub

値のみを貼り付けるためには、PasteSpecial Paste:=xlPasteValuesなどを用いれば良さそうということは調べました。
以下のブロックを含め、いくつかパターンを試しました。しかし、私の知識・経験不足で、どのように組み込めばよいかが分かりませんでした。

 .Worksheets("対象シート").Copy After:=ThisWorkbook.Worksheets(ThisWorkbook.Worksheets.Count).PasteSpecial Paste xlPasteValues

補足情報（バージョンなど）

Windows11, Excel2021

Comments

[otn]

マクロの記録で、やりたい操作を記録して、どう書けばいいか調べましょう。

Answer 1

.Worksheets("対象シート").Copyというのはシートのコピーです。シートのコピーでは値のみ貼り付けはできません。

新規シートを追加(Worksheets.Add)する。
貼り付け元シートのデータをコピーする。
上記の新規シートに値貼り付けをする。
という手順が必要です。

Sub 複数のシートを一つのブックにまとめる()
    Dim A As String
    'フォルダ内のブック名を取得
    A = Dir(ThisWorkbook.Path & "\対象シートフォルダ\*")
    Do While A <> ""
        'ブックを開く
        With Workbooks.Open(ThisWorkbook.Path & "\対象シートフォルダ\" & A)
            '新規シートを追加
            Dim NewWS As Worksheet
            With ThisWorkbook
                Set NewWS = .Worksheets.Add(after:=.Worksheets(.Worksheets.Count))
            End With
            
            '対象シートの値をコピーして新規シートに値貼り付け
            .Worksheets("対象シート").UsedRange.Copy
            NewWS.Cells(1).PasteSpecial Paste:=xlPasteValues
            
            'シート名をブック名に変更
            NewWS.Name = .Name
      
            .Close False                         'ブックを閉じる
        End With
        A = Dir()                                '次のブック名を取得
    Loop
End Sub

Comments

[ekuseru_kun]

ありがとうございます！！解決致しました！
`NewWS.Cells(1).PasteSpecial Paste:=xlPasteFormats`も加えてみて、書式も反映できるようにしてみました。