データ型の異なる入力必須項目が入力されていない場合に警告文を出したい

実現したいこと

備考を除く全ての入力必須テキストボックスが未入力の状態で登録ボタンをクリックした際、「備考以外は入力必須項目です。」と警告文を表示したい。

前提

店舗情報をマスターテーブルに追加するフォームを作成しています。

店舗マスターテーブルのフィールドは、数値型の店舗番号、短いテキスト型の店舗名・〒(郵便番号)・住所・電話番号・FAX番号・備考です。フォーム上のテキストボックスの名前はフィールド名と同様です。既定値はいずれのフィールドも設定していません。

発生している問題・エラーメッセージ

登録ボタンをクリックすると、実行時エラー"13",型が一致しませんと表示が出ます。

該当のソースコード

Option Compare Database
Option Explicit

Private Sub 登録する_Click()
If IsNull(店舗番号 + 店舗名 + 〒 + 住所 + 電話 + ＦＡＸ + 備考) Then
MsgBox "備考以外は入力必須項目です。", vbOKOnly + vbExclamation, "入力不備"
Exit Sub
Else
DoCmd.GoToRecord , , acNewRec
End If
End Sub

試したこと

上記コードから店舗番号を削除し、備考以外のいずれかのテキストボックスを未入力の状態で登録ボタンをクリックすると正常にmsgboxが表示されました。
店舗番号だけ別に記述することも考えましたが、店舗番号が入力されていません。備考以外は必須項目です。と複数回警告が表示されるのも鬱陶しいかなと思います。

sk.exe

2023/04/19 07:37

> 備考を除く全ての入力必須テキストボックスが未入力の状態で登録ボタンをクリックした際、 > 「備考以外は入力必須項目です。」と警告文を表示したい。エラーメッセージを返す際に、具体的にどの必須項目に値が入力されていないのかがユーザーに示されないような設計は適切ではないと思います。 > 店舗番号だけ別に記述することも考えましたが、店舗番号が入力されていません。 > 備考以外は必須項目です。と複数回警告が表示されるのも鬱陶しいかなと思います。それぞれのコントロールの値を個別に判定して、適切な値が入力されていないコントロールが検知された時点でその旨をエラーメッセージとして表示し、 Exit Sub ステートメントでプロシージャの実行を止めればよいでしょう。

退会済みユーザー

2023/04/19 08:12 編集

回答ありがとうございます。ぱっと見で抜けているところがわかるくらいの簡素なフォームですので備考以外は必須項目です。とだけ表示するようにしようと思っていましたが、抜け箇所がわかった方がも親切なのは間違いないですね。 Private Sub 登録する_Click() If Nz(店舗番号, "") = "" Then MsgBox "店舗番号が入力されていません。", vbOKOnly + vbExclamation, "入力不備" 店舗番号.SetFocus Exit Sub ElseIf Nz(店舗名, "") = "" Then MsgBox "店舗名が入力されていません。", vbOKOnly + vbExclamation, "入力不備" 店舗名.SetFocus Exit Sub ElseIf Nz(〒, "") = "" Then MsgBox "郵便番号が入力されていません。", vbOKOnly + vbExclamation, "入力不備" 〒.SetFocus Exit Sub ElseIf Nz(住所, "") = "" Then MsgBox "住所が入力されていません。", vbOKOnly + vbExclamation, "入力不備" 住所.SetFocus Exit Sub ElseIf Nz(電話, "") = "" Then MsgBox "電話番号が入力されていません。", vbOKOnly + vbExclamation, "入力不備" 電話.SetFocus Exit Sub ElseIf Nz(ＦＡＸ, "") = "" Then MsgBox "FAX番号が入力されていません。", vbOKOnly + vbExclamation, "入力不備" ＦＡＸ.SetFocus Exit Sub Else DoCmd.GoToRecord , , acNewRec End If End Sub 以上のように修正してみましたがいかがでしょうか。

sazi

2023/04/19 08:35

元々はNullを結合してのエラーでしょうから、そのコードで試せばエラーにはならないのでは

sk.exe

2023/04/19 09:13 編集

1つの If ... End If ステートメントのみで全ての入力必須項目のバリデーション処理を完結させているなら、それぞれの分岐の中の Exit Sub ステートメントはなくてもよいです。 https://teratail.com/questions/1p4dj1jo5571tc で示したように、複数の If ... End If ステートメントに分けて個々の必須項目のバリデーションを行なったり、End If ステートメント以降に何らかのコードが記述されたりしている場合は、適切な箇所で Exit Sub ステートメントを呼び出すようにして下さい。

hatena19

2023/04/19 16:43

入力必須項目のある入力フォームのUIのサンプルを下記で紹介しています。ご参考に。 https://hatenachips.blog.fc2.com/blog-entry-446.html

退会済みユーザー

2023/04/20 00:00

皆様、コメント頂きありがとうございました。後学のために、実現したいことの条件だとどのように記述すればよいかご教示願います。当初の記述の問題点が知りたいです。

行動規範の内容に同意します

回答1件

ベストアンサー

後学のために、実現したいことの条件だとどのように記述すればよいかご教示願います。

例えばループ処理を使う場合。

vba
1Private Sub 登録する_Click()
2
3    'バリデーション処理の結果が False である場合
4    If IsValidRequiredControls = False Then
5        'プロシージャを抜ける
6        Exit Sub
7    End If
8
9    '新規レコードに移動する
10    DoCmd.GoToRecord , , acNewRec
11
12End Sub
13
14'入力必須項目のバリデーション用関数
15Private Function IsValidRequiredControls() As Boolean
16On Error GoTo Err_IsValidRequiredControls
17
18    '既定の戻り値を False とする
19    IsValidRequiredControls = False
20
21    '入力必須項目とするコントロールの名前のリスト（カンマ区切り）を定数として定義
22    Const RequiredControlNames As String = "店舗番号,店舗名,〒,住所,電話,ＦＡＸ"
23    
24    '入力必須項目がない場合
25    If RequiredControlNames = "" Then
26        '戻り値を True に
27        IsValidRequiredControls = True
28        'プロシージャを抜ける
29        Exit Function
30    End If
31    
32    Dim varArray As Variant
33    Dim varItem As Variant
34    Dim ctlTarget As Access.Control
35
36    '入力必須コントロール名のリストを1次元配列に変換
37    varArray = Split(RequiredControlNames, ",", , vbBinaryCompare)
38
39    '配列の各要素を順次参照する
40    For Each varItem In varArray
41        '現在の要素の値と同じ名前のコントロールを参照
42        Set ctlTarget = Me.Controls(varItem)
43        'そのコントロールの値が Null または空文字列である場合
44        If Nz(ctlTarget.Value, "") = "" Then
45            Debug.Print "コントロール[" & varItem & "]の値が Null または空文字列"
46            'エラーメッセージを返す
47            MsgBox "備考以外は入力必須項目です。", vbExclamation, "入力不備"
48            '戻り値を False としたままプロシージャを抜ける
49            Exit Function
50        End If
51        Set ctlTarget = Nothing
52    Next
53    
54    '全てのチェックをクリアした場合は True を返す
55    IsValidRequiredControls = True
56
57'終了処理
58Exit_IsValidRequiredControls:
59
60    'プロシージャを抜ける
61    Exit Function
62
63'エラー時処理
64Err_IsValidRequiredControls:
65
66    'エラー発生時の戻り値も False とする
67    IsValidRequiredControls = False
68
69    Dim strErrCaption As String
70    Dim strErrMsg As String
71    
72    strErrCaption = "実行時エラー（" & Me.Name & ".IsValidRequiredControls）"
73    
74    strErrMsg = Err.Number & ": " & Err.Description
75    
76    Debug.Print strErrMsg
77
78    strErrMsg = "必須項目の入力チェック中に下記のエラーが発生しました。" & vbCrLf & _
79                strErrMsg
80    
81    'エラーメッセージの表示
82    MsgBox strErrMsg, vbCritical, strErrCaption
83    
84End Function