入力必須項目が未入力でフォームから移動した際、レコードがテーブルに保存されないようにしたい

Question

実現したいこと

売上情報を入力するフォームにメニューに戻るボタンがあり、入力必須項目が未入力の状態でメニューに戻るボタンを押したら入力内容を破棄してもよいかの確認メッセージを表示し、OKを押すとレコードをデータ保存用のテーブルに書き込まずにメニューに戻るようにしたいです。
要は、必須項目が全て入力されている場合のみレコードが保存されるようにしたいのです。

前提

売上情報を入力するフォームを作成しています。
日付・店舗番号・利用者番号を入力するメインフォームと、製品番号・数量を入力するサブフォームがあります。

発生している問題・エラーメッセージ

例えば日付が抜けたままサブフォームに移動した時や、入力を中断してフォームを閉じた時に入力途中の内容がテーブルに書き込まれてしまいます。

試したこと

①本テーブルと同じフィールドを持ったデータ仮置きテーブル・仮置きテーブルを本テーブルに書き込む追加クエリ・仮置きテーブルのレコードを削除するクエリを作成
②仮置きテーブルを入力フォームのレコードソースにして、入力確定時は追加クエリと削除クエリを、入力内容を破棄する時は削除クエリを実行する

この方法で実現も出来ると思うのですが、1つのフォームに対して本テーブル・仮置きテーブル・追加・削除クエリとオブジェクトが多くなって複雑になってしまう気がします。

補足情報（FW/ツールのバージョンなど）

ここにより詳細な情報を記載してください。

Answer 1

日付・店舗番号・利用者番号を入力するメインフォームと、製品番号・数量を入力するサブフォームがあります。

売上情報を入力するフォームにメニューに戻るボタンがあり、入力必須項目が未入力の状態でメニューに戻るボタンを押したら入力内容を破棄してもよいかの確認メッセージを表示し、OKを押すとレコードをデータ保存用のテーブルに書き込まずにメニューに戻るようにしたい

メインフォーム側で上記の処理を行ないたいのであれば、例えばメインフォームのフォームモジュールに次のようなコードを記述なさればよろしいのではないかと。

Option Compare Database
Option Explicit

'フォームの[レコード移動時]イベント
Private Sub Form_Current()
        
    '[売上日付]にフォーカスを移す
    Me![売上日付].SetFocus
    
    'カレントレコードが新規レコードである場合
    If Me.NewRecord = True Then
        'サブフォームコントロールの[編集ロック]プロパティを「はい」に
        Me![売上明細サブフォーム].Locked = True
    Else
        'サブフォームコントロールの[編集ロック]プロパティを「いいえ」に
        Me![売上明細サブフォーム].Locked = False
    End If

End Sub

'フォームの[更新前処理]イベント
Private Sub Form_BeforeUpdate(Cancel As Integer)

    With Me
        
        '[売上日付]の値が日時データとして扱えない値である場合
        If IsDate(![売上日付].Value) = False Then
            'このイベントをキャンセルする
            Cancel = True
            '警告メッセージの表示
            MsgBox "売上日付を入力して下さい！", vbExclamation, "入力エラー"
            '[売上日付]にフォーカスを移す
            ![売上日付].SetFocus
            'プロシージャを抜ける
            Exit Sub
        End If
        
        '[店舗番号]の値が Null または空文字列である場合
        If Nz(![店舗番号].Value, "") = "" Then
            'このイベントをキャンセルする
            Cancel = True
            '警告メッセージの表示
            MsgBox "店舗番号を入力して下さい！", vbExclamation, "入力エラー"
            '[店舗番号]にフォーカスを移す
            ![店舗番号].SetFocus
            'プロシージャを抜ける
            Exit Sub
        End If
        
        '[利用者番号]の値が Null または空文字列である場合
        If Nz(![利用者番号].Value, "") = "" Then
            'このイベントをキャンセルする
            Cancel = True
            '警告メッセージの表示
            MsgBox "利用者番号を入力して下さい！", vbExclamation, "入力エラー"
            '[利用者番号]にフォーカスを移す
            ![利用者番号].SetFocus
            'プロシージャを抜ける
            Exit Sub
        End If
    
    End With

End Sub

'フォームの[更新後処理]イベント
Private Sub Form_AfterUpdate()

    'サブフォームコントロールの[編集ロック]プロパティを「いいえ」に
    Me![売上明細サブフォーム].Locked = False
    
End Sub

'コマンドボタン[メニューに戻るコマンド]の[クリック時]イベント
Private Sub メニューに戻るコマンド_Click()

    'カレントレコードが編集中ではない場合
    If Me.Dirty = False Then
        'このフォームを閉じる
        DoCmd.Close acForm, Me.Name, acSaveNo
        'プロシージャを抜ける
        Exit Sub
    End If

    Dim lngAnswer As Long
    
    '確認ダイアログを表示し、[OK]ボタンと[キャンセル]ボタンのどちらがクリックされたかを取得
    lngAnswer = MsgBox("カレントレコードの編集内容を破棄してフォームを閉じますか？", _
                       vbQuestion + vbOKCancel + vbDefaultButton2, _
                       "カレントレコードの編集中です")
    
    '[キャンセル]ボタンがクリックされた場合
    If lngAnswer = vbCancel Then
        Exit Sub
    End If
    
    'カレントレコードに対する変更を取り消す
    Me.Undo
    'このフォームを閉じる
    DoCmd.Close acForm, Me.Name, acSaveNo

End Sub

各コントロールの名前は適当に書き換えて下さい。

Answer 2

　連結フォームのヘッダーに複数の非連結テキストボックスとOKボタンを追加して、諸々入力後、OKボタンを押して、追加クエリを呼び出すのはどうでしょう？詳細エリアの連結テキストボックスを直接編集しない、それは見る専用とするのです。