excel_vbaでの正規表現について

実現したいこと

EXCEL_VBAでinputboxを使いセルの範囲選択をさせようとしています。
その際、特定のセル範囲が選択されているかどうかの判定を行いたいと考えてます。

前提

条件は下記です。
①列Cの範囲が選択されている。
②10行目以下が選択されている。
OKパターン「$C$26」「$C$24:$C$28」「$C$22:$C$25,$C$30」
NGパターン「$C:$C」「$C$25:$D$31」「$C$8:$C$22」

発生している問題・エラーメッセージ

正規表現で判定をしたいのですが、うまくいきません。

該当のソースコード

下記は、条件①のみを適用した場合です。(正常動作していませんが)
これに加えて、判定条件②を満たしたコードを完成させたいです。

'####セル範囲選択コードは省略"
Dim re As Object
Set re = CreateObject("VBScript.RegExp")
With re
.Global = True
.Pattern = "^$C$[0-9]{1,7}$|^$C$([C]|[0-9]|[$]|[:,])[0-9]{1,7}$"
アドバイスを頂けると幸いです。

行動規範の内容に同意します

回答1件

ベストアンサー

条件は下記です。
①列Cの範囲が選択されている。
②10行目以下が選択されている。

ということなら、正規表現を使わなくても、下記のコードで可能です。

vba
1Public Sub test()
2    On Error GoTo ErrHandl
3    Dim rng As Range
4    Set rng = Application.InputBox( _
5              Prompt:="セルを選択してください。", _
6              Type:=8)
7              
8    Dim a As Range, flg As Boolean
9    flg = True
10    For Each a In rng.Areas
11        '各範囲が1列かつ先頭セルがC 列で10行目以上でなければNG
12        If Not (a.Columns.Count = 1 And a.Column = 3 And a.Row >= 10) Then
13            flg = False
14            Exit For
15        End If
16    Next
17    If flg Then MsgBox "OK" Else MsgBox "NG"
18    
19    Exit Sub
20ErrHandl:
21    Err.Clear
22End Sub

解決済みですが、もっとシンプルな方法を思いついたので、追記しておきます。
Intersectメソッドで、選択した範囲とC10以降の範囲の共通部分を取り出して、
それと選択した部分のアドレスが一致すれば、C10以降の範囲のセルはないということになります。

vba
1Public Sub test2()
2    On Error GoTo ErrHandl
3    Dim rng As Range
4    Set rng = Application.InputBox( _
5              Prompt:="セルを選択してください。", _
6              Type:=8)
7              
8    Dim r As Range
9    Set r = Intersect(rng, Range("C10:C" & Rows.Count))
10    If r.Address = rng.Address Then MsgBox "OK" Else MsgBox "NG"
11        
12    Exit Sub
13ErrHandl:
14    Err.Clear
15End Sub