添付ファイル型（画像データ）のデータをテーブル間で移動させたい

添付ファイル型 フィールドのデータ型は、「RecordSet2型」というもので、ようするにレコードセットで複数のデータを持てるようになっています。

下記で紹介されている CopyAttachmentField関数を使えば簡単にコピーできます。

Access 添付ファイル型のフィールド値のコピー方法(VBA) | SOHOプログラマのぼやき @Links[アットリンクス]

上記のリンク先から、CopyAttachmentField関数を標準モジュールにコピーして、private FunctionをPublic Functionに変更。

フォームの削除ボタンのクリック時を下記のように変更。

Private Sub cmdDel_Click()
    Dim rst As DAO.Recordset
    Set rst = CurrentDb.OpenRecordset("ゴミ箱", dbOpenTable)
    With rst
        .AddNew
        .Fields("削除日付") = Now()

        '中略

        '.Fields("FileData").Value = !FileData.LoadFromFile(Me.フィールド1_FileData)
        CopyAttachmentField Me.Recordset!FileData.Value, rst!FileData.Value
        .Update
    End With

    rst.Close
    Set rst = Nothing
    DoCmd.SetWarnings False
    Me.AllowDeletions = True
    DoCmd.RunCommand acCmdDeleteRecord
    Me.AllowDeletions = False

    '      Me.Undo
    '      Me.Requery
    DoCmd.SetWarnings True

End Sub

フォーム上の添付型フィールドを参照するときは、Me!FileData.Value ではなく Me.Recordset!FileData.Value とする必要があるようです。

CopyAttachmentField関数（リンク先よりコピーして一部変更）

'--------------------------------------------------
'概要 ： 添付ファイル型データをコピー
'--------------------------------------------------
'引数 ： rsFromTbl , I , DAo.Recordset , 待避元の添付ファイル型レコードセット
'     ： rsToTbl   , I , DAo.Recordset , 待避先の添付ファイル型レコードセット
'--------------------------------------------------
'戻り値： 成功 = True 失敗 = False
'--------------------------------------------------
Public Function CopyAttachmentField(ByVal rsFromTbl As DAO.Recordset2, ByVal rsToTbl As DAO.Recordset2) As Boolean
    Dim intField As Integer

    CopyAttachmentField = False '初期値は失敗

    On Error GoTo ERRTRAP

    'レコード終了まで処理
    Do Until rsFromTbl.EOF = True
        rsToTbl.AddNew '待避先に新規追加
        'フィールド分のデータをセットする
        For intField = 0 To rsFromTbl.Fields.Count - 1
            '待避先のフィールドが更新可能な場合
            If rsToTbl.Fields(intField).DataUpdatable = True Then
                '待避元のデータがNullではない場合
                If IsNull(rsFromTbl.Fields(intField).Value) = False Then
                    '待避先に待避元のデータをセットする
                    rsToTbl.Fields(intField).Value = rsFromTbl.Fields(intField).Value
                End If
            End If
        Next
        rsToTbl.Update '待避先を更新
        rsFromTbl.MoveNext
    Loop

    rsFromTbl.Close
    rsToTbl.Close

    Set rsFromTbl = Nothing
    Set rsToTbl = Nothing

    CopyAttachmentField = True 'ここまできたら成功

Exit Function
ERRTRAP:
    MsgBox "添付ファイル型データの追加中にエラーが発生しました" & vbCrLf _
        & "エラー番号:" & Err.Number & vbCrLf _
        & "エラー内容:" & Err.Description & vbCrLf, vbCritical, "予期せぬエラー"
End Function

蛇足

削除したレコードをいったんゴミ箱に保存しておいて、また復活できるようにしようということですよね。
実際にテーブルから削除せずに、テーブルに「削除日時」「削除ユーザ」フィールドを持たせて、そのフィールドがNullなら有効なレコード、入力されていたら削除レコードとして扱う、という方法もあります。

テーブルから実際に削除してしまうと、リレーションシップで参照整合性が設定できないなど、いろいろ具合が悪い場合があります。削除フィールドがNull以外のレコードのみ抽出するクエリを、現状のテーブルと置き換えるだけですので、シンプルにゴミ箱が実現できます。

削除したレコードを復活できる「ごみ箱」の設計 - hatena chips