テキストファイルから特定の文字列に挟まれた行をEXCELマクロを使ってコピーし貼り付けたい

Question

###前提・実現したいこと
.txtテキストファイルに保存してある文字行の中から、特定の文字行に挟まれた行を選択し、Excel2010でマクロを使って、Excelに貼り付けたいです。例えば、

＜テキストファイル例＞ ※例なので実際のテキスト内容は下記に限らず。
東京
大阪
名古屋
広島
福岡
鹿児島

＜上記の内、コピーしたい行＞ ※大阪から福岡までの行を選択したいです。
大阪
名古屋
広島
福岡

###該当のソースコード
Sub PasteFromCSV()
Const CSV_FILE = "c:\temp\command.txt"
Dim ReadWBk As Workbook
Dim WriteWBk As Workbook
Dim WriteSht As Worksheet
Dim Rng As Range

Set WriteWBk = ActiveWorkbook
Set WriteSht = WriteWBk.ActiveSheet

Set ReadWBk = Workbooks.Open(CSV_FILE)
Set Rng = ReadWBk.Worksheets.Item(1).UsedRange
Range("A1:A170").Copy

WriteSht.Range("A1").PasteSpecial xlPasteValues, xlPasteSpecialOperationNone, False, False

ReadWBk.Close
Set ReadWBk = Nothing
End Sub

###試したこと
IFやFINDを試そうとしたのですが、どの構文がよいのか分からず、本問合せに至った次第です。

###補足情報(言語/FW/ツール等のバージョンなど)
EXCEL2010で試しています。

Answer 1

すでにほかの方からのアドバイスにもある通り、実現方法はいくつかあります。

自分からはFind関数を使った方法をご紹介します。

Sub PasteFromCSV()
    Const CSV_FILE = "c:\temp\command.txt"
    Dim ReadWBk As Workbook
    Dim WriteWBk As Workbook
    Dim WriteSht As Worksheet
    Dim Rng As Range
    
    Set WriteWBk = ActiveWorkbook
    Set WriteSht = WriteWBk.ActiveSheet
    
    Set ReadWBk = Workbooks.Open(CSV_FILE)
    'Set Rng = ReadWBk.Worksheets.Item(1).UsedRange
    'Range("A1:A170").Copy
    
    Dim ReadSht As Worksheet
    Dim rngStart As Range   '開始セル
    Dim rngEnd As Range     '終了セル
    
    Set ReadSht = ReadWBk.Worksheets.Item(1)

    Set rngStart = ReadSht.Range("A:A").Find("大阪")
    Set rngEnd = ReadSht.Range("A:A").Find("福岡")
    
    If rngStart Is Nothing Then
        '開始セルが見つからなければA1にセット
        Set rngStart = ReadSht.Cells(1, "A")
    End If
    
    If rngEnd Is Nothing Then
        '終了セルが見つからなければA列最終行にセット
        Set rngEnd = ReadSht.Cells(ReadSht.Cells(Rows.Count, "A").End(xlUp).Row, "A")
    End If
    
    '開始セルから終了セルまでをコピー
    Range(rngStart, rngEnd).Copy
    
    WriteSht.Range("A1").PasteSpecial xlPasteValues, xlPasteSpecialOperationNone, False, False
    
    ReadWBk.Close
    
    Set ReadWBk = Nothing
End Sub

テキストファイルをシートに取り込んだ後、Find関数で大阪のセルと福岡のセルをFind関数で検索し、大阪セル～福岡セルの範囲を範囲コピーしています。

参考になれば幸いです。

Comments

[Tokamura]

ありがとうございます。やりたかったことが実現できました。大変参考になりました。

Answer 2

FileSystemObject で一気に読み込み、Mid関数で目的の範囲を取り出して、レンジに代入

Sub ReadCSV()
    Const CSV_FILE = "c:\temp\command.txt"
    Const BeginWord = "大阪"
    Const EndWord = "福岡"
    Dim strCSV As String, aryCsv As Variant
    Dim p1 As Long, p2 As Long

    With CreateObject("Scripting.FileSystemObject")
        With .GetFile(CSV_FILE).OpenAsTextStream
            strCSV = .ReadAll
            .Close
        End With
    End With
    p1 = InStr(1, strCSV, BeginWord)
    If p1 > 0 Then p2 = InStr(p1, strCSV, EndWord)
    If p2 > 0 Then
        strCSV = Mid(strCSV, p1, p2 - p1 + Len(EndWord))
        aryCsv = Split(strCSV, vbCrLf)
        Range("A1").Resize(UBound(aryCsv) + 1, 1) = WorksheetFunction.Transpose(aryCsv)
    Else
        MsgBox "該当データなし"
    End If
End Sub

Comments

[Tokamura]

やりたいことが実現できました。ありがとうございました。大変助かります。

Answer 3

とりあえずループで回してみました。
処理速度とか体裁にこだわらないなら問題ないと思います。
テキストファイルを読み込み終わった以降に、下記コードを実行してみてください。

    Dim startStr As String
    Dim endStr As String
    Dim copyFlag As Boolean
    Dim writeRow As Long
    
    startStr = "大阪"
    endStr = "福岡"
    copyFlag = False
    writeRow = 1
    
    For Each c In ReadWBk.Worksheets(1).Range("A1:A" & Range("A1").End(xlDown).Row)
        If c = startStr Then copyFlag = True
        If copyFlag Then
            WriteSht.Cells(writeRow, 1) = c
            writeRow = writeRow + 1
            If c = endStr Then Exit For
        End If
    Next

Comments

[Tokamura]

早々のアドバイスありがとうございます。大変参考になりました。