Arduinoを使ってSDカード内のファイルをコピーしたい

Question

前提

Arduinoを使ってSDカード内にあるファイルを別のSDカードにコピーしたいと思っています。Arduino は ATmega328P を使っています。
Arduino とSDカードモジュールはSPIで通信します。SPIのSSを切り替えて２つのSDカードを使い分けたいです。
ＳＤカードモジュール２台は並列接続してあり、SD１とSD2、それぞれのカード内にあるファイルが読めてLCDに表示できることを確認しました。

実現したいこと

・SDカード１にあるファイルを１バイトずつRAMに読み込む。
・RAMに読み込んだデータをSDカード２へ書き込む。

発生している問題・エラーメッセージ

SDカード１にカードが入っているかチェックした時点で、ATmega328が再起動してしまいます。

該当のソースコード

#include <SPI.h>
#include <SD.h>
#include <LiquidCrystal_I2C.h>  // 液晶表示用
LiquidCrystal_I2C lcd(0x27, 20, 4);// set the LCD address to 0x27 for a 16

const char nameTitle[] = "SDcard FileCopy";
const char nameVer[]   = "20221121 working";
const byte SD1pin = 8;
const byte SD2pin = 9;
File anyFile;
File entry;
File root;
String fileName = "text.txt";
unsigned long readPosition;
unsigned long byteCount;
byte byteBuffer[512]; // 1024 だとRAM が足りなかったので512 にした

void setup() {
  // --------- LCD にツール名称とバージョンを表示 --------- //
  lcd.init();                      // initialize the lcd 
  lcd.backlight();
  lcd.setCursor(0,0);
  lcd.print(nameTitle); // タイトルを表示する
  lcd.setCursor(0,1);
  lcd.print(nameVer); // バージョンを表示する  
  delay(3000);
  lcd.clear();

  pinMode(SD1pin, OUTPUT);
  pinMode(SD2pin, OUTPUT);
  digitalWrite(SD1pin, HIGH);
  digitalWrite(SD2pin, HIGH);
  pinMode(10, OUTPUT);        // 10pin 以外を用いる場合は、10pin は
  digitalWrite(10, HIGH);     // output に設定するけど使用しない。

  lcd.setCursor(0,0);
  lcd.print("Starting");
  delay(1000);
  lcd.clear();
  lcd.setCursor(0,0);
  
  // ----------------- SD1 の内容を確認 ----------------- //
  if(!SD.begin(SD1pin)){           // SD1 ライブラリの初期化
    lcd.print("Check:SD1 Failed"); // SD1pin が LOW になる
    delay(2000);             // カードが未挿入ならエラー表示
    while(1);
  }
  lcd.print("Check:SD1 OK");
  delay(1000);
  root = SD.open("/");
  lcd.setCursor(0,1);
  lcd.print("root = SD OK");
  lcd.setCursor(0,1);
  lcd.print("Files on SD1 are:");
  delay(1000);
  lcd.setCursor(0,2);
  //printDirectory(root);
  root.close();
  delay(2000);
  digitalWrite(SD1pin, HIGH);
  lcd.clear();
  
  // ----------------- SD2 の内容を確認 ----------------- //
  if(!SD.begin(SD2pin)){     // SD1 ライブラリの初期化
    lcd.print("Check:SD2 Failed"); // SD1pin が LOW になる
    delay(2000);             // カードが未挿入ならエラー表示
    while(1);
  }
  lcd.print("Check:SD2 OK");
  delay(1000);
  root = SD.open("/");
  lcd.setCursor(0,1);
  lcd.print("Files on SD2 are:");
  lcd.setCursor(0,2);
  //printDirectory(root);
  root.close();
  delay(2000);
  digitalWrite(SD2pin, HIGH);
  lcd.clear();
  
  readPosition = 0;

//
// ここにSD2をフォーマットする処理を入れる
//

} // setup()

void loop() {

  // ---------------- 読み込むSDカードを開く ------------------- //
  lcd.setCursor(0,0);  
  if(!SD.begin(SD1pin)){                  // SD1 を開く
    lcd.print("toRead:SD1 Failed");              // 開けなかったらエラー表示
    delay(2000);
    while(1);  
  }
  // ---------------- 読み込むファイルを開く ------------------- //
  anyFile = SD.open(fileName, FILE_READ); // コピー元のファイルを開く
  while(!anyFile){                        // 開けなかったらエラー表示
    lcd.print("Opening of SFile Failed");
    delay(2000);
    while(1);
  }
  
  // ---------------------- ファイル読み込み ------------------------- //
  if(readPosition == anyFile.size()){     // ファイルすべてを読み込んだら
    lcd.print("Copied bytes: ");          // サイズを表示して停止する
    lcd.print("anyFile.size()");
    while(1);
  }
  anyFile.seek(readPosition);             // 読み込み位置まで移動して
  byteCount = 0;                          // バッファに１バイトずつ読み込む
  while(anyFile.available() && byteCount < 1024){
    byteBuffer[byteCount] = anyFile.read();
    byteCount++;
    readPosition++;
  }
  anyFile.close();
  digitalWrite(SD1pin, HIGH);
  lcd.clear();
  
  // ----------------- 書き込むSDカードを開く -------------------- //
  lcd.setCursor(0,0);  
  if(!SD.begin(SD2pin)){                  // SD2 を開く
    lcd.print("toWrite:SD2 Failed");              // 開けなかったらエラー表示
    delay(2000);
    while(1);  
  }
  // ---------------------- ファイル書き込み ------------------------- //
  anyFile = SD.open(fileName, FILE_WRITE); // 書き込みモードで開く
                                           // ファイル最後の位置で開かれる
  anyFile.write(byteBuffer, byteCount);
  anyFile.close();
  digitalWrite(SD2pin, HIGH);

} // loop()



void printDirectory(File dir){
  while(true){
    File entry = dir.openNextFile();
    if(!entry){
      break;
    }
    lcd.print(entry.name());
    lcd.print(":");
    lcd.print(entry.size(), DEC);
    entry.close();
  } // while(true)
} // printDirectory(File dir)

試したこと

ネット上のこの事例を参考に作成しました。
https://create.arduino.cc/projecthub/nmvrouwe/access-2-sd-cards-with-arduino-506415
自分なりにスケッチを書き換えて試行錯誤を繰り返しましたが、数時間かけても正常に動かすことができません。

補足情報（FW/ツールのバージョンなど）

ArduinoIDE 2.0.1
ATmega328P クロック 16MHz
SDカードモジュールとATmega328の電圧レベル変換は次の記事にありますようにダイオードを使用しました。
http://radiopench.blog96.fc2.com/blog-entry-765.html

Comments

[ozwk]

> ＳＤカードモジュール２台は並列接続してあり、SD１とSD2、それぞれのカード内にあるファイルが読めてLCDに表示できることを確認した

と

> SDカード１にカードが入っているかチェックした時点で、ATmega328が再起動してしまいます。

がなんだか矛盾しているような気がするんですが、どういう状況でしょうか

チェックができなければ、SD１とSD2、それぞれのカード内にあるファイルが読めてLCDに表示できることを確認できないように思えます。

[MTN]

コメントありがとうございます。
LCDに表示できるようになったスケッチは、ここに載せたものとは別のスケッチです。
LCDに表示することができたので、それを利用して今回のスケッチを書いたのですが、なぜか再起動を繰り返してしまいます。

Answer 1

おそらく、メモリ不足によりスタックが枯渇、そんでプログラムが暴走して、結果的に再起動したように見える、だけかと。
一度、byteBufferを小さい値にしてやってみればどうなるか確認してみればいいかと。

んで、一つアドバイスですが、ATMega328では、変数をconstにしたところで、変わらずそれはRAMに割り当てられます。
ピン番号をわざわざ変数を介するってのは、RAMの無駄遣いにしかなりません。

Comments

[MTN]

ご回答ありがとうございます。
はい、小さい値にしてやってみます。
ピン番号も変数を使わず直打ち（？）でやってみます。

[y_waiwai]

定数はdefineで定義しましょう。
そして、文字列などはPROGMEMやFマクロなどを駆使すればROMエリアに追い出せます

[MTN]

byteBuffer を 2 byte にしたら再起動の症状が消えました。
ありがとうございます。さすがに 2 byte だと少ないので、数を変えて影響のない範囲で大きな値を探してみます。
define で定義するようにします。define よりも const を使うほうが良いという記事をネット上で読んだことがあり、それを鵜吞みにして const を使っておりました。SRAMを使わない方向で考えていきたいと思います。
PROGMEM 等はこれから調べてみます。

[y_waiwai]

まあ、このCPUはRAMが２Kしかないので、SDカードを云々するにはちと無理があると思いますよ
参考先でも、メモリ容量の大きなCPUつかってますよね

[MTN]

はい、参考先、そうなってますよね。
まずは手元にあるATMega328 で無理を実感してから、メモリ容量の大きなものに移ろうかと思います。
ありがとうございます。

[thkana]

> define よりも const を使うほうが良い
のは普通な意見だと思います。Cだと違いますが。

> 変数をconstにしたところで、変わらずそれはRAMに割り当てられます。
C++ベースなので、そんなことはないですね。constはRAMを消費しません。
さらにconstでない場合にも最適化が頑張ってこんなことに。

#define pin 3
void setup() {
pinMode(pin,OUTPUT);
}
void loop() {
digitalWrite(pin,0);
}
最大32256バイトのフラッシュメモリのうち、スケッチが726バイト（2%）を使っています。
最大2048バイトのRAMのうち、グローバル変数が9バイト（0%）を使っていて、ローカル変数で2039バイト使うことができます。

const int pin=3;
void setup() {
pinMode(pin,OUTPUT);
}
void loop() {
digitalWrite(pin,0);
}
最大32256バイトのフラッシュメモリのうち、スケッチが726バイト（2%）を使っています。
最大2048バイトのRAMのうち、グローバル変数が9バイト（0%）を使っていて、ローカル変数で2039バイト使うことができます。

PROGMEM const int pin=3;
void setup() {
pinMode(pin,OUTPUT);
}
void loop() {
digitalWrite(pin,0);
}
最大32256バイトのフラッシュメモリのうち、スケッチが726バイト（2%）を使っています。
最大2048バイトのRAMのうち、グローバル変数が9バイト（0%）を使っていて、ローカル変数で2039バイト使うことができます。

int pin=3;
void setup() {
pinMode(pin,OUTPUT);
}
void loop() {
digitalWrite(pin,0);
}
最大32256バイトのフラッシュメモリのうち、スケッチが726バイト（2%）を使っています。
最大2048バイトのRAMのうち、グローバル変数が9バイト（0%）を使っていて、ローカル変数で2039バイト使うことができます。

int pin;
void setup() {
pin=3;
pinMode(pin,OUTPUT);
}
void loop() {
digitalWrite(pin,0);
}
最大32256バイトのフラッシュメモリのうち、スケッチが740バイト（2%）を使っています。
最大2048バイトのRAMのうち、グローバル変数が11バイト（0%）を使っていて、ローカル変数で2037バイト使うことができます。

volatile int pin=3;
void setup() {
pinMode(pin,OUTPUT);
}
void loop() {
digitalWrite(pin,0);
}
最大32256バイトのフラッシュメモリのうち、スケッチが766バイト（2%）を使っています。
最大2048バイトのRAMのうち、グローバル変数が11バイト（0%）を使っていて、ローカル変数で2037バイト使うことができます。

[MTN]

thkana さん、教えてくださってありがとうございます。
そうなんですね、const でもいいんですね。
確かに、グローバル変数は9バイトのままですね。
ありがとうございます！

Answer 2

ちらと見ただけですが、

byte byteBuffer[512]; // 1024 だとRAM が足りなかったので512 にした
としたのなら、

  while(anyFile.available() && byteCount < 1024){
    byteBuffer[byteCount] = anyFile.read();
    byteCount++;
    readPosition++;
  }

こっちも合わせなきゃダメだと思いますがいかが。

Comments

[MTN]

回答ありがとうございます。
確かに、ご指摘の通りですね。
直してやってみます！！