java外部ライブラリを使ったポップアップのやり方(Processing)

Question

Processingについての質問です。

javaのAPIを用いて、例えば画面をクリックしたときに、ポップアップでウインドウが出て「クリックされました」というような表示がされるようにしたいとき、どのように、コーディングすればよろしいでしょうか。

しばらく調べてもわかりませんでした、

Answer 1

ポップアップでウインドウが出て「クリックされました」というような表示

マウスが「いつ」「どの座標で」押されたかはclosed_namedさんの回答の通りですが、「ポップアップを出す」という点について回答します。

• Processingの機能のみを使って出す

textメソッドを使ってウィンドウ上の任意の場所へテキストを表示するなら簡単なのですが、「ポップアップ」的なものにするなら、textメソッドを使って書いた内容を元に戻す配慮などが必要で若干面倒なプログラミングが必要になります。マウスを押した場所に表示するのではなく、どこか当たり障りのない固定的な座標へテキストを表示し、それを消す際にはその領域を単純にrectを用いて背景色で塗りつぶすなら簡単です。

• swingのPopupクラスを使う

いわゆる本物のポップアップウィンドウにするなら、swingのPopupクラスを使うことになりそうですが、Processing上でswing/awtの機能を使うことについて公式にはサポートされていない気がします。つまりそのようなことをしようとするなら「自己責任で」しなくてはならずProcessingのバージョンアップなどにより「いつか動かなくなる」可能性があるかも知れません。

それはともかく試しに挑戦してみたのでそのコードを挙げてみます。

import processing.awt.PSurfaceAWT;
import java.awt.*;
import javax.swing.*;
import java.awt.event.*;

Popup popup;

void setup() {
  size(200, 200);
}

void draw() {
}

void mousePressed() {
  showPopup("マウスが押されています", mouseX, mouseY);
}

void mouseReleased() {
  hidePopup();
}

//
// Processingのメイン画面の実体(awt.Componentクラス)を求める
//
PSurfaceAWT.SmoothCanvas getCanvas(PSurface surf) {
  return (PSurfaceAWT.SmoothCanvas)surf.getNative();
}

//
// 指定位置に指定メッセージのポップアップを表示する。
//
void showPopup(final String message, final int x, final int y){
  // invokeLaterが必要かどうかはっきりしませんが、
  // Processingはswingの標準UIスレッド(EDT)とは
  // 違うスレッドで動作しているため一応こうしています。
  SwingUtilities.invokeLater(new Runnable() {
    public void run() {
      if (popup != null)
        hidePopupOnEDT();
    
      JLabel label = new JLabel(message);
  
      Component canvas = getCanvas(getSurface());
      Point canvasLoc = getCanvas(getSurface()).getLocationOnScreen();
      int mx = canvasLoc.x;
      int my = canvasLoc.y;

      PopupFactory factory = PopupFactory.getSharedInstance();
      popup = factory.getPopup(canvas, label, mx + x, my + y - 16);
      popup.show();
    }
  });
}

//
// 表示中のポップアップがあれば消す。
//
void hidePopup() {
  SwingUtilities.invokeLater(new Runnable() {
    public void run() {
      hidePopupOnEDT();
    }
  });
}

//
// このメソッドはProcessingから直接呼ばないでください
//
void hidePopupOnEDT() {
  if (popup == null)
    return;
    
  popup.hide();
  popup = null;
}

Answer 2

processing
mouseX,mouseYでマウスの座標を取ることができます
また、
void mousePressed(){
...
}

を使うことでマウスがクリックされた際のプログラムを作ることができます

クリックされました、との表示についてはどのような表示をしようとしているかでまた変わってきます