Excel VBA から VBS を実行し結果を取得する

Question

VBAでVBSを実行し、VBSの実行結果(a,b,c)をVBAで取得したいです。
VBAを実行するとエラーは出ませんが、ret=0となります。
どのようにすればよいでしょうか。
よろしくお願いします。

(aa.vbs)
dim a,b,c
'
'計算処理でa,b,cの値を算出
a=4
b=5
c=6
'
msgbox "値1: " & a & vbCrLf & "値2: " & b & vbCrLf & "値3: " & c 
WScript.Quit(a)

Sub test1()
    Dim vbsPath As String
    Dim ret As Long
    vbsPath = "C:\AAA\aa.vbs"
    ret = CreateObject("Wscript.Shell").Run(vbsPath, True)
End Sub

Answer 1

VBAからVBSを実行して結果を受け取るのは色々できるとは思いますが
WScript.Stdout.WriteLine で出力して、
WScript.ShellのStdOut.ReadAllで受信するのがよくあるやり方ではないでしょうか。

具体的には

'(aa.vbs)
dim a,b,c
'
'計算処理でa,b,cの値を算出
a=4
b=5
c=6
'
WScript.Stdout.WriteLine "値1:" & a & vbCrLf & "値2:" & b & vbCrLf & "値3:" & c 
WScript.Quit(0)

Public Sub test()
    Dim t_Wsh 'As IWshRuntimeLibrary.WshShell
    Dim t_Exex 'As IWshRuntimeLibrary.WshExec
    Dim t_StdOut As String
    Dim t_Sp() As String
    Dim t_Sp2() As String
    Dim t_I As Long
    Dim a
    Dim b
    Dim c
    Dim t_VbsPath As String
    t_VbsPath = "C:\AAA\aa.vbs"
    
    Set t_Wsh = CreateObject("WScript.Shell")

    Set t_Exex = t_Wsh.Exec("CScript //Nologo " & t_VbsPath)
    Do While t_Exex.Status = 0
        DoEvents
    Loop

    t_StdOut = t_Exex.StdOut.ReadAll
        
    Debug.Print "ExitCode:" & t_Exex.ExitCode
        
    Set t_Exex = Nothing
    
    t_Sp = Split(t_StdOut, vbCrLf)
    For t_I = 0 To UBound(t_Sp)
        t_Sp2 = Split(t_Sp(t_I), ":")
        If UBound(t_Sp2) > 0 Then
            Select Case t_Sp2(0)
            Case "値1": a = t_Sp2(1)
            Case "値2": b = t_Sp2(1)
            Case "値3": c = t_Sp2(1)
            End Select
        End If
    Next
     
    Debug.Print "値1:" & a & vbCrLf & "値2:" & b & vbCrLf & "値3:" & c

End Sub

まぁ。結果の受け方は、てきとうですが…何となくやりかたはわかるのではないでしょうか。
受信できるのは文字列に限りますけどね…

Runについては、既に回答がなされているので省略します。

Comments

[nkym771]

ありがとうございます。
VBS終了までの待ち、VBS実行結果・終了コードの取得、文字列の分割
など詳しくありがとうございました。

Answer 2

Run(vbsPath, True)

は、Run(vbsPath, -1)ということですが、Runの第二引数のintWindowStyleには、-1の値は定義されていません。おそらく、Run(vbsPath,,True)と書くべき所をカンマを1つ漏らしたのでは？

Comments

[nkym771]

ありがとうございます。
その通りでした。

Answer 3

第三引数にTrueを指定する事でVBScriptの処理を待つことができます。
あなたのプログラムでは第ニ引数にTrueが指定されています。

' ret = CreateObject("Wscript.Shell").Run(vbsPath, True)
ret = CreateObject("Wscript.Shell").Run(vbsPath, , True)
MsgBox (ret)

実行結果

また、WScript.Quitは終了コード（整数値）を指定する事が本当の意味です。
戻り値という意味ではありません。
戻り値として利用できるというだけです。

なので、あなたが期待するようなWScript.Quitを利用して複数の整数値をVBSからVBAに渡す事は不可能です。
VBSで一時的なファイルを作成して、VBAでファイルを読み取る事で値の受け渡しを実現するなどで回避する必要があります。
（このような方法は好まれるものでは無いのであくまでわかりやすい一例として挙げただけです。よく考えて実装する必要があります。）

Comments

[nkym771]

ありがとうございます。
WScript.Quit を利用するのは本来用途から外れているのですね。
一時ファイルを利用する方式を考えます。

dim a,b,c
dim fs
dim f
'
'計算処理でa,b,cの値を算出
a=14
b=25
c=6
'
Set fs=CreateObject("Scripting.FileSystemObject")
Set f=fs.OpenTextFile("aa.txt", 2, true)
f.Write a & "," & b
WScript.Quit