WPF ScrollViewer内のComboboxでドロップダウンリストが表示されている状態でスワイプするとドロップダウンリストが消えずにスクロールしてしまう

Question

###前提・実現したいこと
ScrollViewer内のComboboxでドロップダウンリストが表示されている状態で
ScrollViewer内Comboboxの外領域をスワイプすると
ドロップダウンリストが消えずに表示ままになった状態でスクロールしてしまいます。

マウスホイールではドロップダウンリストが表示されているときは
スクロールすることができませんでした。

スワイプでも同様にスクロールできないようにするか
ドロップダウンリストが消えてほしいのですが、
設定または回避策があればご教授いただけますでしょうか？

###補足情報(言語/FW/ツール等のバージョンなど)
Windows10 Pro(x64)
.NetFramework 4.6.1(VB)
確認した端末:Surface4Pro

Answer 1

twyujiro15様のアドバイスをもとに再度ビヘイビアを検討してみました。
ComboBoxから親ScrollViewerを検索して、
TouchDownイベントをハンドリングするようにしています。
ハンドリングするタイミングはDropDownOpendイベントとしています。

    Public Class CloseDropDownBehavior
        Inherits Behavior(Of ComboBox)

        Private _ScrollViewer As ScrollViewer

        Protected Overrides Sub OnAttached()
            MyBase.OnAttached()
            AddHandler AssociatedObject.Loaded, AddressOf AssociatedObject_Loaded
            AddHandler AssociatedObject.TouchDown, AddressOf AssociatedObject_TouchDown
            AddHandler AssociatedObject.DropDownOpened, AddressOf AssociatedObject_DropDownOpened
            AddHandler AssociatedObject.DropDownClosed, AddressOf AssociatedObject_DropDownClosed
        End Sub

        Protected Overrides Sub OnDetaching()
            MyBase.OnDetaching()
            RemoveHandler AssociatedObject.Loaded, AddressOf AssociatedObject_Loaded
            RemoveHandler AssociatedObject.TouchDown, AddressOf AssociatedObject_TouchDown
            RemoveHandler AssociatedObject.DropDownOpened, AddressOf AssociatedObject_DropDownOpened
            RemoveHandler AssociatedObject.DropDownClosed, AddressOf AssociatedObject_DropDownClosed
            AssociatedObject_DropDownClosed(_ScrollViewer, New EventArgs)
        End Sub

        Private Sub AssociatedObject_Loaded(sender As Object, e As RoutedEventArgs)
            _ScrollViewer = AssociatedObject.
                Parents(Of ScrollViewer).
                Where(Function(x) x.PanningMode <> PanningMode.None).
                FirstOrDefault
        End Sub

        Private Sub AssociatedObject_TouchDown(sender As Object, e As TouchEventArgs)
            'ComboBoxタッチ時はScrollViewerのタッチを抑制
            'これをしないとコンボボックスDropDown後の再タッチでDropDownを閉じることができない
            e.Handled = True
        End Sub

        Private Sub AssociatedObject_DropDownOpened(sender As Object, e As EventArgs)
            If _ScrollViewer Is Nothing Then Return
            AddHandler _ScrollViewer.TouchDown, AddressOf ScrollViewer_TouchDown
        End Sub

        Private Sub AssociatedObject_DropDownClosed(sender As Object, e As EventArgs)
            If _ScrollViewer Is Nothing Then Return
            RemoveHandler _ScrollViewer.TouchDown, AddressOf ScrollViewer_TouchDown
        End Sub

        Private Sub ScrollViewer_TouchDown(sender As Object, e As RoutedEventArgs)
            AssociatedObject.IsDropDownOpen = False
        End Sub
    End Class

※Parentsメソッドは親エレメントを取得するための拡張メソッドです。

Comments

[twyujiro15]

今回は ScrollViewer が親要素ですが、そうとも限らないので、
CloseDropDownBehavior クラスに IsParent 添付プロパティを定義して、
親パネルとなる要素に CloseDropDownBehavior.IsParent="True" を設定するようにするといいかもしれませんね。
そうすれば親パネルを探索するとき、
単純に親要素を辿っていって IsParent が true の Panel を探すだけになります。

[mikupedia]

twyujiro15 様
アドバイスありがとうございます。
＞今回は ScrollViewer が親要素ですが、そうとも限らないので
ScrollViewerのスワイプでドロップダウンが閉じられなかったため、ScrollViewer限定としました。
それ以外のパターンが今のところ思いつかないので添付プロパティとしなくてもよいかなと思っています。必要になったら対応したいと思います。
また、ソースコードでアタッチ時にTouchDown、DropDownOpened、DropDownClosedをハンドリングするように設定していますが、ご指摘通りそもそも親にScrollViewerがいない可能性もあるためハンドリングの設定はScrollViewerが存在していたらとしたほうが良いかもしれませんね。

Answer 2

twyujiro15さんのアドバイスに従って、IsDropDownOpenをFalseにするようにしたビヘイビアを作成しました。
ただ、ScrollViewer内のすべてのエレメントからComboBoxの検索が必要であることと
そのタイミングがScrollChangedイベントに頼ってしまうため、パフォーマンスが悪いかもしれません。
一応、フラグを設けて無駄なエレメントの検索は回避するようにしています。

    Public Class CloseDropDownBehavior
        Inherits Behavior(Of ScrollViewer)

        Private _IsCanCloseDropDow As Boolean

        Protected Overrides Sub OnAttached()
            MyBase.OnAttached()
            AddHandler AssociatedObject.ManipulationStarted, AddressOf AssociatedObject_ManipulationStarted
            AddHandler AssociatedObject.ScrollChanged, AddressOf AssociatedObject_ScrollChanged
        End Sub

        Protected Overrides Sub OnDetaching()
            MyBase.OnDetaching()
            RemoveHandler AssociatedObject.ManipulationStarted, AddressOf AssociatedObject_ManipulationStarted
            RemoveHandler AssociatedObject.ScrollChanged, AddressOf AssociatedObject_ScrollChanged
        End Sub

        Private Sub AssociatedObject_ManipulationStarted(sender As Object, e As ManipulationStartedEventArgs)
            _IsCanCloseDropDow = True
        End Sub

        Private Sub AssociatedObject_ScrollChanged(sender As Object, e As ScrollChangedEventArgs)
            If _IsCanCloseDropDow Then
                _IsCanCloseDropDow = False
                Dim combobox = AssociatedObject.Descendants(Of ComboBox).Where(Function(x) x.IsDropDownOpen = True).FirstOrDefault
                If combobox IsNot Nothing Then
                    combobox.IsDropDownOpen = False
                End If
            End If
        End Sub

    End Class

※Descendantsメソッドは孫エレメントを取得するための拡張メソッドです。

Comments

[twyujiro15]

逆の発想で ComboBox にビヘイビアを付けるようにしては？
親要素のパネルのインスタンスを取得して、
そのパネルがタッチされたら自分の IsDropDownOpen を false にすればいいんですよ。

Answer 3

ScrollViewer 内 ComboBox の外領域をタッチした瞬間に、
ComboBox の IsDropDownOpen プロパティを false にしてはどうでしょうか。